	list      p=16f877            ; list directive to define processor

	#include <p16f877.inc>        ; processor specific variable definitions
	
;
;		PICNIC - PIC Network Interface Controller
;		Copyright (c) 2002 SHINSHU UNIVERSITY KISO LAB
;		 All Rights Reserved.
;
;		01-SEP-2002	Version 1.2.0.0		[original]
;		12-OCT-2003	Version 1.2.0.4a	[K.Wasaki]
;		30-OCT-2004	Version 1.2.0.4b	[K.Wasaki]


;-----------------------------------------------------------------------------------
	
	__CONFIG _CP_OFF & _WDT_OFF & _BODEN_ON & _PWRTE_ON & _HS_OSC & _LVP_OFF


;-----------------------------------------------------------------------------------
HTTP_PORT		EQU	.8080			; HTTPポート番号(80=デフォルト) [ver0.2]
LCD_PORT		EQU	.0			; LCDコントロール用ポート番号(0=未使用)
PARALLEL_PORT		EQU	.10001			; パラレル用ポート番号(0=未使用)
SERIAL_PORT		EQU	.10002			; シリアル用ポート番号(0=未使用)

BOOTPC_PORT		EQU	.68			; BOOTPポート番号(クライアント)
BOOTPS_PORT		EQU	.67			; BOOTPポート番号(サーバ)

BAUD_RATE		EQU	.129	;10		; リセット時のRS232Cボーレート
							; 129=9600bps
							; 10=115200bps

PARALLEL_PACKET_SIZE	EQU	.8			; パラレル転送パケットサイズ
SERIAL_PACKET_SIZE	EQU	(.2 + .6 + .4 + .2 + .1 + .1)		; シリアルステータスパケットのサイズ
							; type:mac:ip:port:baud:flow
CH_BACKSPACE		EQU	.8			; バックスペースの文字コード
SOCKETS			EQU	.4			; ソケット総数(変更不可)


;-----------------------------------------------------------------------------------

		ORG	0x2100
		
		DE	.192, .168, 1, .200	; ＩＰアドレス(0.0.0.0=DHCP) [ver0.2]
		DE	.255 , .255 , .255 , 0	; ネットマスク
		DE	0,0,0,0		; GateWay
		DE	1,2,0,4		; Farmware Version x,x,x,x [ver0.4]
		
		DE	HTTP_PORT / .256 , HTTP_PORT & .255				; HTTPポート番号
		DE	LCD_PORT / .256 , LCD_PORT & .255				; LCDポート番号
		DE	PARALLEL_PORT / .256 , PARALLEL_PORT & .255			; PARALLELポート番号
		DE	SERIAL_PORT / .256 , SERIAL_PORT & .255			; SERIALポート番号

;
;-----------------------------------------------------------------------------------

;
;		プロトコル番号など
;
COM_PROTO	EQU	08H			; HIGH BYTE(共通)
IP_PROTO	EQU	00H			; LOW BYTE (0800h means IP packet)
ARP_PROTO	EQU	06H			; LOW BYTE (0806h means ARP packet)


TCP_PROTO	EQU	.6
UDP_PROTO	EQU	.17
ICMP_PROTO	EQU	.1

;
;		RTL8019AS関連設定項目
;
PAGE_BEGIN	EQU	40H			; メモリ先頭アドレス
PAGE_START	EQU	46H			; 受信バッファ先頭アドレス
PAGE_STOP	EQU	80H			; 受信バッファ終端アドレス

DATA_SIZE	EQU	.18

;
;		Ethernet関連設定項目
;
NE_SIZE		EQU	.4			; RTL8019ステータスエリアサイズ
PACKET_SIZE	EQU	.6 + .6 + .2			; Ethernetヘッダサイズ
ARP_SIZE	EQU	.28			; ARPパケットサイズ
IP_SIZE		EQU	.20			; IP(基本)ヘッダサイズ
UDP_SIZE	EQU	.8			; UDPヘッダサイズ
TCP_SIZE	EQU	.20			; TCP(基本)ヘッダサイズ
DHCP_SIZE	EQU	.308
;
;		TCP/IPステート
;
LISTEN		EQU	00			; ひま
SYN_RCVD	EQU	80H			; SYN,ACKを送ってACKを待っている
ESTAB		EQU	81H			; 通信確立
CLOSE_WAIT	EQU	82H
LAST_ACK	EQU	83H
FIN_WAIT_1	EQU	84H
FIN_WAIT_2	EQU	85H
CLOSING		EQU	86H
TIME_WAIT	EQU	87H

;		ソケット構造体
;------------------------------------------
;		org	0
;so_job		ds	2
;so_ip		ds	4
;so_port	ds	2
;so_seq_no	ds	4
;so_ack_no	ds	4
;------------------------------------------



;-----------------------------------------------------------------------------------
;		Ｉ／Ｏポート設定
;-----------------------------------------------------------------------------------
SA		EQU	PORTC			; NE2000 アドレスバス
SA0		EQU	0			;rc.0
SA1		EQU	1
SA2		EQU	2
SA3		EQU	3
SA4		EQU	4			;rc.4

SD		EQU	PORTD
SD0		EQU	0			;rd.0
SD1		EQU	1
SD2		EQU	2
SD3		EQU	3
SD4		EQU	4
SD5		EQU	5
SD6		EQU	6
SD7		EQU	7			;rd.7

RDY		EQU	5			;rc.5		; ~IOCHRDY


CNT		EQU	PORTE
RD		EQU	0			;re.0	; RTL8019AS ~RD
WR		EQU	1			;re.1	; RTL8019AS ~WR


;
;		ＬＣＤ用Ｉ／Ｏ設定（オプショナルＬＣＤ用)
;
D7		EQU	7			;rb.7			; 液晶用
D6		EQU	6
D5		EQU	5
D4		EQU	4
E		EQU	3			; 液晶イネーブル
RS		EQU	2			;rb.2 ; 液晶ＲＳピン



;-----------------------------------------------------------------------------------
;		グローバル変数
;-----------------------------------------------------------------------------------
;		PAGE 0 
;		org	20h

;	ＬＣＤ用変数
wait_cn		EQU	20H	
wait_cn2	EQU	21H	
d4		EQU	22H	
d8		EQU	23H	

cd		EQU	24H
tmp		EQU	24H	
use		EQU	25H	
;-----------------------------------------------------------------------------------
gcn1		EQU	26H	
sum		EQU	27H		; check sum for TCP,...
sum1		EQU	28H
bytes		EQU	29H			; current ptr for calculate above
ptr		EQU	2AH	


cn_l		EQU	2BH		; fan free
cn_h		EQU	2CH	

remote_adr	EQU	2DH			; リモート
remote_adr1	EQU	2EH
remote_len	EQU	2FH	
remote_len1	EQU	30H
curr		EQU	31H			; Current page address


val		EQU	32H	
val1		EQU	33H	
val2		EQU	34H	
val3		EQU	35H	
val_m		EQU	36H			; for DECIMAL
val_cn		EQU	37H
proto		EQU	37H			; プロトコル番号
state		EQU	38H			; TCPフラグ

;-----------------------------------------------------------------------------------
;
;		ＩＰプロトコル
;
ip_header	EQU	39H
ip_ver_len	EQU	39H		; VERSION:4,DATA SIZE:5
ip_tos		EQU	3AH		; service type
ip_length	EQU	3BH		; データ長
ip_length1	EQU	3CH
ip_ident	EQU	3DH	
ip_ident1	EQU	3EH
ip_flagment	EQU	3FH		
ip_flagment1	EQU	40H
ip_ttl		EQU	41H		; 生存期間
ip_proto	EQU	42H		; プロトコル 1:ICMP,6:TCP,17:UDP
ip_sum		EQU	43H		; ヘッダチェックサム
ip_sum1		EQU	44H
ip_src		EQU	45H	
ip_src1		EQU	46H
ip_src2		EQU	47H
ip_src3		EQU	48H
ip_dest		EQU	49H	
ip_dest1	EQU	4AH
ip_dest2	EQU	4BH
ip_dest3	EQU	4CH


;-----------------------------------------------------------------------------------
;		ＴＣＰプロトコル
;
tcp_header	EQU	4DH	
tcp_src_port	EQU	4DH	
tcp_src_port1	EQU	4EH
tcp_tar_port	EQU	4FH	
tcp_tar_port1	EQU	50H
tcp_seq_no	EQU	51H	
tcp_seq_no1	EQU	52H
tcp_seq_no2	EQU	53H
tcp_seq_no3	EQU	54H
tcp_ack_no	EQU	55H	
tcp_ack_no1	EQU	56H
tcp_ack_no2	EQU	57H
tcp_ack_no3	EQU	58H
tcp_header_size	EQU	59H	
tcp_flags	EQU	5AH	
TCP_URG		EQU	5	
TCP_ACK		EQU	4	
TCP_PSH		EQU	3	
TCP_RST		EQU	2
TCP_SYN		EQU	1	
TCP_FIN		EQU	0	

tcp_window	EQU	5BH	
tcp_window1	EQU	5CH
tcp_sum		EQU	5DH	
tcp_sum1	EQU	5DH
tcp_		EQU	5FH	
tcp_1		EQU	60H	

;-----------------------------------------------------------------------------------
;		ＵＤＰプロトコル
;
udp_header	SET	tcp_header
udp_src_port	SET	tcp_header+0
udp_src_port1	SET	tcp_header+1
udp_tar_port	SET	tcp_header+2
udp_tar_port1	SET	tcp_header+3
udp_length	SET	tcp_header+4
udp_length1	SET	tcp_header+5
udp_sum		SET	tcp_header+6
udp_sum1	SET	tcp_header+7
udp_data	SET	tcp_header+8
udp_data1	SET	tcp_header+9
udp_data2	SET	tcp_header + .10
udp_data3	SET	tcp_header + .11
udp_data4	SET	tcp_header + .12
udp_data5	SET	tcp_header + .13
udp_data6	SET	tcp_header + .14
udp_data7	SET	tcp_header + .15


;-----------------------------------------------------------------------------------
;		ＡＲＰプロトコル
;
arp_header	SET	ip_header
arp_hard_type	SET	ip_header+0
arp_prot_type	SET	ip_header+2
arp_hard_len	SET	ip_header+4
arp_prot_len	SET	ip_header+5
arp_ope		SET	ip_header+6
arp_ope1	SET	ip_header+7
arp_src_mac	SET	ip_header+8
arp_src_ip	SET	ip_header + .14
arp_dest_mac	SET	ip_header + .18
arp_dest_ip	SET	ip_header + .24
arp_dest_ip1	SET	ip_header + .25
arp_dest_ip2	SET	ip_header + .26
arp_dest_ip3	SET	ip_header + .27
;		=	ip_header + .28


;-----------------------------------------------------------------------------------
;		ＩＣＭＰプロトコル
;
icmp_header	SET	tcp_header
icmp_type	SET	tcp_header+0
icmp_code	SET	tcp_header+1
icmp_sum	SET	tcp_header+2
icmp_mes	SET	tcp_header+4


;-----------------------------------------------------------------------------------
;		ＤＨＣＰプロトコル
;
dhcp_header	SET	udp_data
dhcp_ope	SET	udp_data+0
dhcp_type	SET	udp_data+1
dhcp_phylen	SET	udp_data+2
dhcp_hop	SET	udp_data+3
dhcp_trans	SET	udp_data+4
dhcp_sec	SET	udp_data+8
dhcp_dummy	SET	udp_data + .10
dhcp_client_ip	SET	udp_data + .12
dhcp_user_ip	SET	udp_data + .16
dhcp_user_ip1	SET	udp_data + .17
dhcp_user_ip2	SET	udp_data + .18
dhcp_user_ip3	SET	udp_data + .19
dhcp_server_ip	SET	udp_data + .20
dhcp_server_ip1	SET	udp_data + .21
dhcp_server_ip2	SET	udp_data + .22
dhcp_server_ip3	SET	udp_data + .23
dhcp_router_ip	SET	udp_data + .24


;-----------------------------------------------------------------------------------
;		環境設定用変数
;
;		PAGE 1
;		org	0a0h
this_ip		EQU	0A0H		; 自分のＩＰアドレス
this_ip1	EQU	0A1H		
this_ip2	EQU	0A2H		
this_ip3	EQU	0A3H		
mymac		EQU	0A4H		; 自分のＭＡＣアドレス
mymac1		EQU	0A5H
mymac2		EQU	0A6H
mymac3		EQU	0A7H
mymac4		EQU	0A8H
mymac5		EQU	0A9H
seq_no		EQU	0AAH			; 自分のシーケンス番号
seq_no1		EQU	0ABH		
seq_no2		EQU	0ACH		
seq_no3		EQU	0ADH
ident		EQU	0AEH		
ident1		EQU	0AFH
timer		EQU	0B0H		
timer_cn	EQU	0B1H		
dhcp_done	EQU	0B2H		
http_port	EQU	0B3H			; EEPROMからのポート番号のコピー
http_port1	EQU	0B4H
lcd_port	EQU	0B5H		
lcd_port1	EQU	0B6H
para_port	EQU	0B7H		
para_port1	EQU	0B8H
serial_port	EQU	0B9H		
serial_port1	EQU	0BAH

fifo_poi	EQU	0BBH		; ルーチンで使用する(GET)ポインタ
fifo_buff	EQU	0BCH		; 割り込みで使用する(SET)ポインタ
fifo_cn		EQU	0BDH		; 受信バイト数
fifo_top	EQU	0BEH		; バッファ
fifo_bottom	EQU	0DCH

fifo_line	EQU	0DCH		
fifo_line_cn	EQU	0DDH	


;-----------------------------------------------------------------------------------
;		Ethernetヘッダ
;
ne_header	EQU	0DEH		; NE2000 Status
ne_stat		EQU	0DEH		; 受信ステータス(RSR)
ne_next		EQU	0DFH		; 次のバウンダリポインタ(Next Boundary)
ne_cn_l		EQU	0E0H		; データサイズ（Ｌ）
ne_cn_h		EQU	0E1H		; データサイズ（Ｈ）

eth_header	EQU	0E2H			; Ethernet Header
eth_dest	EQU	0E2H			; 送信先ＭＡＣアドレス
eth_dest1	EQU	0E3H
eth_dest2	EQU	0E4H
eth_dest3	EQU	0E5H
eth_dest4	EQU	0E6H
eth_dest5	EQU	0E7H
eth_src		EQU	0E8H		; 送信元ＭＡＣアドレス
eth_src1	EQU	0E9H
eth_src2	EQU	0EAH
eth_src3	EQU	0EBH
eth_src4	EQU	0ECH
eth_src5	EQU	0EDH
eth_type	EQU	0EEH		; パケットタイプ
eth_type1	EQU	0EFH
null		EQU	0F0H


bs_ptr		SET	ne_header
bs_ptr2		SET	ne_header+1
save_line	SET	ne_header+2
save_cn		SET	ne_header+3

;-----------------------------------------------------------------------------------
;		共通変数
;

;		org	70h		; COMMON MEMORY PAGE
; BEGIN -- 割り込み時レジスタ待避用
w_save		EQU	070H	
pclath_save	EQU	071H	
status_save	EQU	072H	
fsr_save	EQU	073H		
save_fsr	EQU	074H		
; END

mul10		EQU	075H
mul101		EQU	076H
getmes_wk	EQU	075H		
getmes_wk1	EQU	076H
com_cn		EQU	077H		
byte_cn		EQU	078H		
com_fsr		EQU	078H		
ind		EQU	079H		
dest		EQU	07AH		
dest1		EQU	07BH
data0		EQU	07CH		; a data for transmit to ethernet chip
wk		EQU	07DH	
wk1		EQU	07EH
wk2		EQU	07FH
common		EQU	07FH	

;-----------------------------------------------------------------------------------
;	１０進変換用エリア
;-----------------------------------------------------------------------------------
;		PAGE 2
;		
			; バイナリ→10進数変換用
decimal_top	EQU	120H	


;-----------------------------------------------------------------------------------
;	ＲＳ２３２Ｃ送信先データ
;-----------------------------------------------------------------------------------
;		PAGE 3
;		org	190h
on_ether	EQU	190H			; 宛て先Ethernetアドレス
on_ether1	EQU	191H
on_ether2	EQU	192H
on_ether3	EQU	193H
on_ether4	EQU	194H
on_ether5	EQU	195H
on_ip		EQU	196H		; 宛て先IPアドレス
on_ip1		EQU	197H
on_ip2		EQU	198H
on_ip3		EQU	199H
on_port		EQU	19AH				; 宛て先ポート番号
on_port1	EQU	19AH
on_rate		EQU	19CH				; 設定されているボーレート
on_flow		EQU	19DH				; ＝０
transmitted	EQU	19EH
skb		EQU	1A0H
;-----------------------------------------------------------------------------------
;		プログラムエントリ
;-----------------------------------------------------------------------------------
		ORG	0			; リセットベクタ(=0000h)
		MOVLW	HIGH (start)		; スタートアップルーチンへ

		MOVWF	PCLATH
		GOTO	start

;-----------------------------------------------------------------------------------
;		割り込み処理
;
;		スタック消費を押さえるため、割り込み処理内ではcallしてはいけない。
;-----------------------------------------------------------------------------------

		org	4		; 割り込みベクタ(=0004h)
interrupt
;-----------------------------------------------------------------------------------
;		コンテキスト待避処理
		movwf	w_save		; Ｗレジスタ保存
		swapf	STATUS, 0	; STATUSレジスタを保存
		clrf	STATUS				; STATUSを０にする
		movwf	status_save
		movf	PCLATH,0		; PCLATHを保存
		movwf	pclath_save
		clrf	PCLATH			; PCLATH=0にする
		bcf	STATUS,IRP	
		movf	FSR, 0		
		movwf	fsr_save	; FSRを保存する
;-------------------------------------------------------------------------------;		RB0割り込み
		btfss	INTCON,INTE
		GOTO	int_next2
		BTFSS	INTCON,INTF
		GOTO	int_next2

		bcf	INTCON,INTF
		BSF	STATUS,RP0
		BSF	STATUS,RP1
		BSF	on_flow,7
		BCF	STATUS,RP1
		BCF	STATUS,RP0
;-------------------------------------------------------------------------------;
int_next2
		BTFSC	PIR1,TMR1IF
		goto	int_tmr1
		goto	int_next1
int_tmr1
		bcf	PIR1,TMR1IF
		BSF	STATUS,RP0
		MOVF	dhcp_done,0
		andlw	7FH
		btfss	STATUS,Z
		DECF	dhcp_done,1
		bcf	STATUS,RP0
int_tmr2
		bsf	STATUS,RP0
		MOVLW	1
		ADDWF	timer,1
		btfsc	STATUS,C
		GOTO	dec_tm
dec_tm9		CLRF	STATUS
;-------------------------------------------------------------------------------
int_next1
		btfss	INTCON, PEIE	
		goto	int2
		btfss	PIR1,RCIF			; RS232C受信？
		goto	int2
;-----------------------------------------------------------------------------------
;		シリアル受信割り込み処理
		bsf	STATUS,RP0	
		
		MOVLW	fifo_bottom - fifo_top
		SUBWF	fifo_cn,0
		BTFSC	3,0
		GOTO	rec_over

		movf	fifo_buff,0		; 現在のリング
		movwf	FSR		;バッファのポインタ取得→fsrへ
		bcf	STATUS,RP0	;
		MOVF	RCREG,0			; リングバッ
		MOVWF	INDF		;ファに受信データを保存
		bsf	STATUS,RP0	
		incF	fifo_buff,1	; 次のアドレスに...
		
		MOVLW	fifo_bottom
		SUBWF	fifo_buff,0
		BTFSS	3,0
		GOTO	int1_1

		MOVLW	fifo_top	
		movwf	fifo_buff
int1_1		incf	fifo_cn,1		; リングバッファにあるデータバイト数＋＋
;-----------------------------------------------------------------------------------
		MOVLW	(fifo_bottom - fifo_top) / 2	; [2004/10/30 ver.1.2.0.4b]
		subwf	fifo_cn,0
		btfss	3,0
		goto	int2
		bsf	STATUS,RP1
		BTFSS	on_flow,0
		GOTO	int2
		CLRF	STATUS
		BSF	PORTB,1
int2
		CLRF	STATUS
;-------------------------------------------------------------------------------;		コンテキスト復帰処理
		MOVF	fsr_save,0			; fsrを復帰
		MOVWF	FSR
		MOVF	pclath_save,0		; pclathを復帰
		MOVWF	PCLATH
		swapf	status_save,0
		movwf	STATUS					; statusを復帰
		swapf	w_save,1
		swapf	w_save,0		; Wを復帰
;	ISR終了
		retfie				; 割り込みルーチンからのリターン


;		RS232C受信バッファオーバーフロー
rec_over
		bcf	STATUS, RP0	
		MOVF	RCREG, 0				; データを読んで捨てる
		bcf	STATUS, RP0	
		goto	int2


;-----------------------------------------------------------------------------------
;		ソケットのタイムアウトチェック
;
dec_tm
		bsf	STATUS, IRP
		MOVLW	SOCKETS
		MOVWF	timer_cn
		MOVLW	(skb + 1) & 0FFH	
		MOVWF	FSR
dec_tm0
		MOVF	INDF,0		
		andlw	0f0h
		btfsc	STATUS, Z	
		goto	dec_tm1
		MOVLW	10H		
		SUBWF	INDF, 1
		movF	INDF, 0		
		andlw	0f0h
		btfss	STATUS, Z	
		goto	dec_tm1
		DECF	FSR, 1		
		CLRF	INDF		
		INCF	FSR,1		
dec_tm1
		MOVLW	10H		
		ADDWF	FSR, 1
		DECFSZ	timer_cn, 1
		GOTO	dec_tm0
		bcf	STATUS, IRP	
		goto	dec_tm9



;-----------------------------------------------------------------------------------
;		16進文字の取得ルーチン
;
getascii
		andlw	0fh
		ADDWF	PCL, 1		
		DT	"0123456789ABCDEF"
;-----------------------------------------------------------------------------------
;		TCPのseq_noをインクリメントする 
;
next_seq_no
		bsf	STATUS,RP0	
		movLW	1				; +65536
		ADDWF	seq_no2,1
		btfsc	STATUS,	C	
		ADDWF	seq_no3,1	
		bcf	STATUS,RP0	
		RETURN


;-----------------------------------------------------------------------------------
;		TCPのseq_noをインクリメントする。
;
inc_seq_no
		bsf	STATUS,IRP	
		movLW	.3		
		ADDWF	FSR,1
		movLW	.1		
		ADDWF	INDF,1
		DECF	FSR,1		
		btfsc	STATUS,C	
		addwf	INDF,1		
		DECF	FSR,1	 
		btfsc	STATUS,C	
		addwf	INDF,1		
		DECF	FSR,1		
		btfsc	STATUS,C	
		addwf	INDF,1		
		bcf	STATUS,IRP	
		retURN

;-----------------------------------------------------------------------------------
;		TCPのseq_noにip_lengthを加算する。
;
add_seq_no
		bsf	STATUS,IRP	
		movLW	.3		
		ADDWF	FSR,1

		MOVF	ip_length1,0	
		addwf	INDF,1		
		DECF	FSR,1		
		movlw	1
		btfsc	STATUS,C	
		addwf	INDF,1		
		DECF	FSR,1		
		btfsc	STATUS,C	
		addwf	INDF,1		
		DECF	FSR,1		
		btfsc	STATUS,C	
		addwf	INDF,1		
	
		movLW	.2		
		ADDWF	FSR,1
		MOVF	ip_length,0	
		addwf	INDF,1		
		DECF	FSR,1		
		movlw	1
		btfsc	STATUS,C	
		addwf	INDF,1		
		DECF	FSR,1		
		btfsc	STATUS,C	
		addwf	INDF,1		
		bcf	STATUS,IRP	
		retURN

;-----------------------------------------------------------------------------------
;		TCPのack_noをインクリメントする。
;
inc_ack_no
		movLW	1		
		ADDWF	tcp_seq_no3,1
		btfsc	STATUS,C	
		addwf	tcp_seq_no2,1	
		btfsc	STATUS,C	
		addwf	tcp_seq_no1,1	
		btfsc	STATUS,C	
		addwf	tcp_seq_no,1	

		goto	copy_ack_no
;		ret

;-----------------------------------------------------------------------------------
;		TCPのack_noにip_lengthを加算する。
;
add_ack_no
		MOVLW	.20 + .20	
		SUBWF	ip_length1,1
		movlw	1
		btfss	STATUS,C	
		subwf	ip_length,1	

		MOVF	ip_length1,0	
		ADDWF	tcp_seq_no3,1
		movlw	1
		btfsc	STATUS,C	
		addwf	tcp_seq_no2,1	
		btfsc	STATUS,C	
		addwf	tcp_seq_no1,1	
		btfsc	STATUS,C	
		addwf	tcp_seq_no,1	

		MOVF	ip_length,0	
		ADDWF	tcp_seq_no2,1
		movlw	1
		btfsc	STATUS,C	
		addwf	tcp_seq_no1,1	
		btfsc	STATUS,C	
		addwf	tcp_seq_no,1	
copy_ack_no
		MOVF	com_fsr,0	
		MOVWF	FSR
		MOVLW	.12		
		ADDWF	FSR,1
		bsf	STATUS,IRP	
		MOVF	tcp_seq_no,0	
		MOVWF	INDF
		INCF	FSR,1		
		MOVF	tcp_seq_no1,0	
		MOVWF	INDF
		INCF	FSR,1		
		MOVF	tcp_seq_no2,0	
		MOVWF	INDF
		INCF	FSR,1		
		MOVF	tcp_seq_no3,0	
		MOVWF	INDF
		bcf	STATUS,IRP	
		retURN


;-----------------------------------------------------------------------------------
;		チェックサムの値をクリアする。
;
clear_sum
		clrF	sum		
		clrF	sum1		
		clrF	bytes		; HI byte/LO byteの識別用
		retURN


;-----------------------------------------------------------------------------------
;		エラーリカバリールーチン
;-----------------------------------------------------------------------------------
overflow2
overflow
		clrF	STATUS		
		
		clrF	PORTC		
		movlw	21h			; RTL8019AS STOP
		call	assert_wr0
		
		MOVLW	HIGH (wait_ms)	
		MOVWF	PCLATH
		MOVLW	.2		
		MOVWF	wait_cn
		call	wait_ms			; 10ms Wait
		clrF	PCLATH		
		
		MOVLW	0AH		
		MOVWF	PORTC		
		DB	01,00		
		call	assert_wr0
		
		MOVLW	0BH		
		MOVWF	PORTC		
		DB	01,00		
		call	assert_wr0
		
		call	initialize		; RTL8019を初期化
		
		MOVLW	0CH
		MOVWF	PORTC					; RCR
		movlw	B'000100'			; MONITOR解除
		call	assert_wr0
		
		MOVLW	0DH		
		MOVWF	PORTC					; TCR
		DB	01,00		;clrw				; L/B解除
		call	assert_wr0
		
		goto	main0			; 通常処理に戻る

;===================================================================================
;		メインルーチン
;===================================================================================
main

		CLRF	PORTC					;rc
		movlw	22h
		call	assert_wr0		; PAGE0に戻す

		MOVLW	0CH		
		MOVWF	PORTC
		movlw	B'000100'
		call	assert_wr0
		MOVLW	0DH		
		MOVWF	PORTC
		DB	01,00						; L/B解除
		call	assert_wr0
		
		MOVLW	HIGH (wait_ms)	
		MOVWF	PCLATH
		MOVLW	.100		
		MOVWF	wait_cn
		call	wait_ms			; 100ms Wait
		clrF	PCLATH		
		
		MOVLW	this_ip		
		MOVWF	FSR
		MOVF	INDF,0		
		INCF	FSR,1		
		iorwf	INDF,0		
		INCF	FSR,1		
		iorwf	INDF,0		
		INCF	FSR,1		
		iorwf	INDF,0		
		btfss	STATUS,2	
		goto	main0			; 自分のIPアドレスが0.0.0.0？
do_dhcp
		CLRF	STATUS
		MOVLW	HIGH (dhcp)	
		MOVWF	PCLATH
		call	dhcp
		MOVLW	$ >> 8		
		MOVWF	PCLATH

;===================================================================================
;		メインループ
;===================================================================================
main0

		bsf	STATUS,RP0	; RS232C受信？
		MOVLW	0
		SUBWF	fifo_cn,0
		BTFSS	3,2
		GOTO	receive232c
		MOVLW	80h
		SUBWF	dhcp_done,0
		BTFSC	3,2
		GOTO	do_dhcp
		bcf	STATUS,RP0	

		CLRF	PCLATH		
		MOVLW	.7		
		MOVWF	PORTC
		call	assert_rd		; ＲＣＲリード
		
		btfsc	data0,4		
		goto	overflow
		btfsc	data0,3		
		goto	overflow
		btfsc	data0,2		
		goto	overflow
		goto	get_packet		; パケット受信あり

main99		goto	main0			; このラベルは未使用[ver0.4]

receive232c
		bcf	STATUS,RP0	
		MOVLW	serial_tx >> 8	
		MOVWF	PCLATH		; receive232c処理へ
		goto	serial_tx

;-----------------------------------------------------------------------------------
;	パケット受信処理
;-----------------------------------------------------------------------------------
get_packet
;	PAGE 1
		CLRF	PORTC		
		movlw	B'01100010'
		call	assert_wr0		; PAGE1にする
		
		MOVLW	.7		
		MOVWF	PORTC
		call	assert_rd
		MOVF	data0,0				; カレントページを取得
		MOVWF	curr
;	PAGE 0
		CLRF	PORTC		
		movlw	B'00100010'
		call	assert_wr0		; PAGE0に戻す
		
		MOVLW	.3		
		MOVWF	PORTC
		call	assert_rd		; BNDYをよむ
		
		INCF	data0,1					; BNDY++
		MOVLW	PAGE_STOP		; overlap計算
		SUBWF	data0,0
		BTFSS	3,0
		GOTO	packet1

		MOVLW	PAGE_START	
		MOVWF	data0
packet1
		MOVF	curr,0				; (BNDY+1)==CURRの場合は新規データなし
		SUBWF	data0,0
		BTFSC	3,2
		goto	main0			; 中断


;-----------------------------------------------------------------------------------
; RTL8019ステータス＋Ethernetヘッダの読み出し
		CLRF	remote_adr	
		MOVF	data0,0		
		MOVWF	remote_adr1
		MOVLW	NE_SIZE + PACKET_SIZE	
		MOVWF	remote_len
		CLRF	remote_len1		
		call	remote_read
		
		MOVLW	NE_SIZE + PACKET_SIZE		; Loop Counter
		MOVWF	gcn1
		bcf	STATUS,IRP		
		MOVLW	ne_header					; アドレスne_headerへ読み出す
		MOVWF	FSR
		MOVLW	10H			
		MOVWF	PORTC
get_packet0
		bcf	PORTE,0				;RD
		btfss	PORTC,RDY				; ~Wait
		goto	$-1
		MOVF	PORTD,0		
		
		bsf	PORTE,0		;RD
		movwf	INDF		;INDF			; *INDF = data バッファへセット
		INCF	FSR,1		
		DECFSZ	gcn1,1		
		GOTO	get_packet0
;
;		Ethernetヘッダによって処理を分岐
		bsf	STATUS,RP0	
		btfss	ne_stat,0	
		goto	main9
		MOVLW	COM_PROTO		; typeの上位８ビットが８以外はスキップ
		SUBWF	eth_type,0
		BTFSS	3,2
		GOTO	main9
		MOVLW	IP_PROTO		; IPプロトコル処理へ分岐
		SUBWF	eth_type1,0
		BTFSC	3,2
		GOTO	do_ip
		MOVLW	ARP_PROTO		; ARPプロトコル処理へ分岐
		SUBWF	eth_type1,0
		BTFSC	3,2
		GOTO	do_arp			; ARPプロトコル処理へ分岐
;		goto	main9				; その他
;-----------------------------------------------------------------------------------
main9
		bcf	STATUS,IRP	
		bcf	STATUS,RP1	
		bsf	STATUS,RP0	
		MOVLW	PAGE_START		; Error Check and Recovery
		SUBWF	ne_next,0
		BTFSS	3,0
		GOTO	overflow2
		MOVLW	PAGE_STOP		; Error Check and Recovery
		SUBWF	ne_next,0
		BTFSC	3,0
		GOTO	overflow2

		DECF	ne_next,1					; 次のバンダリを計算
		MOVLW	PAGE_START	
		SUBWF	ne_next,0
		BTFSC	3,0
		GOTO	packet11

		MOVLW	PAGE_STOP-1	
		MOVWF	ne_next
packet11
		bcf	STATUS,RP0	
		
		CLRF	PORTC		
		movlw	B'00100010'
		call	assert_wr0
		
		MOVLW	.3		
		MOVWF	PORTC
		MOVLW	ne_next		
		MOVWF	FSR
		MOVF	INDF,0			; バンダリポインタセット
		call	assert_wr0
		goto	main99



;-----------------------------------------------------------------------------------
;		ＡＲＰプロトコル処理
;-----------------------------------------------------------------------------------
do_arp
		bcf	STATUS,RP0	
		MOVLW	NE_SIZE + PACKET_SIZE	
		MOVWF	remote_adr
		MOVLW	ne_cn_l			
		MOVWF	FSR
		MOVF	INDF,0			
		MOVWF	remote_len
		INCF	FSR,1			
		MOVF	INDF,0			
		MOVWF	remote_len1

		MOVLW	NE_SIZE + PACKET_SIZE	
		SUBWF	remote_len,1
		movlw	1
		btfss	STATUS,C		
		subwf	remote_len1,1		
		call	remote_read

		MOVLW	ip_header				; アドレスip_header以降にデータを読み出す
		MOVWF	FSR
get_packet10
		movf	remote_len,0		
		iorwf	remote_len1,0		
		btfsc	STATUS,Z		
		goto	get_packet2		; 読み込み終了？
		
		bcf	PORTE,0			
		btfss	PORTC,5						; ~Wait
		goto	$-1
		MOVF	PORTD,0			
		bsf	PORTE,0			
		movwf	INDF			
		INCF	FSR,1			
		
		movlw	1			; レングスをデクリメント
		SUBWF	remote_len,1		
		btfss	STATUS,C		
		SUBWF	remote_len1,1		
		
		btfss	FSR,7						; over flow?
		goto	get_packet10
;	80h以降
get_packet20
		movf	remote_len,0		
		iorwf	remote_len1,0		
		btfsc	STATUS,Z		
		goto	get_packet2		; 読み込み終了
		
		bcf	PORTE,0			
		btfss	PORTC,5						; ~Wait
		goto	$-1
	;	MOVF	PORTD,0			
		bsf	PORTE,0			
	;	movwf	INDF

		movlw	1
		subwf	remote_len,1		
		btfss	STATUS,C		
		subwf	remote_len1,1		
		goto	get_packet20
;
;		ARPヘッダの解析
get_packet2
		MOVLW	0					; arp_codeが0001以外なら捨てる
		SUBWF	arp_ope,0
		BTFSS	3,2
		GOTO	main9

		MOVLW	1			
		SUBWF	arp_ope1,0
		BTFSC	3,2
		GOTO	arp_req

		MOVLW	2			
		SUBWF	arp_ope1,0
		BTFSC	3,2
		GOTO	arp_reply
		
		goto	main9
arp_reply
		MOVLW	HIGH (ser_arp)		
		MOVWF	PCLATH
		goto	ser_arp
arp_req
arp
		MOVLW	this_ip				; this_ipはBANK 1にある。
		MOVWF	FSR
		MOVF	arp_dest_ip,0			; ARPのIPアドレスが自分と同じか？
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	main9
		INCF	FSR,1			

		MOVF	arp_dest_ip1,0		
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	main9
		INCF	FSR,1			

		MOVF	arp_dest_ip2,0		
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	main9
		INCF	FSR,1			
		MOVF	arp_dest_ip3,0		
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	main9


;	自分へのARP要求である
		call	prepare_ether2		

		movlw	COM_PROTO		
		call	assert_wr
		movlw	ARP_PROTO		
		call	assert_wr

		MOVLW	arp1 >> 8
		movwf	PCLATH
		call	arp1			
		CLRF	PCLATH
		CLRF	PORTC			
		movlw	B'00100010'
		call	assert_wr0
		
		MOVLW	.4			
		MOVWF	PORTC
		movlw	PAGE_BEGIN		 
		call	assert_wr0
		
		MOVLW	.5			
		MOVWF	PORTC
		movlw	.60			
		call	assert_wr0
		
		MOVLW	.6			
		MOVWF	PORTC
		DB	01,00		
		call	assert_wr0
		
		call	transmit			; ARP応答を送信する
		goto	main9


;-----------------------------------------------------------------------------------
;		ＩＰプロトコル受信処理
;-----------------------------------------------------------------------------------
do_ip
		bcf	STATUS,RP0	
		MOVLW	NE_SIZE + PACKET_SIZE	
		MOVWF	remote_adr
		MOVLW	ne_cn_l			
		MOVWF	FSR
	;	mov	fsr,#ip_length
		MOVF	INDF,0			
		MOVWF	remote_len
		INCF	FSR,1			
		MOVF	INDF,0			
		MOVWF	remote_len1

		MOVLW	NE_SIZE + PACKET_SIZE				; 受信バイト数からEtherヘッダ長を引く
		SUBWF	remote_len,1
		movlw	1
		btfss	STATUS,C		
		subwf	remote_len1,1		
		call	remote_read
;
;	ＩＰパケットの受信
		MOVLW	ip_header				; アドレスip_headerへデータを読み込む
		MOVWF	FSR

		bcf	PORTE,0			
		btfss	PORTC,5						; ~Wait
		goto	$-1
		MOVF	PORTD,0			
		bsf	PORTE,0			
		movwf	INDF					; １バイト読む！
		INCF	FSR,1			

		movlw	1			
		subwf	remote_len,1		
		btfss	STATUS,C		
		subwf	remote_len1,1		

		MOVF	ip_ver_len,0		; 残りバイト数算出
		MOVWF	gcn1
		MOVLW	0FH			
		ANDWF	gcn1,1

		BCF	3,0			
		RLF	gcn1,1			
		RLF	gcn1,1			
		DECF	gcn1,1				; IPヘッダからIPヘッダサイズを計算
		call	copy_toram		; RAMに転送

ip_get_packet2
		MOVLW	45H			; IP Version 4 ?
		SUBWF	ip_ver_len,0
		BTFSS	3,2
		GOTO	ip_get_packet9
		MOVLW	TCP_PROTO			; TCP受信処理へ
		SUBWF	ip_proto,0
		BTFSC	3,2
		GOTO	tcp
		MOVLW	UDP_PROTO			; UDP受信処理へ
		SUBWF	ip_proto,0
		BTFSC	3,2
		GOTO	udp
		MOVLW	ICMP_PROTO		; ICMP受信処理へ
		SUBWF	ip_proto,0
		BTFSC	3,2
		GOTO	icmp
ip_get_packet9
		call	abort				; リモートＤＭＡ中止
		goto	main9

;-----------------------------------------------------------------------------------
;		gcn1のバイト数分データを読み込む
;-----------------------------------------------------------------------------------
copy_toram
		bcf	PORTE,0		
		btfss	PORTC,5					; ~Wait
		goto	$-1
		MOVF	PORTD,0		
		bsf	PORTE,0		
		movwf	INDF				; *INDF = data
		INCF	FSR,1					; fsr++
		
		movlw	1		
		subwf	remote_len,1	
		btfss	STATUS,C	
		subwf	remote_len1,1	
		
		DECFSZ	gcn1,1		
		GOTO	copy_toram
		retURN



;-----------------------------------------------------------------------------------
;		パケットの残りをバッファＲＡＭへ
;-----------------------------------------------------------------------------------
get_remain
get_remain0
		movf	remote_len,0	
		iorwf	remote_len1,0	
		btfsc	STATUS,Z	
		goto	get_remain9	
		
		bcf	PORTE,0		
		btfss	PORTC,5					; ~Wait
		goto	$-1
		MOVF	PORTD,0		
		bsf	PORTE,0		
		movwf	INDF				; 表にセット
		INCF	FSR,1		
		
		movlw	1		
		subwf	remote_len,1	
		btfss	STATUS,C	
		subwf	remote_len1,1	
		
		movlw	.16+.128
		addwf	FSR,0		
		btfss	STATUS,C	
		goto	get_remain0

		MOVLW	20H				; バンクを変えて更に読み込み
		MOVWF	FSR
		bsf	STATUS,IRP	
get_remain20
		movf	remote_len,0	
		iorwf	remote_len1,0	
		btfsc	STATUS,Z	
		goto	get_remain9		; 読み込み終了
		
		bcf	PORTE,0		
		btfss	PORTC,5					; ~Wait
		goto	$-1
		MOVF	PORTD,0		
		bsf	PORTE,0		
		movwf	INDF				; 裏にセット
		INCF	FSR,1		
		
		movlw	1
		subwf	remote_len,1	
		btfss	STATUS,C	
		subwf	remote_len1,1	
		
		movlw	.16+.128
		addwf	FSR,0		
		btfss	STATUS,C	
		goto	get_remain20

get_remain30
		call	abort
		
;		movf	remote_len,0	
;		iorwf	remote_len[1],0
;		btfsc	z
;		goto	get_remain9		; 読み込み終了
;		
;		bcf	RD
;		btfss	RDY			; ~Wait
;		goto	$-1
;		bsf	RD
;
;		movlw	1
;		subwf	remote_len[0],1
;		btfss	STATUS,C
;		subwf	remote_len[1],1
;		goto	get_remain30
get_remain9
		bcf	STATUS,IRP	
		retURN




;-----------------------------------------------------------------------------------
;		ＩＣＭＰプロトコル処理
;-----------------------------------------------------------------------------------
icmp
		call	get_remain			; RTL8019からデータを転送
		MOVLW	.8			; typeが08h以外は捨てる
		SUBWF	icmp_type,0
		BTFSS	3,2
		GOTO	main9
		MOVLW	0				; codeが08h以外は捨てる
		SUBWF	icmp_code,0
		BTFSS	3,2
		GOTO	main9
ping
		MOVLW	ICMP_PROTO			; プロトコル＝ICMP
		MOVWF	proto
		call	prepare_ip			; IPパケットの準備
;
		MOVLW	PACKET_SIZE + IP_SIZE	
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN		
		MOVWF	remote_adr1
		MOVF	ip_length1,0				;ne_cn_l
		MOVWF	remote_len
		MOVLW	IP_SIZE - 1		
		SUBWF	remote_len,1
		CLRF	remote_len1		
		call	remote_write
		
		call	clear_sum			; チェックサムの値をクリア
		
		MOVLW	10H			
		MOVWF	PORTC
		call	assert_wr2times			; type : code
		call	assert_wr2times			; sum High : Low
		
		MOVF	ip_length1,0				;ne_cn_l
		MOVWF	gcn1
		MOVLW	IP_SIZE + 4		;sub	gcn1,#IP_SIZE + 4
		SUBWF	gcn1,1
		MOVLW	icmp_header + 4		
		MOVWF	FSR
icmp10
		MOVF	INDF,0			
		INCF	FSR,1			
		call	assert_wr
		
		movlw	.16 + .128
		addwf	FSR,0			
		btfsc	STATUS,C		
		goto	icmp20
icmp19		DECFSZ	gcn1,1			
		GOTO	icmp10
		bcf	STATUS,IRP		

		DB	01,00		;clrw
		call	assert_wr

		MOVLW	PACKET_SIZE + IP_SIZE + 2	
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN		
		MOVWF	remote_adr1
		call	set_checksum
		
		MOVLW	4H			
		MOVWF	PORTC
		movlw	PAGE_BEGIN			; transmit page is start page 
		call	assert_wr0
		
		MOVLW	.5			
		MOVWF	PORTC
		MOVLW	ne_cn_l			
		MOVWF	FSR
		MOVF	INDF,0			
		call	assert_wr0
		
		MOVLW	.6			
		MOVWF	PORTC
		INCF	FSR,1			
		MOVF	INDF,0			
		call	assert_wr0
		
		call	transmit			; PINGの応答を送信
		goto	main9
icmp20
		MOVLW	20H			
		MOVWF	FSR
		bsf	STATUS,IRP		
		goto	icmp19



;-----------------------------------------------------------------------------------
;		ＵＤＰ
;-----------------------------------------------------------------------------------
udp
		MOVLW	.8			
		MOVWF	gcn1
		call	copy_toram
		
;	BOOTPポートのチェック
		MOVLW	BOOTPC_PORT / .256	
		SUBWF	udp_tar_port,0
		BTFSS	3,2
		GOTO	udp_1
		MOVLW	BOOTPC_PORT & 0FFH		; BOOTP処理へ
		SUBWF	udp_tar_port1,0
		BTFSC	3,2
		GOTO	bootp_res

		MOVLW	this_ip			
		MOVWF	FSR
		MOVF	INDF,0				; 自分への送信データか？
		SUBWF	ip_dest,0
		BTFSS	3,2
		GOTO	main9

		INCF	FSR,1			
		MOVF	INDF,0			
		SUBWF	ip_dest1,0
		BTFSS	3,2
		GOTO	main9

		INCF	FSR,1			
		MOVF	INDF,0			
		SUBWF	ip_dest2,0
		BTFSS	3,2
		GOTO	main9
		INCF	FSR,1			
		MOVF	INDF,0			
		SUBWF	ip_dest3,0
		BTFSS	3,2
		GOTO	main9

;	LCDポートのチェック
udp_1
		MOVLW	lcd_port & 0FFH		
		MOVWF	FSR
		MOVF	INDF,0			
		SUBWF	udp_tar_port,0
		BTFSS	3,2
		GOTO	udp_2
		INCF	FSR,1			
		MOVF	INDF,0			
		SUBWF	udp_tar_port1,0
		BTFSC	3,2
		GOTO	udp_lcd_tag
udp_2
		MOVLW	para_port & 0FFH	
		MOVWF	FSR
		MOVF	INDF,0			
		SUBWF	udp_tar_port,0
		BTFSS	3,2
		GOTO	udp_3

		INCF	FSR,1			
		MOVF	INDF,0			
		SUBWF	udp_tar_port1,0
		BTFSC	3,2
		GOTO	udp_parallel_tag
udp_3
		MOVLW	serial_port & 0FFH	
		MOVWF	FSR
		MOVF	INDF,0			
		SUBWF	udp_tar_port,0
		BTFSS	3,2
		GOTO	udp_4
		INCF	FSR,1			
		MOVF	INDF,0			
		SUBWF	udp_tar_port1,0
		BTFSC	3,2
		GOTO	udp_serial_tag
udp_4
;
;		add new funciton this
;
		goto	main9
udp_lcd_tag
		movlw	udp_lcd >> 8
		movwf	PCLATH
		GOTO	udp_lcd
;
;		パラレルＩ／Ｏの処理（ＵＤＰ）
;
udp_parallel_tag
		MOVLW	udp_data		
		MOVWF	FSR
		call	get_remain
		MOVLW	HIGH (udp_parallel)	
		MOVWF	PCLATH
		goto	udp_parallel
udp_serial_tag
		MOVLW	HIGH (udp_serial)	
		MOVWF	PCLATH
		goto	udp_serial

;-----------------------------------------------------------------------------------
get_dgram
		movf	remote_len,0		
		iorwf	remote_len1,0		
		btfsc	STATUS,Z		
		goto	get_dgram9
		
		bcf	PORTE,0			
		btfss	PORTC,5						; ~Wait
		goto	$-1
		MOVF	PORTD,0			
		bsf	PORTE,0			
		movwf	data0
		
		movlw	1
		subwf	remote_len,1		
		btfss	STATUS,C		
		subwf	remote_len1,1		
		
		BCF	3,0							; OK
		retURN
get_dgram9
		BSF	3,0							; EOT
		RETURN


;-----------------------------------------------------------------------------------
;		BOOTP応答
;-----------------------------------------------------------------------------------
bootp_res
		call	get_remain

		MOVLW	this_ip		
		MOVWF	FSR
		MOVF	INDF,0		
		INCF	FSR,1
		iorwf	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		btfss	STATUS,Z
		goto	main9
		
		MOVLW	HIGH (bootp)	
		MOVWF	PCLATH
		call	bootp
		MOVLW	HIGH (bootp_res)
		MOVWF	PCLATH
		
		movlw	35h	; 
		call	assert_wr
		movlw	01h
		call	assert_wr
		movlw	3		; request
		call	assert_wr
		
		movlw	3dh	; 
		call	assert_wr
		movlw	07h
		call	assert_wr
		movlw	01h
		call	assert_wr
		MOVLW	mymac		
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes			; 自分のＭＡＣ
		
		movlw	.54	; 
		call	assert_wr
		movlw	04h
		call	assert_wr
		movlw	0c0h
		call	assert_wr
		movlw	0a8h
		call	assert_wr
		movlw	0h
		call	assert_wr
		movlw	3h
		call	assert_wr

		movlw	.50	; 
		call	assert_wr
		movlw	4
		call	assert_wr
		
		MOVLW	dhcp_user_ip		
		MOVWF	FSR
		movlw	4
		call	transmit_nbytes
		
		
		movlw	0ffh
		call	assert_wr
		
		MOVLW	.64 - .7 - .9 - .1 - .6 - .6
		MOVWF	gcn1
bootp_40
		DB	01,00		;clrw
		call	assert_wr
		DECFSZ	gcn1,1		
		GOTO	bootp_40
		MOVLW	HIGH (bootp_tx)
		MOVWF	PCLATH
		call	bootp_tx
		MOVLW	HIGH (bootp_40)
		MOVWF	PCLATH
;
;	ここでDHCPサーバからもらったＩＰｱﾄﾞﾚｽを自分のｱﾄﾞﾚｽとして登録
		MOVLW	this_ip		
		MOVWF	FSR
		MOVF	dhcp_user_ip,0	
		MOVWF	INDF
		INCF	FSR,1
		MOVF	dhcp_user_ip1,0	
		MOVWF	INDF
		INCF	FSR,1
		MOVF	dhcp_user_ip2,0	
		MOVWF	INDF
		INCF	FSR,1
		MOVF	dhcp_user_ip3,0	
		MOVWF	INDF
		bsf	STATUS,RP0
		CLRF	dhcp_done
		BCF	STATUS,RP0

;
;	もらったＩＰアドレスを液晶に表示
		bcf	PORTB,2
		MOVLW	0C0H		
		MOVWF	d4
		MOVLW	HIGH (write_lcd4)
		MOVWF	PCLATH
		call	write_lcd4			; 2行目に移動
		
		MOVLW	HIGH(print_ip)
		MOVWF	PCLATH
		call	print_ip			; 表示！
		CLRF	PORTB
		CLRF	PCLATH
		goto	main9




;-----------------------------------------------------------------------------------
;		ＴＣＰ
;-----------------------------------------------------------------------------------
tcp
		MOVLW	.20			; 20バイトを読み込む
		MOVWF	gcn1
		call	copy_toram
		
		MOVLW	http_port & 0ffh		
		MOVWF	FSR
		MOVF	INDF,0		; EEPROMのhttpポートと一致するか？
		SUBWF	tcp_tar_port,0
		BTFSS	3,2
		GOTO	tcp9

		INCF	FSR,1
				
		MOVF	INDF,0
		SUBWF	tcp_tar_port1,0
		BTFSC	3,2
		GOTO	tcp_www

tcp9		goto	main9				; http以外でTCPに応答するものはない
;
;	http処理
tcp_www
		MOVLW	this_ip		
		MOVWF	FSR
		MOVF	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		btfsc	STATUS,Z
		goto	main9			; IPアドレスが0.0.0.0なら処理中止
		
		btfsc	tcp_flags,5	;TCP_URG			; URG
		goto	main9			; 廃棄
		
		MOVLW	HIGH(search_socket)
		MOVWF	PCLATH
		call	search_socket		; ソケットを検索
		MOVLW	HIGH (tcp_www)
		MOVWF	PCLATH
		btfsc	STATUS,C
		goto	state1			; ステート存在あり？
		
		call	no_socket		; ソケット作成
		goto	main9
;
;	socket state1
state1
		MOVLW	.12		;add	FSR,#12
		ADDWF	FSR,1
	;	mov	pclath,#print_hex>>8
	;	mov	pclath,#$>>8
;
		MOVF	INDF,0		
		SUBWF	tcp_seq_no,0
		BTFSS	3,2
		GOTO	state12
		INCF	FSR,1
		MOVF	INDF,0		
		SUBWF	tcp_seq_no1,0
		BTFSS	3,2
		GOTO	state12
		INCF	FSR,1
		MOVF	INDF,0		
		SUBWF	tcp_seq_no2,0
		BTFSS	3,2
		GOTO	state12
		INCF	FSR,1
		MOVF	INDF,0		
		SUBWF	tcp_seq_no3,0
		BTFSS	3,2
		GOTO	state12
		MOVLW	.15		
		SUBWF	FSR,1
		call	state2
state12		CLRF	PCLATH
		goto	main9
		
state2
		MOVLW	HIGH(state_table)
		MOVWF	PCLATH

		MOVF	INDF,0
		andlw	7fh
		ADDWF	2,1		
state_table
		goto	job_SYN_RCVD		;
		goto	job_ESTAB		;
		goto	job_CLOSE_WAIT		;
	;	nop	;goto	job_LAST_ACK	;
		goto	main9
		goto	job_FIN_WAIT_1		;
		goto	job_FIN_WAIT_2		;
	;	nop	;goto	job_CLOSING	;
		goto	main9
	;	nop	;goto	job_TIME_WAIT	;
		goto	main9
		goto	main9		;ACK,PSH,RST,SYN,FIN





;-----------------------------------------------------------------------------------
;		SYNを受け取り,
;		SYN,ACKを送ってACK待ち
job_SYN_RCVD
		btfsc	tcp_flags,TCP_RST
		goto	recv_rst
		btfsc	tcp_flags,TCP_FIN
		goto	recv_fin
		btfss	tcp_flags,TCP_ACK
		RETURN

		MOVLW	ESTAB	;mov	INDF,#ESTAB
		MOVWF	INDF
		bcf	STATUS,IRP
		RETURN
recv_rst
		clrF	INDF
		bcf	STATUS,IRP
		RETURN

;-----------------------------------------------------------------------------------
;
;
job_FIN_WAIT_1
		btfsc	tcp_flags,TCP_RST
		goto	recv_rst
		btfss	tcp_flags,TCP_ACK
		RETURN
		
		MOVLW	FIN_WAIT_2
		MOVWF	INDF
		bcf	STATUS,IRP
		RETURN

;-----------------------------------------------------------------------------------
;
;
job_FIN_WAIT_2
		btfsc	tcp_flags,TCP_RST
		goto	recv_rst
		btfss	tcp_flags,TCP_FIN
		RETURN
		
		clrF	INDF
		bcf	STATUS,IRP

		call	inc_ack_no
		call	send_ack
		RETURN

;-----------------------------------------------------------------------------------
;
;
		nop
job_ESTAB
		btfsc	tcp_flags,TCP_RST
		goto	recv_rst
		btfsc	tcp_flags,TCP_FIN
		goto	recv_fin
		
		INCF	FSR,1
		MOVLW	HIGH (job_ESTAB)
		MOVWF	PCLATH
		MOVF	INDF,0
		andlw	0fh
		ADDWF	2,1		;jmp	pc+w
		goto	ESTAB_00
		goto	ESTAB_01
		goto	ESTAB_02
		goto	ESTAB_03
		goto	ESTAB_99


recv_fin
		MOVLW	0
		MOVWF	INDF
		bcf	STATUS,IRP
		
		call	inc_ack_no
		call	send_ack
		RETURN

;-----------------------------------------------------------------------------------
;
;
job_CLOSE_WAIT
		MOVLW	0
		MOVWF	INDF
		bcf	STATUS,IRP
		
		call	send_fin
		RETURN
ESTAB_99
		decF	FSR,1
		MOVLW	FIN_WAIT_1
		MOVWF	INDF
		bcf	STATUS,IRP
		
		call	send_fin
		
		MOVF	com_fsr,0
		MOVWF	FSR
		MOVLW	.8
		ADDWF	FSR,1
		call	inc_seq_no
		RETURN

;-----------------------------------------------------------------------------------
;		ESTABLISH
;
ESTAB_00
		incF	INDF,1
		bcf	STATUS,IRP
estab0
		MOVLW	HIGH(get_nextbyte)
		MOVWF	PCLATH

		call	get_nextbyte		; バッファからデータを取得
		MOVLW	HIGH (estab0)
		MOVWF	PCLATH
		
		MOVLW	0			; 終了？
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	estab1
			; 改行文字？
		MOVLW	0AH
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	estab1
			; '?'文字を発見？(=GETコマンドの処理)
		MOVLW	'?'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse_cgi_tag
		goto	estab0
parse9

;-----------------------------------------------------------------------------------
;
;
estab1
		call	abort			; バッファ転送中止
		call	add_ack_no		; ACK NOを加算
;		call	send_ack		; ACKを送信
		
		MOVLW	014H			;バンクアドレス＝14h fan
		MOVWF	wk
		goto	send_mes		; メッセージ送信
;
;		バンク間ジャンプ用
parse_cgi_tag
		MOVLW	HIGH(parse_cgi)
		MOVWF	PCLATH

		goto	parse_cgi




ESTAB_01
		incF	INDF,1
		bcf	STATUS,IRP
	;	call	send_ack
	;
		MOVLW	017H	
		MOVWF	wk
		goto	send_mes		; メッセージ送信
ESTAB_02
		incF	INDF,1
		bcf	STATUS,IRP
	;	call	send_ack
		
		;mov	wk,#01Ah		; バンクアドレス＝19h
		MOVLW	01AH
		MOVWF	wk
		goto	send_mes		; メッセージ送信
ESTAB_03
		incF	INDF,1
		bcf	STATUS,IRP
	;	call	send_ack
		
		;mov	wk,#01Dh		; バンクアドレス＝1bh
		MOVLW	01DH
		MOVWF	wk
		goto	send_mes		; メッセージ送信
;
;		リモートＤＭＡ転送中止
abort
		CLRF	PORTC	 
		movlw	22h
		call	assert_wr0		; PAGE0に戻す
		
		MOVLW	0ah
		MOVWF	PORTC
		DB	01,00		;clrw
		call	assert_wr0
		
		MOVLW	0bh
		MOVWF	PORTC
		DB	01,00		;clrw
		call	assert_wr0
		RETURN





;-----------------------------------------------------------------------------------
;		ＲＳＴパケットの送信
send_rst
		MOVLW	B'000100'		; RST
		MOVWF	state
		goto	send_common


;-----------------------------------------------------------------------------------
;		ＦＩＮパケットの送信
send_fin
		MOVLW	B'010001'		; ACK+FIN
		MOVWF	state
		goto	send_common


;-----------------------------------------------------------------------------------
;		ＡＣＫパケットの送信
send_ack
		MOVLW	B'010000'		; ACK
		MOVWF	state
;		goto	send_common
send_common
		MOVLW	0		
		MOVWF	ip_length
		;mov	ip_length[1],#IP_SIZE + TCP_SIZE
		MOVLW	IP_SIZE + TCP_SIZE
		MOVWF	ip_length1
		
		MOVLW	TCP_PROTO	
		MOVWF	proto
		call	prepare_ip
		
		MOVLW	PACKET_SIZE + IP_SIZE	
		MOVWF	remote_adr
		;mov	remote_adr[1],#PAGE_BEGIN
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		;mov	remote_len[0],#20		; 20バイト
		MOVLW	.20
		MOVWF	remote_len
		;mov	remote_len[1],#0
		MOVLW	0
		MOVWF	remote_len1
		call	remote_write
		
		call	clear_sum			; チェックサムの値をクリア
		
		MOVLW	http_port & 0ffh
		MOVWF	FSR
		movlw	2
		call	transmit_nbytes			; 自分のポート番号
		
		MOVLW	tcp_src_port
		MOVWF	FSR
		movlw	2
		call	transmit_nbytes			; 相手のポート番号

		MOVF	com_fsr,0
		MOVWF	FSR
		MOVLW	.8
		ADDWF	FSR,1
		bsf	STATUS,IRP
		movlw	4+4
		call	transmit_nbytes			; 自分のＳＥＱＮＯ
		bcf	STATUS,IRP
		
		movlw	50h			; 20bytes
		call	assert_wr
		MOVF	state,0			;mov	w,state
		call	assert_wr
		
		movlw	08h			; window(high)
		call	assert_wr
		movlw	00h			; window(low)
		call	assert_wr
		
		call	assert_wr2times			; tcp sum
		call	assert_wr2times			; 緊急ポインタ
		
		call	calc_tcp_sum			; TCP SUMの計算
		
		MOVLW	4h
		MOVWF	PORTC
		movlw	PAGE_BEGIN			; transmit page is start page 
		call	assert_wr0
		
		MOVLW	5
		MOVWF	PORTC
		movlw	.60				; 60バイト送信
		call	assert_wr0
		
		MOVLW	6
		MOVWF	PORTC
		DB	01,00		;clrw					; 上位転送バイト＝０
		call	assert_wr0
		call	transmit			; 送信！！
		RETURN

;-----------------------------------------------------------------------------------
;
;
send_mes
		MOVLW	assert_wr2x & 0ffh	; 送信ｊｏｂをRTL8019に
		MOVWF	dest
		MOVLW	HIGH (assert_wr2x)	
		MOVWF	dest1		
send_mes_head
				; 仮に65535バイト転送に設定
;-------
		MOVLW	PACKET_SIZE + IP_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	0FFH
		MOVWF	remote_len
		MOVLW	0FFH
		MOVWF	remote_len1

;-------		

		;mov	remote_len[1],#0ffh		; 
		call	remote_write
		
		;clr	remote_len[0]
		;clr	remote_len[1]
		CLRF	remote_len
		CLRF	remote_len1
		
		call	clear_sum			; チェックサムの値をクリア
		
		MOVLW	http_port & 0ffh
		MOVWF	FSR
		movlw	2
		call	transmit_nbytes2		; 自分のポート番号
		
		MOVLW	tcp_src_port
		MOVWF	FSR
		movlw	2
		call	transmit_nbytes2		; 相手のポート番号

		bsf	STATUS,IRP
		MOVF	com_fsr,0
		MOVWF	FSR
		MOVLW	.8
		ADDWF	FSR,1
		movlw	4
		call	transmit_nbytes2		; 自分のＳＥＱＮＯ
		bcf	STATUS,IRP
	
		MOVLW	tcp_seq_no
		MOVWF	FSR
		movlw	4
		call	transmit_nbytes2		; 相手のＳＥＱＮＯ＋１
		
		movlw	50h		; 20bytes
		call	assert_wr2
		movlw	B'011000'
		call	assert_wr2
		
		movlw	08h		; window(high)
		call	assert_wr2
		movlw	00h		; window(low)
		call	assert_wr2
		
		DB	01,00		;clrw
		call	assert_wr2		; tcp sum
		DB	01,00		;clrw
		call	assert_wr2		; tcp sum
		DB	01,00		;clrw
		call	assert_wr2		; 緊急ポインタ
		DB	01,00		;clrw
		call	assert_wr2		; 緊急ポインタ
	
		CLRF	ind
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVF	wk,0		; 読み出すアドレス＝[wk:ind]
		MOVWF	EEADRH
send_mes0
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVF	ind,0		
		MOVWF	EEADR
		bsf	STATUS,RP0
		bsf	EECON1,7		;eepgd
		bsf	EECON1,0	;eecon1.0 ; コードエリアからデータを読み出す
		nop				; ダミーサイクル
		nop
		bcf	STATUS,RP0
		MOVF	EEDATH,0		; (読んだデータを)作業領域へ移動
		MOVWF	getmes_wk
		MOVF	EEDATA,0	
		MOVWF	getmes_wk1

		bcf	STATUS,RP1
		
		RLF	getmes_wk1,0		
		RLF	getmes_wk,1		
		MOVF	getmes_wk,0		; 上位７ビットが０か？
		MOVWF	data0
		MOVLW	7FH		
		ANDWF	data0,1
		MOVF	data0,1		
		btfsc	STATUS,Z
		goto	send_mes9		; 上位７ビットが０なら終了
;
;		上位７ビットがメタ文字なら処理を分岐
		MOVLW	'$'  
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	ctrl_code2
 		MOVLW	'@'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	ctrl_code3
 		MOVLW	'%'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	ctrl_code4

		MOVLW	'~'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	ctrl_code5
		
		MOVF	data0,0			;
		call	assert_wr2
		
		MOVF	getmes_wk1,0		; 下位７ビットをRTL8019バッファへ転送
		andlw	7fh
		call	assert_wr2
		
		MOVLW	1					; ind++
		ADDWF	ind,1
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		btfsc	STATUS,C
		INCF	EEADRH,1
		goto	send_mes0
send_mes9

send_mes_foot
		call	abort			; リモートＤＭＡ転送の中止
		
	
		MOVF	remote_len,0
		MOVWF	ip_length1
	
		MOVF	remote_len1,0
		MOVWF	ip_length

		call	calc_tcp_sum		; TCP SUMを計算する
		
		MOVLW	.20		;add	ip_length[1],#20; 20を加算
		ADDWF	ip_length1,1
		movlw	1
		btfsc	STATUS,C
		addwf	ip_length,1		;addwf	ip_length[0]
		
		MOVLW	TCP_PROTO	; TCP packet
		MOVWF	proto
		call	prepare_ip		; IPプロトコルの準備
		
		MOVLW	4h
		MOVWF	PORTC
		movlw	PAGE_BEGIN			; transmit page is start page 
		call	assert_wr0
		
		MOVLW	PACKET_SIZE			; パケットサイズ6+6+2を送信バイト数に加算1
		addWF	ip_length1,1
		movlw	1
		btfsc	STATUS,C
		addwf	ip_length,1	
		
		MOVLW	6
		MOVWF	PORTC
		MOVF	ip_length,0		
		call	assert_wr0
		MOVF	ip_length,1		
		btfsc	STATUS,Z
		goto	send_mes_foot1
send_mes_foot2
		MOVLW	5
		MOVWF	PORTC
		MOVF	ip_length1,0	
		call	assert_wr0
		call	transmit			; 送信！！
		
;
;	Additional Code
send_mes_foot3
		MOVLW	PACKET_SIZE+IP_SIZE+TCP_SIZE
		SUBWF	ip_length1,1	
	
		movlw	1
		btfss	STATUS,C
	
		SUBWF	ip_length,1	
		
		MOVF	com_fsr,0
		MOVWF	FSR
		MOVLW	.8
		ADDWF	FSR,1
		call	add_seq_no			; seq noに加算
		RETURN

send_mes_foot1
 		MOVLW	.60
		SUBWF	ip_length1,0
		BTFSC	3,0
		GOTO	send_mes_foot2
		MOVLW	5
		MOVWF	PORTC
		movlw	.60				; MINIMUM 60bytes
		call	assert_wr0
		call	transmit
		goto	send_mes_foot3

;-----------------------------------------------------------------------------------
;		ＡＤ変換
;
ad_in
		RLF	getmes_wk1,1	
		RLF	getmes_wk1,1		
		RLF	getmes_wk1,1		
		MOVLW	B'00111000'	 
		ANDWF	getmes_wk1,1
		MOVLW	B'10000001'	
		IORWF	getmes_wk1,1
		MOVF	getmes_wk1,0		; ADCON1に値を設定
		MOVWF	ADCON1
		MOVLW	1	
		MOVWF	wait_cn
		MOVLW	HIGH (wait_ms)
		MOVWF	PCLATH

		call	wait_ms				; サンプリング時間20us待機
		MOVLW	HIGH (ad_in)
		MOVWF	PCLATH
		
		bsf	ADCON1,2		; ＡＤ変換開始
		btfsc	ADCON1,2		; ＡＤ変換待ち
		goto	$-1
		
		MOVF	ADRESH,0			; 変換結果をval[1]:val[0]へ
		MOVWF	val1
		bsf	STATUS,RP0
		MOVF	ADRESL,0	
		bcf	STATUS,RP0
		movwf	val		
		
		btfss	getmes_wk1,5				; RA5かどうか？
		goto	ad_in1				; RA5以外
	;
	;ＡＤ変換結果を５倍する
	;
		BCF	3,0		
		RLF	val,1		
		RLF	val1,1		
		BCF	3,0	
		RLF	val,1		
		RLF	val1,1		
		
		MOVF	ADRESH,0	
		ADDWF	val1,1
		bsf	STATUS,RP0
		MOVF	ADRESL,0
		bcf	STATUS,RP0
		addwf	val,1
		btfsc	STATUS,C
		INCF	val1,1	

		MOVLW	decimal_top & 0ffh	; 格納場所初期値
		MOVWF	FSR
		bsf	STATUS,IRP			; ＩＲＰ＝１
		MOVLW	HIGH (divide16)
		MOVWF	PCLATH

		call	divide16
ad_in1
		MOVLW	HIGH (put_decimal16)
		MOVWF	PCLATH

		call	put_decimal16			; 10進数に変換
		MOVLW	HIGH (ad_in1)
		MOVWF	PCLATH
		goto	ctrl_next



;-----------------------------------------------------------------------------------
;	SOCKET STATUS
ctrl_code5
		MOVLW	7FH		
		ANDWF	getmes_wk1,1
		swapf	getmes_wk1,1	
		movf	getmes_wk1,0	
		movwf	FSR
		bsf	STATUS,IRP
		
;		movlw	put_socket_stat >> 8	
;		MOVWF	PCLATH
;		call	put_socket_stat			; socketステータスを表示
		bcf	STATUS,IRP
		goto	ctrl_next
;--------------------------------------------------------------------------
;	TRIS
;	入力・出力の表示
ctrl_code4
		MOVLW	7FH		
		ANDWF	getmes_wk1,1
		MOVF	getmes_wk1,0
		MOVWF	FSR
		SWAPF	FSR,1		
		MOVLW	0FH		
		ANDWF	FSR,1
		MOVLW	PORTA | 80H	
		ADDWF	FSR,1
		
		MOVF	getmes_wk1,0
		call	getbitpos
		MOVF	INDF,0		
		ANDWF	data0,1
		BTFSC	3,2		
		GOTO	ctrl_out
		goto	ctrl_in
;
;		ビット位置返す
;
getbitpos
		movwf	wk
		MOVLW	1	
		MOVWF	data0
		MOVLW	07H		
		ANDWF	wk,1
		BTFSC	3,2		
		GOTO	getbitpos9
getbitpos0
		BCF	3,0	
		RLF	data0,1	
		DECFSZ	wk,1		
		GOTO	getbitpos0
getbitpos9	RETURN


;-----------------------------------------------------------------------------------
;	PARALLEL
;	現在のHigh/Lowの表示
ctrl_code3
		MOVLW	7FH		
		ANDWF	getmes_wk1,1
		MOVF	getmes_wk1,0
		MOVWF	FSR
		SWAPF	FSR,1		
		MOVLW	0FH		
		ANDWF	FSR,1
		BTFSS	3,2		
		GOTO	ctrl_code31

		MOVLW	80h | PORTA
		ADDWF	FSR,1
		MOVF	getmes_wk1,0
		call	getbitpos
		
		MOVF	INDF,0
		andwf	data0,0				; TRIS_RAのチェック
		BTFSC	3,2			; 出力ピン？
		GOTO	ctrl_code32

		MOVLW	1FH		
		MOVWF	PCLATH
		call	getadtable
		MOVWF	wk	
		MOVLW	HIGH (ctrl_code3)
		MOVWF	PCLATH
		
		MOVF	wk,0		
		ANDWF	data0,1
		BTFSS	3,2		; 1ならアナログ入力
		GOTO	ad_in
;
;
ctrl_code32
		CLRF	FSR		
ctrl_code31	MOVLW	PORTA				; + 05h
		ADDWF	FSR,1

		MOVF	getmes_wk1,0
		call	getbitpos
		MOVF	INDF,0		
		ANDWF	data0,1
		BTFSC	3,2		
		GOTO	ctrl_low
		goto	ctrl_high

;-----------------------------------------------------------------------------------
;	ショートメッセージの取得
get_short_mes
		MOVLW	1FH		; バンク＝1h
		MOVWF	PCLATH
		MOVF	wk,0			
		MOVWF	PCL
ctrl_out
		movlw	mes_out & .255	; 'OUT'
		goto	put_short_mes10
ctrl_in
		movlw	mes_in & .255	; 'IN'
		goto	put_short_mes10
ctrl_high
		movlw	mes_high & .255	; 'HIGH'
		goto	put_short_mes10
ctrl_low
		movlw	mes_low & .255	; 'LOW'
		goto	put_short_mes10
put_short_mes10
		MOVWF	wk		
put_short_mes0
		call	get_short_mes
		MOVWF	data0		
		MOVLW	HIGH (put_short_mes0)
		MOVWF	PCLATH		; PCLATHの修正
		
		MOVLW	0			; NULL?
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	ctrl_next
		MOVF	data0,0
		call	assert_wr2		; RTL8019へ転送
		
		INCF	wk,1		;			; wk++
		goto	put_short_mes0
;
;		META CHARACTER
ctrl_code2
		MOVLW	HIGH (ctrl_code1)
		MOVWF	PCLATH

		MOVF	getmes_wk1,0
		andlw	7fh
		addlw	-'0'			;不明
		
		call	ctrl_code1			; コントロール文字出力ルーチンへ
		MOVLW	HIGH (ctrl_code2)
		MOVWF	PCLATH
ctrl_next
		MOVLW	1			; ind++
		ADDWF	ind,1
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		btfsc	STATUS,C
		INCF	EEADRH,1
		goto	send_mes0

;-----------------------------------------------------------------------------------
;		ソケットの作成
;
no_socket
		btfss	tcp_flags,TCP_SYN
		RETURN
;
;	SYNパケットの受信→SYN+ACKの送信
;
recv_syn
		MOVLW	HIGH (socket_entry)
		MOVWF	PCLATH

		call	socket_entry			; ソケットのエントリーを検索
		MOVLW	HIGH (recv_syn)
		MOVWF	PCLATH
		btfsc	STATUS,C
		goto	send_rst			; ソケットの空きなし
		
				;
		MOVLW	0
		MOVWF	ip_length
				; IPヘッダ=20+24
		MOVLW	.20 + .24
		MOVWF	ip_length1
		
		MOVLW	TCP_PROTO		; TCP packet
		MOVWF	proto
		call	prepare_ip
;
	
;-------
		MOVLW	PACKET_SIZE + IP_SIZE	;mov	remote_adr[0],#PACKET_SIZE + IP_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	.20 + .4
		MOVWF	remote_len
		MOVLW	0
		MOVWF	remote_len1

;-------		
		
		call	remote_write
		
		call	clear_sum			; チェックサムの値をクリア
		
		MOVLW	http_port & 0ffh
		MOVWF	FSR
		movlw	2
		call	transmit_nbytes			; 自分のポート番号
		
		MOVLW	tcp_src_port
		MOVWF	FSR
		movlw	2
		call	transmit_nbytes			; 相手のポート番号

		MOVLW	seq_no
		MOVWF	FSR
		movlw	4
		call	transmit_nbytes			; 自分のＳＥＱＮＯ
		
		
		call	inc_ack_no		; tcp_seq_no++;
		
		MOVF	com_fsr,0
		MOVWF	FSR
		MOVLW	.8
		ADDWF	FSR,1

		bsf	STATUS,IRP
		bsf	STATUS,RP0
		MOVF	seq_no,0	; 自分のSEQ NOを自分のソケット＋８に
		MOVWF	INDF
		INCF	FSR,1
		MOVF	seq_no1,0
		MOVWF	INDF
		INCF	FSR,1
		MOVF	seq_no2,0
		MOVWF	INDF
		INCF	FSR,1
		MOVF	seq_no3,0	
		MOVWF	INDF
		INCF	FSR,1
		bcf	STATUS,RP0
		
		MOVF	tcp_seq_no,0	
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_seq_no1,0
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_seq_no2,0
		MOVWF	INDF
		INCF	FSR,1
		;mov	INDF,tcp_seq_no[3]
		MOVF	tcp_seq_no3,0
		MOVWF	INDF
		bcf	STATUS,IRP
	
		MOVF	com_fsr,0
		MOVWF	FSR
		MOVLW	.8
		ADDWF	FSR,1
		call	inc_seq_no
		
		MOVLW	tcp_seq_no
		MOVWF	FSR
		movlw	4
		call	transmit_nbytes		; 相手のＳＥＱＮＯ＋１
		
		movlw	60h			; オプション有り
		call	assert_wr
		movlw	B'010010'			; ACK+SYN
		call	assert_wr
		
		movlw	08h			; window(high)
		call	assert_wr
		movlw	00h			; window(low)
		call	assert_wr
		
		call	assert_wr2times		; tcp sum
		call	assert_wr2times		; 緊急ポインタ
		
		movlw	2h
		call	assert_wr		
		movlw	4h
		call	assert_wr		
		movlw	5h
		call	assert_wr		
		movlw	0b4h
		call	assert_wr		
		
		call	calc_tcp_sum		; TCP SUMの計算
		
		MOVLW	4h
		MOVWF	PORTC
		movlw	PAGE_BEGIN		; transmit page is start page 
		call	assert_wr0
		
		MOVLW	5
		MOVWF	PORTC
		movlw	.60			; 60バイト送信
		call	assert_wr0
		
		MOVLW	6
		MOVWF	PORTC
		DB	01,00		;clrw
		call	assert_wr0
		call	transmit		; 送信！

		call	next_seq_no		; seq_no++
		RETURN

;-----------------------------------------------------------------------------------
;		チェックサム計算
calc_tcp_sum
		CLRF	bytes		;clr	bytes	;２バイトアラインの調整
		
		MOVLW	this_ip		;mov	fsr,#this_ip; 自分のＩＰアドレスを加算
		
		MOVWF	FSR
		MOVF	INDF,0
		call	calc_sum
		INCF	FSR,1
		MOVF	INDF,0
		call	calc_sum
		INCF	FSR,1
		MOVF	INDF,0
		call	calc_sum
		INCF	FSR,1
		MOVF	INDF,0
		call	calc_sum
	
		MOVF	ip_src,0		; 相手のＩＰアドレスを加算
		call	calc_sum
		MOVF	ip_src1,0
		call	calc_sum
		MOVF	ip_src2,0
		call	calc_sum
		MOVF	ip_src3,0
		call	calc_sum
		
		DB	01,00		;clrw				; プロトコル番号を加算
		call	calc_sum
		MOVLW	TCP_PROTO
		call	calc_sum
		
		MOVF	remote_len1,0	; バイト数を加算
		call	calc_sum
		MOVF	remote_len,0
		call	calc_sum
		
	
;-------
		MOVLW	PACKET_SIZE + IP_SIZE + .16
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

;-------		
		
		call	set_checksum		; RTL8019バッファに設定
		RETURN



;===================================================================================
;		ＮＩＣの初期化ルーチン
;===================================================================================
initialize
		call	init_nic			; ＮＩＣリセット
		call	getmac				; ＭＡＣアドレス取得
		call	setmac				; ＭＡＣアドレスセット
							; リングバッファ初期化
		bsf	STATUS,RP0
		MOVLW	fifo_top		
		MOVWF	fifo_buff
		MOVWF	fifo_poi			
		MOVWF	fifo_line		 
		
		clrF	fifo_cn
		clrF	fifo_line_cn
		bcf	STATUS,RP0
		
		RETURN



;-----------------------------------------------------------------------------------
;		RTL8019のリセット
;-----------------------------------------------------------------------------------
reset_nic
		clrF	PORTC
		movlw	21h
		call	assert_wr0		; STOP OPERATION
		
		MOVLW	1Fh
		MOVWF	PORTC
		call	assert_rd		; 1ehを読む
		
		MOVLW	1Fh
		MOVWF	PORTC
		MOVF	data0,0
		call	assert_wr0		; それを書き戻す（RESET)
reset_nic0
		MOVLW	07h
		MOVWF	PORTC
		call	assert_rd		; ステータスを読む
		
		btfss	data0,7			;data.7	; RESET 終了チェック
		goto	reset_nic0
		RETURN


;-----------------------------------------------------------------------------------
;		RTL8019の初期化
;-----------------------------------------------------------------------------------
init_nic
		call	reset_nic
		
		MOVLW	0eh			; DCR(Data Conifguration Register)
		MOVWF	PORTC
		movlw	68h
		call	assert_wr0
		
		MOVLW	0ah
		MOVWF	PORTC
		DB	01,00		;clrw
		call	assert_wr0		; for over flow
		
		MOVLW	0bh
		MOVWF	PORTC
		DB	01,00		;clrw
		call	assert_wr0		; for over flow
		
		MOVLW	01h
		MOVWF	PORTC
		movlw	PAGE_START		; PAGE START
		call	assert_wr0
		
		MOVLW	02h
		MOVWF	PORTC
		movlw	PAGE_STOP		; PAGE STOP
		call	assert_wr0
		
		MOVLW	03h
		MOVWF	PORTC
		movlw	PAGE_START		; BDRY
		call	assert_wr0
		
		MOVLW	0ch			; RCR
		MOVWF	PORTC
		movlw	0h	;	20h
		call	assert_wr0
		
		MOVLW	0dh			; TCR
		MOVWF	PORTC
		movlw	2			; LOOPBACK
		call	assert_wr0

		MOVLW	0fh			; IMR
		MOVWF	PORTC
		movlw	B'11111'
		call	assert_wr0
		
		MOVLW	7			; ISR
		MOVWF	PORTC
		movlw	0ffh
		call	assert_wr0

		clrF	PORTC			; CR(Command Regster)
		movlw	22h			; START OPERATION with L/B
		call	assert_wr0
		RETURN

;-----------------------------------------------------------------------------------
;		ＭＡＣアドレス取得
;-----------------------------------------------------------------------------------
getmac
		clrF	PORTC
		movlw	22h
		call	assert_wr0
		
		CLRF	remote_adr 
		CLRF	remote_adr1	 
		MOVLW	.12	 	;12bytes転送
		MOVWF	remote_len
		clrF	remote_len1	 
		call	remote_read

		MOVLW	6			; MACアドレスは６バイト
		MOVWF	gcn1
		MOVLW	mymac		; アドレスにmymacに設定
		MOVWF	FSR
get_mac0
		MOVLW	10h
		MOVWF	PORTC
		call	assert_rd		; から読み
		call	assert_rd		; 
		
		MOVF	data0,0	;mov	INDF,data		; MACアドレスをPICに読み込む
		MOVWF	INDF
		INCF	FSR,1
		DECFSZ	gcn1,1	 
		GOTO	get_mac0
		RETURN



;-----------------------------------------------------------------------------------
;		ＭＡＣアドレス設定
;-----------------------------------------------------------------------------------
setmac
;	PAGE 1
		clrF	PORTC
		movlw	B'01100010'
		call	assert_wr0
;
		MOVLW	01h
		MOVWF	PORTC
		MOVLW	mymac
		MOVWF	FSR
		MOVLW	6			; MACアドレスは６バイト
		MOVWF	gcn1
setmac0
		MOVF	INDF,0
		call	assert_wr0		; MACアドレスの設定
		INCF	FSR,1
		INCF	PORTC,1
		DECFSZ	gcn1,1	 
		GOTO	setmac0
		MOVLW	7
		MOVWF	PORTC
		movlw	PAGE_START + 1		; ついでに
		call	assert_wr0		; カレントページのセット
		
		MOVLW	8
		MOVWF	PORTC
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		INCF	PORTC,1	 
		DB	01,00		;clrw
		call	assert_wr0
		
		clrF	PORTC
		movlw	22h
		call	assert_wr0
		RETURN



;-----------------------------------------------------------------------------------
;		リモートＤＭＡ書き込み準備
;-----------------------------------------------------------------------------------
remote_write
		MOVLW	8
		MOVWF	PORTC
		MOVF	remote_adr,0
		call	assert_wr0
		
		MOVLW	9
		MOVWF	PORTC
		MOVF	remote_adr1,0
		call	assert_wr0
		
		MOVLW	0ah
		MOVWF	PORTC
		MOVF	remote_len,0
		call	assert_wr0
		
		MOVLW	0bh
		MOVWF	PORTC
		MOVF	remote_len1,0
		call	assert_wr0
		
		clrF	PORTC
		movlw	B'00010010'
		call	assert_wr0		; write now!
		MOVLW	10h
		MOVWF	PORTC
		RETURN


;-----------------------------------------------------------------------------------
;		リモートＤＭＡ読み込み準備
;-----------------------------------------------------------------------------------
remote_read
		MOVLW	8
		MOVWF	PORTC
		MOVF	remote_adr,0
		call	assert_wr0
		
		MOVLW	9
		MOVWF	PORTC
		MOVF	remote_adr1,0
		call	assert_wr0
		
		MOVLW	0ah
		MOVWF	PORTC
		MOVF	remote_len,0
		call	assert_wr0
		
		MOVLW	0bh
		MOVWF	PORTC
		MOVF	remote_len1,0
		call	assert_wr0
		
		clrF	PORTC
		movlw	B'00001010'
		call	assert_wr0		; read now!
		MOVLW	10h
		MOVWF	PORTC
		RETURN

;-----------------------------------------------------------------------------------
;		チェックサムの計算
;-----------------------------------------------------------------------------------
calc_sum
		BTFSS	bytes,0		;btfss	bytes.0	;アラインメントチェック
		goto	calc_sum_high
;	LOWバイト
		ADDWF	sum,1	 ;データを(sum[1],sum[0])に加算
		movlw	1
		btfsc	STATUS,C
		addwf	sum1,1		 

		btfsc	STATUS,C			; １の補数の計算
		addwf	sum,1	 
		btfsc	STATUS,C
		addwf	sum1,1	 
		INCF	bytes,1	 	; アラインを次に
		RETURN
;	HIGHバイト
calc_sum_high
		ADDWF	sum1,1		  ; データを(sum[1],sum[0])に加算
		movlw	1
		
		btfsc	STATUS,C			; １の補数の計算
		ADDWF	sum,1		 
		btfsc	STATUS,C
		ADDWF	sum1,1		 
	
		INCF	bytes,1	 			; アラインを次に
		RETURN



assert_wr2times
		DB	01,00		;clrw
		call	assert_wr
		DB	01,00		;clrw
		goto	assert_wr
;-----------------------------------------------------------------------------------
;	送信データ=data
assert_wr2x
		MOVLW	1	 	; remote_len++
		ADDWF	remote_len,1
		btfsc	STATUS,C
		INCF	remote_len1,1	 
		MOVF	data0,0			; data変数を媒介
		goto	assert_wr
;	送信データ=W
assert_wr2	movwf	data0		; 一度しまう
		MOVLW	1	 	; remote_len++
		ADDWF	remote_len,1
		btfsc	STATUS,C
		INCF	remote_len1,1	 
		MOVF	data0,0
;-----------------------------------------------------------------------------------
;		RTL8019へ書き込み(チェックサム考慮)
;-----------------------------------------------------------------------------------HAVE
assert_wr
		MOVWF	PORTD	 
assert_wr_2	btfss	bytes,0		 
		goto	asser_wr_high
		
		ADDWF	sum,1		 
		movlw	1
		btfsc	STATUS,C
		ADDWF	sum1,1		 

		btfsc	STATUS,C
		ADDWF	sum,1	 
		btfsc	STATUS,C
		ADDWF	sum1,1	 
		
		INCF	bytes,1		 
		goto	assert_wr0_2
asser_wr_high
		ADDWF	sum1,1	 
		movlw	1
		
		btfsc	STATUS,C
		ADDWF	sum,1	 
		btfsc	STATUS,C
		ADDWF	sum1,1	 
	
		INCF	bytes,1	 
		goto	assert_wr0_2


;-----------------------------------------------------------------------------------
;		RTL8019へ単純書き込み
;-----------------------------------------------------------------------------------
assert_wr0
		movwf	PORTD	 
assert_wr0_2	bsf	STATUS,RP0
		clrF	PORTD	 			; ＲＤポート出力
		bcf	STATUS,RP0
		
		bcf	PORTE,1	 
		

		btfss	PORTC,5
		goto	$-1
		
		bsf	PORTE,1	 
		
		bsf	STATUS,RP0
		MOVLW	0FFH		 	;ＲＤポート入力
		MOVWF	PORTD
		bcf	STATUS,RP0
		RETURN


assert_rd
		bcf	PORTE,0
		
		btfss	PORTC,5			; ~Wait
		goto	$-1
		
		MOVF	PORTD,0		 
		MOVWF	data0
		bsf	PORTE,0
		RETURN



;-----------------------------------------------------------------------------------
;		パケット送信関連処理
;-----------------------------------------------------------------------------------
transmit_this_ip
		MOVLW	this_ip	 
		MOVWF	FSR
		movlw	4

transmit_nbytes
		movwf	gcn1
		MOVLW	10h
		MOVWF	PORTC
transmit0	MOVF	INDF,0
		call	assert_wr
		INCF	FSR,1
		DECFSZ	gcn1,1	 
		GOTO	transmit0
		RETURN


transmit_nbytes2
		movwf	gcn1
		MOVLW	10h
		MOVWF	PORTC
transmit2_0	MOVF	INDF,0
		call	assert_wr2
		INCF	FSR,1
		DECFSZ	gcn1,1		 
		GOTO	transmit2_0
		RETURN

;-----------------------------------------------------------------------------------
;		パケット送信
;-----------------------------------------------------------------------------------
transmit
retry
		clrF	PORTC
		call	assert_rd
		
		BTFSC	data0,2	 	; 送信ビットを見る
		goto	transmit			; 送信待ち
		
		clrF	PORTC
		movlw	B'00100110'			; 送信ビットを立てる
		call	assert_wr0			; 送信！
trans100
		MOVLW	4
		MOVWF	PORTC
		call	assert_rd
		
		btfsc	data0,0	 
		goto	transmit9			; 送信完了？
		btfsc	data0,3	 
		goto	retry
		
		goto	trans100
transmit9	RETURN


 
;-----------------------------------------------------------------------------------
;		Ethernetヘッダを作成する。
;-----------------------------------------------------------------------------------
prepare_ether2
		movlw	PACKET_SIZE + ARP_SIZE
		MOVWF	remote_len
		GOTO	prepare_ether1
prepare_ether
	;	call	wait_transmit			; 送信中待ちを行う
		movlw	PACKET_SIZE + IP_SIZE
		MOVWF	remote_len
prepare_ether1
		CLRF	remote_len1
		CLRF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1


 
		call	remote_write
		
		MOVLW	10h			; このパケットを送ってくれた相手のＭＡＣ
		MOVWF	PORTC
		MOVLW	eth_src
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes
		
		MOVLW	mymac		; 自分のＭＡＣアドレスを設定
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes
		RETURN


;-----------------------------------------------------------------------------------
;		ＩＰヘッダ作成作業
;-----------------------------------------------------------------------------------
prepare_ip
		call	prepare_ether
		movlw	COM_PROTO
		call	assert_wr
		movlw	IP_PROTO
		call	assert_wr
		
		call	ip_common
		
 
		MOVLW	ip_sum - ip_header + PACKET_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1


 		
	;	goto	set_checksum
set_checksum
		COMF	sum,1	 
		COMF	sum1,1	 
		
		MOVLW	2	 	;チェックサムは２バイトである
		MOVWF	remote_len
		CLRF	remote_len1	 
		call	remote_write
		
		MOVLW	10h
		MOVWF	PORTC
		MOVF	sum1,0
		call	assert_wr0			; チェックサムの書き込み(assert_wr0をコールしなければならない)
		MOVF	sum,0
		call	assert_wr0
		RETURN



;-----------------------------------------------------------------------------------
;		ＩＰプロトコルヘッダ作成
;-----------------------------------------------------------------------------------
ip_common
		call	clear_sum			; チェックサムの値をクリア
		
		MOVLW	10h
		MOVWF	PORTC
		movlw	45h			; ID
		call	assert_wr
		movlw	00h			; TOS
		call	assert_wr
		
		MOVF	ip_length,0			; length high
		call	assert_wr
		MOVF	ip_length1,0			; length low
		call	assert_wr
		
		MOVLW	ident
		MOVWF	FSR
		MOVF	INDF,0			; Seq No High
		call	assert_wr
		INCF	FSR,1
		
		MOVF	INDF,0			; Seq No Low
		call	assert_wr
		MOVLW	1		 
		ADDWF	INDF,1
		decF	FSR,1
		btfsc	STATUS,C
		addwf	INDF,1

		movlw	00h			; flagment(2bytes)
		call	assert_wr
		movlw	00h			;
		call	assert_wr
		
		movlw	0ffh			; TTL
		call	assert_wr
		
		MOVF	proto,0			; PROTOCOL = anything
		call	assert_wr
		
		call	assert_wr2times			; sum is zero
		
		call	transmit_this_ip
		
		MOVLW	ip_src			; to IP
		MOVWF	FSR
		movlw	4
		call	transmit_nbytes
		RETURN




;-----------------------------------------------------------------------------------
;		パラレルＩ／Ｆの制御
;-----------------------------------------------------------------------------------
		org	820h
udp_parallel
		MOVLW	$ >> 8
		MOVWF	PCLATH
		MOVLW	udp_data
		MOVWF	FSR
		
		MOVLW	6	 
		SUBWF	INDF,0
		BTFSC	3,0
		GOTO	main90
		MOVF	INDF,0
		INCF	FSR,1
		ADDWF	2,1	 
		goto	para_get_status			; ステータスの取得
		goto	para_set_high			; Ｈｉｇｈ設定
		goto	para_set_low			; Ｌｏｗ設定
		goto	para_set_whole			; 全設定
		goto	para_get_adc			; A/D変換
		goto	para_set_rbpu			; 内蔵プルアップOn/Off
;
;	HIGH/INPUTにセット
para_set_high
		call	para_set_common
		MOVF	wk1,0	 
		IORWF	INDF,1
		goto	para_get_status
;
;	LOW/OUTPUTにセット
para_set_low
		call	para_set_common
		COMF	wk1,1	 
		MOVF	wk1,0	 
		ANDWF	INDF,1
		goto	para_get_status
;
;	ビット位置の計算
para_set_common
		INCF	FSR,1
		MOVF	INDF,0	 	;ビット位置(0-7)
		MOVWF	wk
		MOVLW	1 
		MOVWF	wk1
para_set_common0
		MOVLW	0 
		SUBWF	wk,0
		BTFSC	3,2
		GOTO	para_set_common9
		BCF	3,0	 
		RLF	wk1,1 
		DECF	wk,1 
		goto	para_set_common0
para_set_common9
		decF	FSR,1
		MOVF	INDF,0		; I/Oポート番号
		MOVWF	FSR
		RETURN
;
;	SET WHOLEモード
para_set_whole
		MOVF	INDF,0	 	; ポート
		MOVWF	ptr
		INCF	FSR,1
		MOVF	INDF,0 		; サイズ
		MOVWF	gcn1
		INCF	FSR,1
para_set_whole0
		MOVF	INDF,0	 		; Mask
		MOVWF	wk
		INCF	FSR,1
		MOVF	INDF,0 
		MOVWF	wk1
		INCF	FSR,1
		
		MOVF	FSR,0 		; save FSR
		MOVWF	wk2
		MOVF	ptr,0
		MOVWF	FSR
		MOVF	INDF,0
		ANDWF	wk,0 
		IORWF	wk1,0	 
		movwF	INDF		; *ptr = (*ptr & Mask) | Value
		MOVF	wk2,0		; restore FSR
		MOVWF	FSR
		
		INCF	ptr,1 
		DECFSZ	gcn1,1	 
		GOTO	para_set_whole0
		goto	para_get_status


;
; 内蔵プルアップOn/Off
para_set_rbpu
		bsf	STATUS,RP0
		MOVLW	0 
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	para_set_rbpu1
		BSF	OPTION_REG,7     ;プルアップしない
		goto	para_set_rbpu9
para_set_rbpu1
		BCF	OPTION_REG,7   ; プルアップする
para_set_rbpu9	bcf	STATUS,RP0
		goto	para_get_status



;-----------------------------------------------------------------------------------
para_get_adc
		MOVF	INDF,0 		; ADCON1の設定
		MOVWF	ADCON1
		BSF	ADCON1,0 
		INCF	FSR,1
		
		MOVF	INDF,0 		;アクイジションタイム待機
		MOVWF	wait_cn
para_get_aqu0
		MOVLW	8	 
		MOVWF	wait_cn2
		DECFSZ	wait_cn2,1 
		GOTO	$-1
		DECFSZ	wait_cn,1 		; 25μs×WaitTime
		GOTO	para_get_aqu0
		BSF	ADCON1,2 	 ; ＡＤ変換開始
		BTFSC	ADCON1,2 	; ＡＤ変換待ち(同期式）
		goto	$-1 		; 本当は非同期にしたいところ(^_^;
		
		CLRF	PCLATH
para_get_status
		MOVLW	para_port	 ; 送信元ポート番号
		MOVWF	wk2
common_get_status
		CLRF	ip_length	 
	 
		MOVLW	IP_SIZE + UDP_SIZE + PARALLEL_PACKET_SIZE
		MOVWF	ip_length1
		
		CLRF	PCLATH
		
		MOVLW	UDP_PROTO		; UDP packet
		MOVWF	proto
		call	prepare_ip			; ＩＰパケットまで作成
		
		call	clear_sum			; チェックサムの値をクリア
		
 
		MOVLW	PACKET_SIZE+IP_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	(UDP_SIZE + PARALLEL_PACKET_SIZE) & 0ffh
		MOVWF	remote_len
		MOVLW	HIGH (UDP_SIZE + PARALLEL_PACKET_SIZE)
		MOVWF	remote_len1
 
		call	remote_write
		
		MOVLW	10h
		MOVWF	PORTC
		
		MOVF	wk2,0		;para_port
		MOVWF	FSR
		MOVF	INDF,0			; From PORT #(HIGH)
		call	assert_wr
		INCF	FSR,1
		MOVF	INDF,0			; From PORT #(LOW)
		call	assert_wr
		
		MOVF	udp_src_port,00		; To PORT #
		call	assert_wr
		MOVF	udp_src_port1,0
		call	assert_wr
		
 		MOVLW	HIGH (UDP_SIZE + PARALLEL_PACKET_SIZE)
		call	assert_wr
		movlw	(UDP_SIZE + PARALLEL_PACKET_SIZE) & 0ffh ; UDP DATAGRAM SIZE
		call	assert_wr
		
		call	assert_wr2times			; sum(not fixed)
 		
		MOVF	PORTA,0
		call	assert_wr			; 
		MOVF	PORTB,0
		call	assert_wr			; 
		
		MOVLW	80h + PORTA			;ra
		MOVWF	FSR
		MOVF	INDF,0
		call	assert_wr			; 
		INCF	FSR,1
		MOVF	INDF,0
		call	assert_wr			; 
		
		MOVF	ADRESH,0 
		MOVWF	val1			; 変換結果をval[1]:val[0]へ
		bsf	STATUS,RP0
		MOVF	ADRESL,0			;adres,0; page1は下位バイト
		bcf	STATUS,RP0
		MOVWF	val		 
		
		MOVF	val1,0
		call	assert_wr			; AD 変換結果(H)
		MOVF	val,0
		call	assert_wr			; AD 変換結果(L)
		
		bsf	STATUS,RP0
		MOVF	ADCON1,0
		bcf	STATUS,RP0
		call	assert_wr			;
		movlw	0				; Reserved
		call	assert_wr			;
		
		MOVLW	HIGH (calc_udp_sum)
		MOVWF	PCLATH

		call	calc_udp_sum
		MOVLW	HIGH (transmit_60bytes)
		MOVWF	PCLATH

		call	transmit_60bytes
main90		
		MOVLW	HIGH (main9)
		MOVWF	PCLATH

		goto	main9


;-----------------------------------------------------------------------------------
;		ＵＤＰチェックサム計算＋送信
;
calc_udp_sum
		CLRF	PCLATH
		CLRF	bytes		;clr	bytes ; ２バイトアラインの調整
		MOVLW	this_ip	 	; 自分のＩＰアドレスを加算
		MOVWF	FSR
		
		MOVF	INDF,0
		call	calc_sum
		INCF	FSR,1
		MOVF	INDF,0
		call	calc_sum
		INCF	FSR,1
		MOVF	INDF,0
		call	calc_sum
		INCF	FSR,1
		MOVF	INDF,0
		call	calc_sum
	
		MOVF	ip_src,0		; 相手のＩＰアドレスを加算
		call	calc_sum
		MOVF	ip_src1,0
		call	calc_sum
		MOVF	ip_src2,0
		call	calc_sum
		MOVF	ip_src3,0
		call	calc_sum
	
		DB	01,00		;clrw				; プロトコル番号を加算
		call	calc_sum
		MOVLW	UDP_PROTO
		call	calc_sum
		
		MOVF	remote_len1,0		;#PARALLEL_PACKET_SIZE>>8
		call	calc_sum
		MOVF	remote_len,0		;#PARALLEL_PACKET_SIZE & 0ffh
		call	calc_sum

	 	; チェックサムのセット位置
 
		MOVLW	PACKET_SIZE+IP_SIZE + 6
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

 		call	set_checksum
		RETURN

transmit_60bytes
		CLRF	PCLATH
		
		MOVLW	4h
		MOVWF	PORTC
		movlw	PAGE_BEGIN			; transmit page is start page 
		call	assert_wr0
		
		MOVLW	5
		MOVWF	PORTC
		movlw	.60		; 基本的に６０バイトとする。(PARALLEL_PACKET_SIZE+IP_SIZE+PACKET_SIZE) & 0ffh
		call	assert_wr0
		
		MOVLW	6
		MOVWF	PORTC
		movlw	0		; (PARALLEL_PACKET_SIZE+IP_SIZE+PACKET_SIZE) >> 8
		call	assert_wr0
		
		call	transmit
		RETURN

;-----------------------------------------------------------------------------------
;		シリアルポート処理
;
udp_serial
		bsf	STATUS,RP0
		BSF	STATUS,RP1
		movlw	.16
		MOVwf	transmitted & 0ffh
		clrf	STATUS

		MOVF	udp_length,0 
		MOVWF	remote_len1
		MOVF	udp_length1,0 
		MOVWF	remote_len

		MOVLW	8	 
		SUBWF	remote_len,1
		btfss	STATUS,C
		DECF	remote_len1,1 
		
		MOVLW	HIGH (get_dgram)
		MOVWF	PCLATH

		call	get_dgram
		MOVLW	$>>8		;HIGH (udp_serial)
		MOVWF	PCLATH
		
		btfsc	STATUS,C
		goto	main90
		
		MOVF	data0,0	 
		MOVWF	udp_data
		MOVLW	4	 
		SUBWF	data0,0
		BTFSC	3,0
		GOTO	main90
		MOVF	data0,0
		ADDWF	2,1 
		goto	ser_get_status		; ステータス表示
		goto	ser_register_tag	; アドレス登録
		goto	ser_unregister_tag	; アドレス削除
		goto	ser_transmit		; データ送信
;
;		ＡＲＰ応答受信処理
ser_arp
		bcf	STATUS,IRP
		MOVLW	arp_src_mac & 0ffh
		MOVWF	FSR

		bsf	STATUS,RP0
		bsf	STATUS,RP1
		MOVF	INDF,0	 
		MOVWF	on_ether & 0FFH	; ハードウェアアドレスをセット
		INCF	FSR,1
		MOVF	INDF,0	 
		MOVWF	on_ether1 & 0FFH
		INCF	FSR,1
		MOVF	INDF,0 
		MOVWF	on_ether2 & 0FFH
		INCF	FSR,1
		MOVF	INDF,0 
		MOVWF	on_ether3 & 0FFH
		INCF	FSR,1
		MOVF	INDF,0	 
		MOVWF	on_ether4 & 0FFH
		INCF	FSR,1
		MOVF	INDF,0	 
		MOVWF	on_ether5 & 0FFH
		CLRF	STATUS	 
 
		
		bsf	RCSTA,4		;cren
		bsf	INTCON,6	;peie			; 使用許可
		MOVLW	HIGH (main9)
		MOVWF	PCLATH

		goto	main9

;-----------------------------------------------------------------------------------
;		ホストへシリアルポートのステータスを送信する。
;-----------------------------------------------------------------------------------
ser_get_status
		CLRF	ip_length 
 		MOVLW	IP_SIZE + UDP_SIZE + SERIAL_PACKET_SIZE
		MOVWF	ip_length1

		CLRF	PCLATH
		
		MOVLW	UDP_PROTO		; UDP packet
		MOVWF	proto
		call	prepare_ip			; ＩＰパケットまで作成
		
		call	clear_sum			; チェックサムの値をクリア
		
 
		MOVLW	PACKET_SIZE+IP_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	(UDP_SIZE + SERIAL_PACKET_SIZE) & 0ffh
		MOVWF	remote_len
		MOVLW	HIGH (UDP_SIZE + SERIAL_PACKET_SIZE)
		MOVWF	remote_len1

;-------		
		call	remote_write
		
		MOVLW	10h
		MOVWF	PORTC
		
		MOVLW	serial_port
		MOVWF	FSR
		MOVF	INDF,0			; From PORT #(HIGH)
		call	assert_wr
		INCF	FSR,1
		MOVF	INDF,0			; From PORT #(LOW)
		call	assert_wr
		
		MOVF	udp_src_port,0		; To PORT #
		call	assert_wr
		MOVF	udp_src_port1,0
		call	assert_wr
		
		movlw	HIGH (UDP_SIZE + SERIAL_PACKET_SIZE)
		call	assert_wr
		movlw	(UDP_SIZE + SERIAL_PACKET_SIZE) & 0ffh ; UDP DATAGRAM SIZE
		call	assert_wr
		
		call	assert_wr2times			; sum(not fixed)
;
;		DGRAM
;
		CLRF	PCLATH
		
		MOVF	udp_data,0
		call	assert_wr			; sum(not fixed)
		
		bsf	STATUS,IRP
		MOVLW	transmitted & 0ffh
		movwf	FSR
		movf	INDF,0
		call	assert_wr
		MOVLW	on_ether & 0ffh
		MOVWF	FSR
		movlw	SERIAL_PACKET_SIZE-2
		call	transmit_nbytes
		bcf	STATUS,IRP
		
		MOVLW	HIGH (calc_udp_sum)
		MOVWF	PCLATH

		call	calc_udp_sum
		MOVLW	HIGH (transmit_60bytes)
		MOVWF	PCLATH

		call	transmit_60bytes

		MOVLW	HIGH (main9)
		MOVWF	PCLATH

		goto	main9

;-----------------------------------------------------------------------------------
ser_transmit
		bsf	STATUS,RP0
		bsf	STATUS,RP1
		CLRF	transmitted & 0ffh
		clrf	STATUS
ser_transmit0
		MOVLW	get_dgram >> 8
		movwf	PCLATH
		CALL	get_dgram
		MOVLW	$ >> 8
		MOVWF	PCLATH
		BTFSC	STATUS,C
		GOTO	ser_transmit9
		
		BSF	STATUS,RP0
		BSF	STATUS,RP1
		BTFSS	on_flow,0
		GOTO	ser_transmit1

		CLRF	STATUS
		BTFSC	PORTB,0
		GOTO	ser_transmit9
ser_transmit1
		CLRF	STATUS
		CALL	async_transmit
		bsf	STATUS,RP0
		BSF	STATUS,RP1
		INCF	transmitted,1
		clrf	STATUS
		GOTO	ser_transmit0
ser_transmit9
		MOVLW	HIGH (ser_get_status)
		MOVWF	PCLATH

		goto	ser_get_status

;-----------------------------------------------------------------------------------
ser_register_tag
		MOVLW	4+2			; 6バイトを読み込む
		MOVWF	gcn1
		MOVLW	udp_data+1
		MOVWF	FSR
		MOVLW	HIGH (copy_toram)
		MOVWF	PCLATH

		call	copy_toram
		
		MOVLW	HIGH (ser_register)
		MOVWF	PCLATH

		goto	ser_register

;-----------------------------------------------------------------------------------
ser_unregister_tag
		MOVLW	HIGH (ser_unregister)
		MOVWF	PCLATH

		goto	ser_unregister


;-----------------------------------------------------------------------------------
;		受信したパケットのソケットが有るかをチェック
;-----------------------------------------------------------------------------------
search_socket
		bsf	STATUS,IRP
		MOVLW	SOCKETS		;mov	com_cn,#SOCKETS
		MOVWF	com_cn
		MOVLW	skb & 0ffh		;mov	com_fsr,#0a0h
		MOVWF	com_fsr
search_socket0
		MOVF	com_fsr,0
		MOVWF	FSR
		BTFSS	INDF,7	 
		goto	search_socket9
		
		MOVLW	.2
		ADDWF	FSR,1
		MOVF	ip_src,0 
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	search_socket9
		INCF	FSR,1
		MOVF	ip_src1,0 
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	search_socket9
		INCF	FSR,1
		MOVF	ip_src2,0 
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	search_socket9
		INCF	FSR,1
		MOVF	ip_src3,0 
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	search_socket9
		INCF	FSR,1
		
 
		MOVF	tcp_src_port,0
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	search_socket9
		INCF	FSR,1
 
		MOVF	tcp_src_port1,0	
		SUBWF	INDF,0
		BTFSS	3,2
		GOTO	search_socket9
		INCF	FSR,1
		
		MOVLW	.7
		SUBWF	FSR,1
		MOVLW	0F0H 
		IORWF	INDF,1
		decF	FSR,1
		BSF	3,0	 
		RETURN
search_socket9
		MOVLW	10H	 
		ADDWF	com_fsr,1
		DECFSZ	com_cn,1 
		GOTO	search_socket0
		bcf	STATUS,IRP
		BCF	3,0	 
		RETURN


;-----------------------------------------------------------------------------------
;		ソケットの新規作成
;-----------------------------------------------------------------------------------
socket_entry
		bsf	STATUS,IRP
		MOVLW	skb & 0ffh
		MOVWF	FSR
		MOVF	FSR,0	 
		MOVWF	com_fsr
		MOVLW	SOCKETS	 
		MOVWF	com_cn
entry0
		BTFSC	INDF,7	 
		goto	entry9
		
		MOVLW	SYN_RCVD
		MOVWF	INDF
		INCF	FSR,1
		MOVLW	0f0h
		MOVWF	INDF
		INCF	FSR,1
		MOVF	ip_src,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	ip_src1,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	ip_src2,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	ip_src3,0 
		MOVWF	INDF
		INCF	FSR,1
		
		MOVF	tcp_src_port,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_src_port1,0 
		MOVWF	INDF
		INCF	FSR,1
		
		MOVF	tcp_seq_no,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_seq_no1,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_seq_no2,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_seq_no3,0 
		MOVWF	INDF
		INCF	FSR,1

		MOVF	tcp_ack_no,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_ack_no1,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_ack_no2,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	tcp_ack_no3,0 
		MOVWF	INDF
		INCF	FSR,1
		bcf	STATUS,IRP
		BCF	3,0	 
		RETURN
entry9
		MOVLW	10h
		ADDWF	FSR,1

		MOVLW	10H	 
		ADDWF	com_fsr,1
		DECFSZ	com_cn,1 
		GOTO	entry0
		
socket_entry_99	bcf	STATUS,IRP
		BSF	3,0 
		RETURN


;-----------------------------------------------------------------------------------
;		Ethernetパケットのブロードキャスト送信処理
;-----------------------------------------------------------------------------------
broad_cast
		CLRF	PCLATH
 
		MOVLW	0
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	IP_SIZE + PACKET_SIZE
		MOVWF	remote_len
		MOVLW	0
		MOVWF	remote_len1
 
		call	remote_write
		
		MOVLW	10h			; 送信先：ff-ff-ff-ff-ff-ffに送信
		MOVWF	PORTC
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		
		MOVLW	mymac		; 送信元：自分のＭＡＣアドレスを設定
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes
		RETURN

bootp2
		call	broad_cast
		CLRF	PCLATH
		
		movlw	COM_PROTO
		call	assert_wr
		movlw	IP_PROTO
		call	assert_wr

		movlw	.255
		movwf	ip_src 	; 自分のＩＰは255.255.255.255として送信
		movwf	ip_src1	 
		movwf	ip_src2	 
		movwf	ip_src3	 
		
  
		MOVLW	HIGH (DHCP_SIZE+20)
		MOVWF	ip_length
 
		MOVLW	(DHCP_SIZE + .20) & 0FFH
		MOVWF	ip_length1
		
		MOVLW	UDP_PROTO
		MOVWF	proto
		call	ip_common
 
		MOVLW	ip_sum - ip_header + PACKET_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1
 		
		goto	set_checksum

bootp
		call	bootp2
		CLRF	PCLATH
		
		call	clear_sum			; チェックサムの値をクリア
 
		MOVLW	PACKET_SIZE+IP_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	DHCP_SIZE & 0ffh
		MOVWF	remote_len
		MOVLW	HIGH (DHCP_SIZE)
		MOVWF	remote_len1

;-------		
		call	remote_write
		
		MOVLW	10h
		MOVWF	PORTC
		
		movlw	0				; クライアントBOOTPポート
		call	assert_wr
		movlw	BOOTPC_PORT			; クライアントBOOTPポート
		call	assert_wr
		
		movlw	0				; サーバBOOTPポート
		call	assert_wr
		movlw	BOOTPS_PORT			; サーバBOOTPポート
		call	assert_wr
		
		movlw	HIGH (DHCP_SIZE)	;DHCP_SIZE>>8
		call	assert_wr
		movlw	DHCP_SIZE & 0ffh		; length
		call	assert_wr
		
		call	assert_wr2times			; sum
		
		movlw	1
		call	assert_wr			; Requare:1,Reply:2
		movlw	1
		call	assert_wr			; 10Mbps Ethernet:1
		movlw	6
		call	assert_wr			; EthernetLength:6
		DB	01,00		;clrw
		call	assert_wr			; Hop Count
		
		
		MOVLW	mymac + 2
		MOVWF	FSR
		MOVF	INDF,0
		call	assert_wr
		INCF	FSR,1
		MOVF	INDF,0
		call	assert_wr
		INCF	FSR,1
		MOVF	INDF,0
		call	assert_wr
		INCF	FSR,1
		MOVF	INDF,0
		call	assert_wr
		
		call	assert_wr2times
		call	assert_wr2times
		
		
		MOVLW	4*4
		MOVWF	gcn1
bootp_10	
		MOVLW	HIGH (assert_wr)
		MOVWF	PCLATH

		DB	01,00		;clrw
		call	assert_wr
		MOVLW	HIGH (bootp_10)
		MOVWF	PCLATH
		DECFSZ	gcn1,1		;djnz	gcn1,bootp_10
		GOTO	bootp_10
;
;	クライアントハードウェアアドレス
;
		MOVLW	mymac
		MOVWF	FSR
		MOVLW	HIGH (transmit_nbytes)
		MOVWF	PCLATH

		movlw	6
		call	transmit_nbytes
		MOVLW	HIGH (bootp_10)
		MOVWF	PCLATH
		
		MOVLW	.16 - .6
		MOVWF	gcn1
bootp_10_0
		MOVLW	HIGH (assert_wr)
		MOVWF	PCLATH

		DB	01,00		;clrw
		call	assert_wr
		MOVLW	HIGH (bootp_10_0)
		MOVWF	PCLATH
		DECFSZ	gcn1,1	 
		GOTO	bootp_10_0
;
;		起動ファイル名
;
		MOVLW	.128 + .64
		MOVWF	gcn1
bootp_20
		MOVLW	HIGH (assert_wr)
		MOVWF	PCLATH

		DB	01,00		;clrw
		call	assert_wr
		MOVLW	HIGH (bootp_20)
		MOVWF	PCLATH
		DECFSZ	gcn1,1	 
		GOTO	bootp_20
	;
	;	Magic
	;
		MOVLW	HIGH (assert_wr)
		MOVWF	PCLATH

		movlw	63h	; 99
		call	assert_wr
		movlw	82h	; 130
		call	assert_wr
		movlw	53h	; 83
		call	assert_wr
		movlw	63h	; 99
		call	assert_wr
		RETURN


bootp_tx
		CLRF	PCLATH
		DB	01,00		;clrw
		call	calc_sum
		DB	01,00		;clrw
		call	calc_sum
		DB	01,00		;clrw
		call	calc_sum
		DB	01,00		;clrw
		call	calc_sum
		
		MOVLW	0ffh
		call	calc_sum
		MOVLW	0ffh
		call	calc_sum
		MOVLW	0ffh
		call	calc_sum
		MOVLW	0ffh
		call	calc_sum
		
		DB	01,00	 
		call	calc_sum
		MOVLW	.17
		call	calc_sum
		
		MOVLW	HIGH (DHCP_SIZE)
		call	calc_sum
		MOVLW	DHCP_SIZE & 0ffh
		call	calc_sum

 
 		MOVLW	PACKET_SIZE+IP_SIZE + 6
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1
 		call	set_checksum
		
		
		MOVLW	4h
		MOVWF	PORTC
		movlw	PAGE_BEGIN			; transmit page is start page 
		call	assert_wr0
		
		MOVLW	5
		MOVWF	PORTC
		movlw	(DHCP_SIZE+IP_SIZE+PACKET_SIZE) & 0ffh
		call	assert_wr0
		
		MOVLW	6
		MOVWF	PORTC
		movlw	HIGH (DHCP_SIZE+IP_SIZE+PACKET_SIZE)
		call	assert_wr0
		
		call	transmit
;		setb	rb.5
		RETURN
;-----------------------------------------------------------------------------------
;		ＥＥＰＲＯＭデータの書き込み
;		アドレスは自動インクリメントする
;--------------------------------------------------------------------------------- 
;		org	0a00h

		goto	$		;不明
write_eeprom16
		MOVLW	'b'	 
		MOVWF	ind
		MOVF	wk2,0	 
		XORWF	wk1,1
		MOVF	wk1,0	 
		XORWF	wk2,1
		MOVF	wk2,0	 
		XORWF	wk1,1
		call	write_eeprom
		MOVF	wk2,0	 
		MOVWF	wk1
write_eeprom
		MOVLW	'w'	 
		SUBWF	ind,0
		BTFSC	3,2
		GOTO	write_eeprom16
write_eeprom0	bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVF	wk,0	 	;addr
		MOVWF	EEADR
		MOVF	wk1,0 
		MOVWF	EEDATA
		bsf	STATUS,RP0
		bcf	EECON1,7			;eepgd
		bsf	EECON1,2		;wren
		
		bcf	INTCON,7		;gie
		MOVLW	55H	 
		MOVWF	EECON2
		MOVLW	0AAH	 
		MOVWF	EECON2
		bsf	EECON1,1		;wr
		
		btfsc	EECON1,1		;wr
		goto	$-1
		
		bcf	EECON1,2		;wren
		bcf	STATUS,RP0
		bcf	STATUS,RP1
		INCF	wk,1 
		bsf	INTCON,7		;gie
		RETURN




get_nextbyte
		MOVF	remote_len,0 
		iorwf	remote_len1,0 
		btfsc	STATUS,Z
		goto	get_nextbyte9
		
		bcf	PORTE,0
		btfss	PORTC,5			; ~Wait
		goto	$-1
		MOVF	PORTD,0
		bsf	PORTE,0
		
		MOVWF	data0	 
		MOVLW	0AH	 
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	get_nextbyte9
		movlw	1			; LENGTH--
		subwf	remote_len,1 
		btfss	STATUS,C
		subwf	remote_len1,1	 
		RETURN
get_nextbyte9
		CLRF	data0		 
		RETURN





;-----------------------------------------------------------------------------------
;		ｃｇｉ(GETメソッド)のパースHAVE
;		00b=192.168.0.200
;-----------------------------------------------------------------------------------
parse_cgi
		call	get_nextbyte
		MOVLW	0	 
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse9_tag
 
		MOVLW	0AH
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse9_tag
 	; Initial value
		MOVLW	'I'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	initial_values_tag
	 		; ピンの変更
		MOVLW	'R'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	modify_pin
		

		MOVLW	'0'	 
		SUBWF	data0,1
		MOVF	data0,0	 
		MOVWF	wk
		SWAPF	wk,1 
		
		call	get_nextbyte
	 
		MOVLW	0
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse9_tag
		
		MOVLW	'0'	 
		SUBWF	data0,1
		MOVF	data0,0	 
		IORWF	wk,1
		
		call	get_nextbyte
	 
		MOVLW	0
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse9_tag
		MOVF	data0,0	 
		MOVWF	ind
 	; byte単位
		MOVLW	'b'
		SUBWF	ind,0
		BTFSC	3,2
		GOTO	parse4
 		; word単位
		MOVLW	'w'
		SUBWF	ind,0
		BTFSC	3,2
		GOTO	parse4
		goto	parse9_tag				; b|w以外なら終了
parse4
		CLRF	wk1  			; 値の初期値＝０
		CLRF	wk2	 
		
		call	get_nextbyte			; skip '='
	 
		MOVLW	0
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse9_tag
 
		MOVLW	'&'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse_cgi

parse_cgi0
		call	get_nextbyte
 
		MOVLW	0
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse9_tag
 
		MOVLW	' '
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse91_tag
	 		MOVLW	9
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse91_tag
	 
		MOVLW	'&'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse_cgi2
		
 
		MOVLW	'.'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse_cgi3
 
		MOVLW	','
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	parse_cgi3
 
		MOVLW	'0'
		SUBWF	data0,0
		BTFSS	3,0
		GOTO	parse_cgi3
 
		MOVLW	'9' ^ 0FFH
		ADDWF	data0,0
		BTFSC	3,0
		GOTO	parse_cgi3
		
		call	multiply_added
		goto	parse_cgi0
parse_cgi2
		call	write_eeprom
		goto	parse_cgi
parse_cgi3
		call	write_eeprom
		CLRF	wk1	 
		CLRF	wk2	 
		goto	parse_cgi0
parse91_tag
		call	write_eeprom
parse9_tag
		MOVLW	HIGH (parse9)
		MOVWF	PCLATH

		goto	parse9


;-----------------------------------------------------------------------------------
;		１０倍してdataを足し込む
;-----------------------------------------------------------------------------------
multiply_added
		MOVLW	'0'	 	
		SUBWF	data0,1		; dataはASCIIキャラクタになっているため
		
		BCF	3,0 
		RLF	wk1,1	 
		RLF	wk2,1	 		;
		
		MOVF	wk1,0 	;
		MOVWF	mul10
		MOVF	wk2,0	 
		MOVWF	mul101
		BCF	3,0 
		RLF	wk1,1	 
		RLF	wk2,1	 
		BCF	3,0	 
		RLF	wk1,1	 
		RLF	wk2,1	 
		MOVF	mul10,0	  
		ADDWF	wk1,1
		btfsc	STATUS,C
		INCF	wk2,1	 
		MOVF	mul101,0  
		ADDWF	wk2,1
		MOVF	data0,0	 	;足し込み
		ADDWF	wk1,1
		btfsc	STATUS,C			; CARRYのチェック
		INCF	wk2,1	 
		RETURN



;-----------------------------------------------------------------------------------
;		ＥＥＰＲＯＭデータを初期値に戻す
;-----------------------------------------------------------------------------------
		goto	$	 
initial_values_tag
		call	initial_values
		goto	parse9_tag

initial_values
		MOVLW	default_values_end - default_values_begin
		MOVWF	gcn1
		CLRF	wk	 
initial_values0
		call	get_initial_value
		MOVWF	wk1 
		
		MOVLW	HIGH (write_eeprom0)
		MOVWF	PCLATH

		call	write_eeprom0
		MOVLW	HIGH (initial_values0)
		MOVWF	PCLATH
		
		DECFSZ	gcn1,1	 
		GOTO	initial_values0
		RETURN

;-----------------------------------------------------------------------------------
;		ｃｇｉによるピンの変更
;		RA0=H
;-----------------------------------------------------------------------------------HAVE
modify_pin
		call	get_nextbyte			; どのポートかを取得
		MOVLW	'A' ; 範囲外はエラー
		SUBWF	data0,0
		BTFSS	3,0
		GOTO	parse9_tag
		MOVLW	'B' ^ 0FFH	 
		ADDWF	data0,0
		BTFSC	3,0
		GOTO	parse9_tag
		MOVLW	'A'	 	; 'A'を減算
		SUBWF	data0,1
		MOVLW	PORTA	 
		ADDWF	data0,1
		MOVF	data0,0
		MOVWF	FSR

		call	get_nextbyte			; ビット位置の取得
		MOVLW	'0'	 	;範囲外はエラー
		SUBWF	data0,0
		BTFSS	3,0
		GOTO	parse9_tag
		MOVLW	'9' ^ 0FFH		 	; 
		ADDWF	data0,0
		BTFSC	3,0
		GOTO	parse9_tag
		MOVLW	'0'		 
		SUBWF	data0,1
		INCF	data0,1		 
		CLRF	wk		 
		BSF	3,0	 
modify_pin0
		RLF	wk,1	 
		DECFSZ	data0,1	 
		GOTO	modify_pin0
		call	get_nextbyte
		MOVLW	'='		 
		SUBWF	data0,0		;; '='がないとエラー
		BTFSS	3,2
		GOTO	parse9_tag
		call	get_nextbyte
		MOVLW	'H'	 
		SUBWF	data0,0		; High/Lowどちらを出力するか？
		BTFSC	3,2
		GOTO	modify_pin_h
		COMF	wk,1		 
		MOVF	wk,0		 
		ANDWF	INDF,1		; Ｉ／Ｏポートに'Ｌ'を出力する
		goto	parse9_tag

modify_pin_h
		MOVF	wk,0	 
		IORWF	INDF,1		;; Ｉ／Ｏポートに'Ｈ'を出力する
		goto	parse9_tag


get_initial_value
		MOVLW	1FH	 ; 初期値の値を取得
		MOVWF	PCLATH
		MOVF	wk,0	 
		MOVWF	PCL




;===================================================================================
;		スタートアップルーチン
;===================================================================================
;		org	0c00h

start

		CLRF	PORTA			; 各ポートの初期化
		CLRF	PORTB
		clrF	PORTC			; RC =  RTL8019AS の SA0-SA5
		clrF	PORTD			; RD = 00h
		MOVLW	B'111'		; 各コントロールポート＝Ｈ
		MOVWF	PORTE
		bsf	STATUS,RP0
		MOVLW	B'10000110'	 
		DB	00,62	 		; 割り込みの設定
		MOVLW	B'10000010' 
		MOVWF	ADCON1		; RE0-2 are Digital Pin
		MOVLW	B'00111111' 
		MOVWF	TRISA		; RA0-4はＡＤ入力ピンとする
		MOVLW	B'000'	 	; RE0-2は出力ピンとする
		MOVWF	TRISE
		bcf	STATUS,RP0

		CLRF	use	 
				; LCDポート/シリアルポート有効フラグをクリア

		call	get_ip_address		; EEPROMのIPアドレスをファイルレジスタに読み出す。
		call	get_port_no		; EEPROMのポート番号をファイルレジスタに読み出す。
;
;	LCDポートのチェック
;	ポートが０以外ならrb７－２は出力
;
		bsf	STATUS,RP0
		MOVF	lcd_port,0	; ＬＣＤポート番号が０かのチェック
		iorwf	lcd_port1,0 
		movlw	B'00001111'		; ＬＣＤポートが０の時,RB7-4出力,RB3-0入力
		btfss	STATUS,Z
		movlw	B'00000011'		; ＬＣＤポートが０以外の時,RB7-2出力,RB1-0入力
		MOVWF	TRISB	 
		bcf	STATUS,RP0
		
		btfss	STATUS,Z
		bsf	use,0	 
			; ＬＣＤポートが０以外ならuse.LCDをイネーブルにする。


;	SERIALポートのチェック

		call	clear_seq_no		; TCPシーケンス番号を０に
		
		call	init_lcd		; 液晶モジュールの初期化
		
		MOVLW	B'11' 
		MOVWF	PORTE		; 各コントロールポート＝Ｈ
		
		MOVLW	5	 	; ５ｍｓ待つ
		MOVWF	wait_cn
		call	wait_ms
		
		bsf	STATUS,RP0
		MOVLW	B'11100000'
		MOVWF	TRISC
		MOVLW	B'11111111' 
		MOVWF	TRISD
		MOVLW	B'000'	 
		MOVWF	TRISE
		bcf	STATUS,RP0
		
		call	init_socket		; ソケットバッファ初期化
		CLRF	PCLATH
		
		call	initialize		; RTL8019ASの初期化
		
		MOVLW	$>>8
		MOVWF	PCLATH
		
		MOVLW	this_ip	 
		MOVWF	FSR
		;mov	FSR,#this_ip		; 自分のIPが 0.0.0.0 かどうかのチェック
		MOVF	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		INCF	FSR,1
		iorwf	INDF,0
		btfsc	STATUS,Z
		goto	start1			; IPが0.0.0.0の時はstart1へ
		
		MOVLW	HIGH (print_ip)	; IPアドレスを液晶に表示
		MOVWF	PCLATH
		call	print_ip
		goto	start2
start1
		MOVLW	HIGH (write_lcd4)
		MOVWF	PCLATH
		
		bsf	PORTB,2
		MOVLW	'D'			; 'DHCP'を液晶に表示
		MOVWF	d4
		call	write_lcd4
		MOVLW	'H'
		MOVWF	d4
		call	write_lcd4
		MOVLW	'C'
		MOVWF	d4
		call	write_lcd4
		MOVLW	'P'
		MOVWF	d4
		call	write_lcd4
		
		MOVLW	$ >> 8
		MOVWF	PCLATH
start2
		bsf	STATUS,RP0
		MOVLW	B'11110000'		; rc.4を入力ピンに変更
		MOVWF	PORTC
		bcf	STATUS,RP0
		
		MOVLW	HIGH (wait_us)
		MOVWF	PCLATH

		MOVLW	.100 	; 100us待つ
		MOVWF	wait_cn
		call	wait_us
		
		MOVLW	HIGH (start2)
		MOVWF	PCLATH
		btfss	PORTC,4		 	; rc.4ピンをチェック
		goto	bootstrap		; 'L'ならブートストラップモードへ移行
		
		bsf	STATUS,RP0
		MOVLW	B'10100000'		; rcを元に戻す
		MOVWF	TRISC
		MOVLW	B'00100110' 
		MOVWF	TXSTA			; ASYNCモジュール送信側を初期化
		MOVLW	BAUD_RATE 
		MOVWF	SPBRG			; ボーレート設定
		BSF	PIE1,5			; rcie; 受信割り込み許可
		bcf	STATUS,RP0
		MOVLW	B'10000000'	 
		MOVWF	RCSTA			; ASYNCモジュール受信側を初期化
		bcf	STATUS,RP0
		bcf	INTCON,6	;peie		; 周辺装置割り込み許可
		
		CLRF	PCLATH
		
		;mov	dest[0],#assert_wr2x & 0ffh
		;mov	dest[1],#assert_wr2x >>8
		MOVLW	assert_wr2x & 0ffh 
		MOVWF	dest
		MOVLW	HIGH (assert_wr2x) 
		MOVWF	dest1		
		bsf	STATUS,RP0
		CLRF	dhcp_done
		bcf	STATUS,RP0
		CLRF	PORTB			; 初期状態 RB=00h
		CLRF	TMR1L
		CLRF	TMR1H
		MOVLW	B'000101'
		MOVWF	T1CON
		BSF	STATUS,RP0

		BSF	PIE1,TMR1IE
		BCF	STATUS,RP0
		BSF	INTCON,PEIE	 
		BSF	INTCON,GIE	 
		BSF	INTCON,GIE		;gie; グローバル割り込み許可
		goto	main
;-----------------------------------------------------------------------------------
;		ソケットバッファのクリア
;-----------------------------------------------------------------------------------
init_socket
		bsf	STATUS,IRP
		MOVLW	skb & 0FFh
		MOVWF	FSR

		MOVLW	SOCKETS * .16	 
		MOVWF	com_cn
init_socket0	clrF	INDF
		INCF	FSR,1
		DECFSZ	com_cn,1	 
		GOTO	init_socket0
;
;		シリアル登録アドレスのクリア
;
;		bsf	STATUS,IRP	; already irp set
		MOVLW	on_ether & 0ffh
		MOVWF	FSR

		MOVLW	SERIAL_PACKET_SIZE - 2	 
		MOVWF	com_cn
init_on_ether0	clrF	INDF
		INCF	FSR,1
		DECFSZ	com_cn,1		 
		GOTO	init_on_ether0
		
		bcf	STATUS,IRP
		RETURN

;-----------------------------------------------------------------------------------
;		PIC16F877のEEPROMならIPアドレスを取得
;-----------------------------------------------------------------------------------
get_ip_address
		bsf	STATUS,RP0
		
		MOVLW	this_ip	 
		MOVWF	FSR
		MOVLW	4		 
		MOVWF	common
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		CLRF	EEADR	 
get_ip_address0
		bsf	STATUS,RP1
		bsf	STATUS,RP0
		bcf	EECON1,7			;eepgd
		BSF	EECON1,0 
		bcf	STATUS,RP0
		MOVF	EEDATA,0	 
		INCF	EEADR,1	 
		bcf	STATUS,RP1
		
		movwf	INDF
		INCF	FSR,1
		DECFSZ	common,1 
		GOTO	get_ip_address0
		
		MOVLW	ident
		MOVWF	FSR
		clrF	INDF
		INCF	FSR,1
		clrF	INDF
		RETURN
;-----------------------------------------------------------------------------------
;		PIC16F877のEEPROMからポート番号を取得
;-----------------------------------------------------------------------------------
get_port_no
		MOVLW	http_port & 0ffh
		MOVWF	FSR
		MOVLW	.4 * .2	 
		MOVWF	common
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVLW	.16	 
		MOVWF	EEADR
get_port_no0
		bsf	STATUS,RP0
		bcf	EECON1,7	;eepgd
		bsf	EECON1,0 
		bcf	STATUS,RP0
		MOVF	EEDATA,0 
		MOVWF	INDF
		INCF	FSR,1
		INCF	EEADR,1	 
		
		DECFSZ	common,1 
		GOTO	get_port_no0
		bcf	STATUS,RP1
		RETURN
;-----------------------------------------------------------------------------------
;		ＴＣＰシーケンス番号の初期化
;-----------------------------------------------------------------------------------
clear_seq_no
		bsf	STATUS,RP0
		CLRF	seq_no	 
		CLRF	seq_no1	 
		CLRF	seq_no2	 
		CLRF	seq_no3	 
		bcf	STATUS,RP0
		RETURN


;-----------------------------------------------------------------------------------
;		液晶初期化
;-----------------------------------------------------------------------------------HAVE
init_lcd
		MOVLW	.15	 	; wait 15ms
		MOVWF	wait_cn
		call	wait_ms
		
		BCF	PORTB,2			; RS='L'
		MOVLW	B'00110000'
		MOVWF	d8
		call	write_lcd8
		MOVLW	.5		; wait 4.1ms
		MOVWF	wait_cn
		call	wait_ms
		
		MOVLW	B'00110000'
		MOVWF	d8
		call	write_lcd8
		MOVLW	.100		; wait 100us
		MOVWF	wait_cn
		call	wait_us
		
		MOVLW	B'00110000'
		MOVWF	d8
		call	write_lcd8		; 0 0 0011 (3)
		
		MOVLW	B'00100000'
		MOVWF	d8
		call	write_lcd8		; 0 0 0010 (4bit)
	;
		MOVLW	B'00101000'		; duty,font set9
		MOVWF	d4
		call	write_lcd4
		
		MOVLW	B'00000001'		; クリアコマンド
		MOVWF	d4
		call	write_lcd4
		MOVLW	.2		; クリアが終わるまで待つ
		MOVWF	wait_cn
		call	wait_ms
		
		MOVLW	B'00000110'		; entry mode set
		MOVWF	d4
		call	write_lcd4
		
		MOVLW	B'00001110'		; display on,cursor on
		MOVWF	d4
		call	write_lcd4
		RETURN



;-----------------------------------------------------------------------------------
;		８ビットモード用液晶書き込みルーチン
;-----------------------------------------------------------------------------------
write_lcd8
		BTFSS	use,0		;btfss	use.0; LCDがオンでないとRBポートには書き込まない
		goto	lcd_skip
		
		MOVF	PORTB,0	 
		MOVWF	tmp
		MOVLW	0FH	 
		ANDWF	tmp,1
		MOVLW	0F0H	 
		ANDWF	d8,1
		MOVF	d8,0	 
		IORWF	tmp,1
		MOVF	tmp,0	 	; ＲＢポートへ出力
		MOVWF	PORTB

		goto	$+1
		BSF	PORTB,3	 	; Ｅピンを'H'
		GOTO	$+1			;jmp	$+1
		BCF	PORTB,3	 
lcd_skip
		MOVLW	.40
		MOVWF	wait_cn
		call	wait_us
		RETURN




;-----------------------------------------------------------------------------------
;		４ビットモード用液晶書き込みルーチン
;-----------------------------------------------------------------------------------
write_lcd4
		MOVF	d4,0	 
		MOVWF	d8
		call	write_lcd8
		
		MOVF	d4,0	 
		MOVWF	d8
		SWAPF	d8,1	 
		call	write_lcd8
		RETURN

;-----------------------------------------------------------------------------------
;		１６進数液晶出力ルーチン
;-----------------------------------------------------------------------------------
print_hex
		bsf	PORTB,2
		swapf	cd,0
		CLRF	PCLATH
		call	getascii
		MOVWF	d4	 
		call	write_lcd4
	;
		MOVF	cd,0
		CLRF	PCLATH
		call	getascii
		MOVWF	d4	 
		call	write_lcd4
		RETURN


;-----------------------------------------------------------------------------------
;		ｍｓオーダーのウェイト
;-----------------------------------------------------------------------------------
wait_ms
wait_ms0
		MOVLW	0	 
		MOVWF	wait_cn2
wait_ms1	GOTO	$+1	 
		GOTO	$+1 
		GOTO	$+1	 
		GOTO	$+1	 
		GOTO	$+1	 
		GOTO	$+1	 
		GOTO	$+1	 
		DECFSZ	wait_cn2,1 
		GOTO	wait_ms1
		DECFSZ	wait_cn,1 
		GOTO	wait_ms0
		RETURN

;-----------------------------------------------------------------------------------
;		μｓオーダーのウェイト
;-----------------------------------------------------------------------------------
wait_us
wait_us0
		GOTO	$+1 
	 
		DECFSZ	wait_cn,1
		GOTO	wait_us0
		RETURN


;-----------------------------------------------------------------------------------
;		バイナリ３２ビットの１０進変換ルーチン
;-----------------------------------------------------------------------------------
put_decimal32
		MOVF	FSR,0	 
		MOVWF	save_fsr
		MOVLW	decimal_top & 0ffh	; 格納場所初期値
		MOVWF	FSR
		bsf	STATUS,IRP			; ＩＲＰ＝１
		call	divide32		; 最下位変換
		call	divide32
		call	divide32
		call	divide32
		call	divide32
		
		call	divide32
		call	divide32
		call	divide32
		call	divide32
		call	divide32		; 最上位変換
		
		MOVLW	.10 - .1		;mov	val_cn,#10-1
		MOVWF	val_cn
		goto	put_decimal_ent


;-----------------------------------------------------------------------------------
;		バイナリ１６ビットの１０進変換ルーチン
;-----------------------------------------------------------------------------------
put_decimal16
		MOVF	FSR,0 
		MOVWF	save_fsr
		MOVLW	decimal_top & 0ffh	; 格納場所初期値
		MOVWF	FSR
		bsf	STATUS,IRP			; ＩＲＰ＝１
		call	divide16		; 最下位変換
		call	divide16
		call	divide16
		call	divide16
		call	divide16		; 最上位変換
		
		MOVLW	.5 - .1	 
		MOVWF	val_cn
		goto	put_decimal_ent

;-----------------------------------------------------------------------------------
;		バイナリ８ビットの１０進変換ルーチン
;-----------------------------------------------------------------------------------
put_decimal
		movwf	val
		
		MOVF	FSR,0	 
		MOVWF	save_fsr
		MOVLW	decimal_top & 0ffh	; 格納場所初期値
		MOVWF	FSR
		bsf	STATUS,IRP			; ＩＲＰ＝１
		call	divide			; 最下位変換
		call	divide
		call	divide			; 最上位変換
		
		MOVLW	.3 - .1	 
		MOVWF	val_cn
put_decimal_ent	CLRF	val_m	 
put_decimal0
		MOVLW	0	 
		SUBWF	val_m,0
		BTFSS	3,2
		GOTO	put_decimal1
		MOVLW	'0'	 
		SUBWF	INDF,0
		BTFSC	3,2
		GOTO	put_decimal2
put_decimal1	MOVF	INDF,0	 
		MOVWF	data0
		call	puttty
			; 出力(出力先はdestで変わる)
		MOVLW	HIGH (put_decimal1)
		MOVWF	PCLATH
		
		INCF	val_m,1	 
put_decimal2	INCF	FSR,1
		DECFSZ	val_cn,1 
		GOTO	put_decimal0
		MOVF	INDF,0	 	; 最下位桁
		MOVWF	data0
		call	puttty			; 出力(出力先はdestで変わる)
		MOVLW	HIGH (put_decimal2)
		MOVWF	PCLATH

		bcf	STATUS,IRP
		MOVF	save_fsr,0
		MOVWF	FSR
		RETURN


;-----------------------------------------------------------------------------------
;		バイナリ８ビットを１０進で液晶に表示する
;-----------------------------------------------------------------------------------
print_dec
		movwf	val
		
		MOVF	FSR,0	 	; fsrをセーブ
		MOVWF	save_fsr
		MOVLW	decimal_top & 0ffh	; 格納場所初期値
		MOVWF	FSR
		bsf	STATUS,IRP			; ＩＲＰ＝１
		call	divide			; 最下位変換
		call	divide
		call	divide			; 最上位変換
		
		bsf	PORTB,2
		MOVF	INDF,0 
		MOVWF	d4
		call	write_lcd4
		INCF	FSR,1
		MOVF	INDF,0	 
		MOVWF	d4
		call	write_lcd4
		INCF	FSR,1
		MOVF	INDF,0 
		MOVWF	d4
		call	write_lcd4
		
		bcf	STATUS,IRP
		MOVF	save_fsr,0
		MOVWF	FSR
		RETURN






;-----------------------------------------------------------------------------------
;		８ビット除算サブルーチン
;-----------------------------------------------------------------------------------
divide
		MOVLW	8
		MOVWF	gcn1
		CLRF	val_m 
divide0
		BCF	3,0 
		RLF	val,1	 
		RLF	val_m,1	 
		
		movlw	B'11110110'
		addwf	val_m,0
		btfsc	STATUS,C
		MOVWF	val_m	 
		btfsc	STATUS,C
		INCF	val,1 
		
		DECFSZ	gcn1,1
		GOTO	divide0
		decF	FSR,1
		MOVF	val_m,0	 	; 余り
		MOVWF	INDF
		MOVLW	'0'	 
		ADDWF	INDF,1
		RETURN


;-----------------------------------------------------------------------------------
;		１６ビット除算サブルーチン
;-----------------------------------------------------------------------------------
divide16
		MOVLW	.16
		MOVWF	gcn1
		clrF	val_m
divide16_0
		BCF	3,0	 
		RLF	val,1	 
		RLF	val1,1	 
		RLF	val_m,1	 
		
		movlw	B'11110110'
		addwf	val_m,0
		btfsc	STATUS,C
		MOVWF	val_m	 
		btfsc	STATUS,C
		INCF	val,1	 
		
		DECFSZ	gcn1,1	 
		GOTO	divide16_0
		decF	FSR,1
		MOVF	val_m,0 	; 余り
		MOVWF	INDF
		MOVLW	'0'	 
		ADDWF	INDF,1
		RETURN


;-----------------------------------------------------------------------------------
;		３２ビット除算サブルーチン
;-----------------------------------------------------------------------------------
divide32
		MOVLW	.32
		MOVWF	gcn1
		CLRF	val_m	 
divide32_0
		BCF	3,0	 
		RLF	val,1	 
		RLF	val1,1	 
		RLF	val2,1	 
		RLF	val3,1		 
		RLF	val_m,1	 
		
		movlw	B'11110110'
		addwf	val_m,0
		btfsc	STATUS,C
		MOVWF	val_m	 
		btfsc	STATUS,C
		INCF	val,1	 
		
		DECFSZ	gcn1,1	 
		GOTO	divide32_0
		decF	FSR,1
		MOVF	val_m,0	 	; 余り
		MOVWF	INDF
		MOVLW	'0'	 
		ADDWF	INDF,1
		RETURN

;===================================================================================
;		ブートストラップメインルーチン
;===================================================================================
get_lcdmes
		MOVLW	lcd_mes >> 8	 
		MOVWF	PCLATH
		MOVF	wk,0 
		MOVWF	PCL
;
;	BOOTSTRAP MODE Entry
;
bootstrap
		MOVLW	$ >> 8	 
		MOVWF	PCLATH
		MOVLW	B'11000000' 
		MOVWF	d4
		bcf	PORTB,2			;RS
		call	write_lcd4		; カーソルを２行目に移動

		MOVLW	.16	 
		MOVWF	gcn1
		MOVLW	lcd_mes & 0ffh
		MOVWF	wk
bootstrap10
		call	get_lcdmes		; 'Bootstrap Mode'を液晶に表示
		MOVWF	d4 
		
		MOVLW	$ >> 8	 
		MOVWF	PCLATH

		bsf	PORTB,2		;RS
		call	write_lcd4
		MOVLW	$ >> 8	 
		MOVWF	PCLATH

		
		INCF	wk,1	 
		DECFSZ	gcn1,1
		GOTO	bootstrap10	 
;
;		ASYNCの初期化
;
		bsf	STATUS,RP0 
		MOVLW	B'10100000' 
		MOVWF	TRISC
		MOVLW	B'00100110'	 	; 送信側設定
		MOVWF	TXSTA
		MOVLW	BAUD_RATE 	; ボーレート設定
		MOVWF	SPBRG
		BSF	PIE1,RCIE 		; 受信割り込み有効
		bcf	STATUS,RP0	 
		MOVLW	B'10010000' 
		MOVWF	RCSTA
		MOVLW	async_transmit & 0ffh ; 送信ルーチンの設定
		MOVWF	dest
		MOVLW	async_transmit >> 8  
		MOVWF	dest1
		bsf	INTCON,PEIE	 			; 周辺装置割り込み許可
		bsf	INTCON,GIE 			; (グローバルな)割り込み許可

		MOVLW	bs_1 & 00ffh 		; 起動メッセージ
		MOVWF	com_cn
		call	put_bs_text
		
		MOVLW	bs_config & 00ffh 
		MOVWF	com_cn			; 現在の設定表示
		call	put_bs_text
		
		MOVLW	bs_prompt & 00ffh 	; プロンプト表示
		MOVWF	com_cn
		call	put_bs_text
;-----------------------------------------------------------------------------------
;		Bootstrapのメインループ
;-----------------------------------------------------------------------------------
		bsf	STATUS,RP0	 
bootstrap0
 			; 受信待機(受信するとfifo_cn!=0になる)
		MOVLW	0
		SUBWF	fifo_cn,0
		BTFSC	3,2
		GOTO	bootstrap0		
		MOVF	fifo_poi,0	 
		MOVWF	FSR			; 受信ポインタを取得
		MOVF	INDF,0		 
		MOVWF	data0			; 受信した文字を取得
		
		incF	fifo_poi,1				; 受信バッファをインクリメント
 
		MOVLW	fifo_bottom
		SUBWF	fifo_poi,0
		BTFSS	3,0
		GOTO	ring1_1
		MOVLW	fifo_top 
		MOVWF	fifo_poi
ring1_1		DECF	fifo_cn,1	 	; 受信バイト数をデクリメント
		
 		; バックスペース文字の場合...
		MOVLW	CH_BACKSPACE
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	boots_bs
		bcf	STATUS,RP0 
		call	async_transmit				; エコーバックの為、送信！！
		bsf	STATUS,RP0 
		
 			; CRの場合...
		MOVLW	.13
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	boots_cr			
		incF	fifo_line_cn,1
		goto	bootstrap0				; メインループへ戻る


;-----------------------------------------------------------------------------------
;		バックスペース受信処理
;-----------------------------------------------------------------------------------
boots_bs
 				; 削除する文字がない場合はなにもしない
		MOVLW	0
		SUBWF	fifo_line_cn,0
		BTFSC	3,2
		GOTO	bootstrap0
		MOVF	fifo_poi,0 
		MOVWF	FSR
		DECF	FSR,1	 
		
 		MOVLW	fifo_top
		SUBWF	FSR,0
		BTFSC	3,0
		GOTO	boots_bs1
		MOVLW	fifo_bottom - 1	 
		MOVWF	FSR
boots_bs1	clrF	INDF	 	; いまタイプされたBS文字をクリア
		
		MOVF	fifo_line,0	 
		MOVWF	FSR
		MOVF	fifo_line_cn,0	 
		ADDWF	FSR,1
		DECF	FSR,1		 
		
	 
		MOVLW	fifo_bottom
		SUBWF	FSR,0
		BTFSS	3,0
		GOTO	boots_bs2
		MOVLW	fifo_top	 
		SUBWF	FSR,1
boots_bs2	clrF	INDF	 	; 直前のタイプ文字をクリア
		bcf	STATUS,IRP		 
		
		bcf	STATUS,RP0	 
		call	async_transmit				; エコーバックの為、BS文字をエコー
		MOVLW	' '	 
		MOVWF	data0
		call	async_transmit				; スペースの出力してから
		MOVLW	CH_BACKSPACE 
		MOVWF	data0
		call	async_transmit				; もう一度ＢＳをエコー
		bsf	STATUS,RP0 
		
		decF	fifo_line_cn,1
		goto	bootstrap0


;-----------------------------------------------------------------------------------
;		ＣＲ受信処理
;-----------------------------------------------------------------------------------
boots_cr
		MOVLW	.10	 
		MOVWF	data0
		bcf	STATUS,RP0	 
		call	async_transmit				; 改行をエコー
		bsf	STATUS,RP0	 
	 	; 何も入力されていない？
		MOVLW	0
		SUBWF	fifo_line_cn,0
		BTFSS	3,2
		goto	bs_job					; 仕事を分担
bootstrap9
		bcf	STATUS,RP0		;rp0
		MOVLW	bs_prompt & 00ffh	;mov	com_cn,#bs_prompt & 00ffh
		MOVWF	com_cn			; プロンプト表示
		call	put_bs_text
		
		bsf	STATUS,RP0	 
		MOVF	fifo_poi,0		 
		MOVWF	fifo_line
		clrF	fifo_line_cn
		goto	bootstrap0				; メインループへ

;
;		無効なコマンドが入力されたとき
;
bootstrap99
		bcf	STATUS,RP0		 
		MOVLW	bs_invalid & 00ffh 
		MOVWF	com_cn
		call	put_bs_text
		goto	bootstrap9



get_bs_str
		MOVLW	1FH		 
		MOVWF	PCLATH
		MOVF	bs_ptr,0	 
		goto	get_bs_job
get_bs_str2
		MOVLW	1FH		 
		MOVWF	PCLATH
		MOVF	bs_ptr2,0	 
		MOVWF	PCL


;-----------------------------------------------------------------------------------
;		コマンド解析処理
;-----------------------------------------------------------------------------------
bs_job
		movf	fifo_line,0 
		MOVWF	save_line
		MOVF	fifo_line_cn,0	 
		MOVWF	save_cn
		clrF	bs_ptr
bs_job10
		call	get_bs_str
		MOVWF	bs_ptr2	 
		MOVLW	$ >> 8	 
		MOVWF	PCLATH

		
 				; 該当なし
		MOVLW	0
		SUBWF	bs_ptr2,0
		BTFSC	3,2
		GOTO	bootstrap99
bs_job0
		call	get_bs_str2
		MOVWF	wk	 
		MOVLW	$ >> 8	 
		MOVWF	PCLATH

	 	; 最後までＯＫ
		MOVLW	0
		SUBWF	wk,0
		BTFSC	3,2
		GOTO	bs_job1			
		call	getterm				; バッファから１文字取得
		bsf	STATUS,RP0	 
		
 		MOVLW	.13
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	bs_job2	
 		; 文字違い？
		MOVF	data0,0
		SUBWF	wk,0
		BTFSS	3,2
		GOTO	bs_job2			
		incF	bs_ptr2,1				; 1文字進める
		goto	bs_job0

bs_job2
		MOVLW	2		 
		ADDWF	bs_ptr,1
		MOVF	save_line,0	 
		MOVWF	fifo_line
		MOVF	save_cn,0	 
		MOVWF	fifo_line_cn
		goto	bs_job10
bs_job1
		incF	bs_ptr,1
		call	get_bs_str
		MOVWF	wk	 
		
		bcf	STATUS,RP0	 
		MOVLW	0EH		 
		MOVWF	PCLATH
		MOVF	wk,0	 
		MOVWF	PCL


;		org	0e00h


;-----------------------------------------------------------------------------------
;		'initialize' 実行ルーチン
bsj_init
		call	initial_values
bsj_config	MOVLW	bs_config & 00ffh    
		MOVWF	com_cn			; 現在の設定表示

		call	put_bs_text
		goto	bootstrap9
;-----------------------------------------------------------------------------------
;		'help' 実行ルーチン
bsj_help
		MOVLW	bs_help & 00ffh	 
		MOVWF	com_cn			; ヘルプ
		call	put_bs_text
		goto	bootstrap9
;-----------------------------------------------------------------------------------
;		スペース文字の読み飛ばし
skip_space
		call	getterm
 
		MOVLW	' '
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	skip_space
 
		MOVLW	9
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	skip_space	
		retURN
;-----------------------------------------------------------------------------------
;		'lcd=xxxxx' 実行ルーチン
bsj_lcd
		MOVLW	.16 + .2 
		MOVWF	 wk
		goto	bs_set_word
;-----------------------------------------------------------------------------------
;		'para=xxxxx' 実行ルーチン
bsj_para
		MOVLW	.16 + .2 + .2
		MOVWF	 wk
;		mov	wk[0],#16+2+2
		goto	bs_set_word
;-----------------------------------------------------------------------------------
;		'serial=xxxxx' 実行ルーチン
bsj_serial
;		mov	wk[0],#16+2+2+2
		MOVLW	.16 + .2 +.2 + .2
		MOVWF	 wk
		goto	bs_set_word
;-----------------------------------------------------------------------------------
;		'http=xxxxx' 実行ルーチン
bsj_http
;		mov	wk[0],#16
		MOVLW	.16
		MOVWF	 wk
		
bs_set_word	MOVLW	'w'	 
		MOVWF	ind
		MOVLW	1	 
		MOVWF	byte_cn
		goto	bs_set_common
;-----------------------------------------------------------------------------------
;		'net=xxxxx' 実行ルーチン
bsj_net
		;mov	wk[0],#4
		MOVLW	4
		MOVWF	wk
		goto	bs_set_byte
;-----------------------------------------------------------------------------------
;		'gate=xxxxx' 実行ルーチン
bsj_gate
 
		MOVLW	8
		MOVWF	wk
		goto	bs_set_byte
;-----------------------------------------------------------------------------------
;		'ip=xxx.xxx.xxx.xxx' 実行ルーチン
bsj_ip
 		; EEPROM ADR=0
		MOVLW	0
		MOVWF	wk
		
bs_set_byte 
		MOVLW	'b'
		MOVWF	ind
	 
		MOVLW	4
		MOVWF	byte_cn
		
bs_set_common
		call	skip_space
	 
		MOVLW	.13
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	put_bs_err	
	 
		MOVLW	'='
		SUBWF	data0,0
		BTFSS	3,2
		GOTO	put_bs_err			
		
		call	skip_space
	 
		MOVLW	.13
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	put_bs_err			
		CLRF	wk1		 ; 値の初期値＝０
		CLRF	wk2	 	; 値の初期値＝０
		goto	bs_getnumber
bs_getnumber0
		call	getterm
bs_getnumber
	 				; CRなら終了
		MOVLW	.13
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	bs_write9			
 		MOVLW	'.'
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	bs_write
 		MOVLW	','
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	bs_write
 		MOVLW	'0'
		SUBWF	data0,0
		BTFSS	3,0
		GOTO	bs_write
 		MOVLW	'9' ^ 0FFH
		ADDWF	data0,0
		BTFSC	3,0
		GOTO	bs_write

		call	multiply_added
		goto	bs_getnumber0
bs_write
		call	write_eeprom
		decF	byte_cn,1
 				; 規定バイト数を書き込んだ？
		MOVLW	0
		SUBWF	byte_cn,0
		BTFSC	3,2
		GOTO	bootstrap9
		CLRF	wk1		;clr	wk[1]; 値の初期値＝０
		CLRF	wk2		;clr	wk[2]	; 値の初期値＝０

		goto	bs_getnumber0
bs_write9
		call	write_eeprom
		goto	bootstrap9

;-----------------------------------------------------------------------------------
;		ラインバッファから１文字読み込み(終端文字はCR)
;-----------------------------------------------------------------------------------
getterm
		bsf	STATUS,RP0		;rp0
getterm0	MOVF	fifo_line,0		;mov	fsr,fifo_line
		MOVWF	FSR
		MOVF	INDF,0			;mov	data,indirect	
		MOVWF	data0			; コマンドの解析
		
		incF	fifo_line,1
 		MOVLW	fifo_bottom
		SUBWF	fifo_line,0
		BTFSS	3,0
		GOTO	getterm1
		MOVLW	fifo_top 
		MOVWF	fifo_line
getterm1	decF	fifo_line_cn,1				; 受信バイト数をデクリメント
		
			; NULL文字はスキップする
		MOVLW	0
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	getterm0
		bcf	STATUS,RP0		;rp0
		retURN 

put_bs_err
		MOVLW	bs_err & 00ffh	 
		MOVWF	com_cn			; Syntax error表示
		call	put_bs_text
		goto	bootstrap9




;-----------------------------------------------------------------------------------
;		ブートストラップルーチン用テキスト出力ルーチン
;-----------------------------------------------------------------------------------
put_bs_text
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVLW	13H	 	; BANK 10h fan
		MOVWF	EEADRH
		MOVF	com_cn,0	 
		MOVWF	EEADR
		bsf	STATUS,RP0
		bsf	EECON1,7	;eepgd
		BSF	EECON1,0 
		nop
		nop
		bcf	STATUS,RP0
		;mov	getmes_wk[0],eedath
		;mov	getmes_wk[1],eedata
		MOVF	EEDATH,0
		MOVWF	getmes_wk
		MOVF	EEDATA,0 
		MOVWF	getmes_wk1
		bcf	STATUS,RP1
		
		RLF	getmes_wk1,0	 
		RLF	getmes_wk,1	 
		MOVF	getmes_wk,0
		andlw	7fh
		btfsc	STATUS,Z
		goto	put_bs_text9
		MOVWF	data0		 
		MOVLW	'$'		 
		SUBWF	data0,0
		BTFSC	3,2
		GOTO	ctrl_code
		call	async_transmit
		
		MOVF	getmes_wk1,0
		andlw	7fh
		btfsc	STATUS,Z
		goto	put_bs_text9
		MOVWF	data0		 
		call	async_transmit
		
		INCF	com_cn,1	 
		goto	put_bs_text
put_bs_text9	RETURN



;-----------------------------------------------------------------------------------
;		２３２Ｃ出力ルーチン
;-----------------------------------------------------------------------------------
async_transmit
		BTFSS	PIR1,4		;btfss	pir1.4
		goto	async_transmit
		MOVF	data0,0		 
		MOVWF	TXREG
		RETURN


;-----------------------------------------------------------------------------------
;		コントロールコード出力(その１)
;-----------------------------------------------------------------------------------
;		org	0f00h
ctrl_code
		MOVLW	HIGH (ctrl_code1)
		MOVWF	PCLATH
		MOVF	getmes_wk1,0
		andlw	7fh
		addlw	-'0'
		call	ctrl_code1
		INCF	com_cn,1		 
		goto	put_bs_text
		
;		nop	10
ctrl_code1
		ADDWF	2,1	 
		goto	put_mac_address		; 0:MACアドレス
		goto	put_ip_address		; 1:IPアドレス
		goto	put_netmask		; 2:ネットマスク
		goto	put_gateway_address	; 3:ゲートウェイ
		goto	put_http_port		; 4:httpポート
		goto	put_lcd_port		; 5:lcdポート
		goto	put_io_port		; 6:parallelポート
		goto	put_232_port		; 7:232cポート
		goto	put_version		; 8:バージョン表示
		
		goto	put_send_packet		; 9:送信パケット数
		goto	put_this_ip		; A:自ＩＰの表示
		goto	put_ptop		; B:PtoP IPアドレス＜未実装＞

put_send_packet
		MOVLW	ident
		MOVWF	FSR
		MOVF	INDF,0		 
		MOVWF	val1
		INCF	FSR,1
		MOVF	INDF,0		 
		MOVWF	val
		INCF	FSR,1	
		MOVLW	0		 
		MOVWF	val2
		INCF	FSR,1
		MOVLW	0	 
		MOVWF	val3
		goto	put_decimal32		; 送信パケット数を表示

put_http_port
		bsf	STATUS,RP1
		MOVLW	.16		 
		MOVWF	EEADR
		goto	putcom16
put_lcd_port
		bsf	STATUS,RP1
		MOVLW	.16 + .2	 
		MOVWF	EEADR
		goto	putcom16
put_io_port
		bsf	STATUS,RP1
		MOVLW	.16 + .4	 
		MOVWF	EEADR
		goto	putcom16
put_232_port
		bsf	STATUS,RP1
		MOVLW	.16 + .6	 
		MOVWF	EEADR
putcom16	goto	put_number16
	;	RETURN


put_this_ip
		MOVLW	this_ip	 
		MOVWF	FSR
		MOVLW	4
		MOVWF	common
		call	put_number_fr
		RETURN
put_ptop
		bsf	STATUS,RP1
		MOVLW	.24	 
		MOVWF	EEADR
		goto	putcom32
put_ip_address
		bsf	STATUS,RP1
		CLRF	EEADR		 
		goto	putcom32
put_netmask
		bsf	STATUS,RP1
		MOVLW	.4
		MOVWF	EEADR
		goto	putcom32
put_gateway_address
		bsf	STATUS,RP1
		MOVLW	.8
		MOVWF	EEADR
		goto	putcom32
put_version
		bsf	STATUS,RP1
		MOVLW	.12
		MOVWF	EEADR
putcom32	MOVLW	.4	 
		MOVWF	common
		goto	put_number
		RETURN

;-----------------------------------------------------------------------------------
;		外部ポートに出力
;-----------------------------------------------------------------------------------
puttty
		MOVF	dest1,0	 
		MOVWF	PCLATH
		MOVF	dest,0	 
		MOVWF	PCL


;-------------------------------------------------------------------------------

;-----------------------------------------------------------------------------------
;		Ｗｅｂブラウザにソケットステータスを送る（いわゆるnetstat -n)
;-----------------------------------------------------------------------------------
;put_socket_stat
;		bsf	STATUS,IRP 
;		MOVF	INDF,0	 
;		MOVWF	cd
;		incF	FSR,1		;fsr
;		call	put_hexadecimal
;		MOVF	INDF,0	 
;		MOVWF	cd
;		incF	FSR,1		;fsr
;		call	put_hexadecimal
;		
;		MOVLW	' '	 
;		MOVWF	data0
;		call	puttty
;		MOVLW	$ >> 8	 
;		MOVWF	PCLATH
;		bsf	STATUS,IRP	;irp
;		MOVF	INDF,0	 
;		incF	FSR,1		;fsr
;		call	put_decimal
;		MOVLW	'.'	 
;		MOVWF	data0
;		call	puttty
;		MOVLW	 $ >> 8	 
;;		MOVWF	PCLATH
;		
;		bsf	STATUS,IRP		;irp
;		MOVF	INDF,0		 
;		INCF	FSR,1	 
;		call	put_decimal
;		MOVLW	'.'	 
;		MOVWF	data0
;		call	puttty
;		MOVLW	$ >> 8	 
;		MOVWF	PCLATH
;		
;		bsf	STATUS,IRP
;		MOVF	INDF,0	 
;		INCF	FSR,1		;inc	fsr
;		call	put_decimal
;		MOVLW	'.'	 
;		MOVWF	data0
;		call	puttty
;		MOVLW	$ >>8	 
;		MOVWF	PCLATH
;		bsf	STATUS,IRP	;irp
;		MOVF	INDF,0	 
;		incF	FSR,1
;		call	put_decimal
;		
;;		MOVLW	' '	 
;		MOVWF	data0
;		call	puttty
;		MOVLW	$ >>8	 
;		MOVWF	PCLATH		
;		
;		bsf	STATUS,IRP	;irp
;		MOVF	INDF,0	 
;		MOVWF	val1
;		incF	FSR,1		;fsr
;		MOVF	INDF,0	 
;		MOVWF	val
;		INCF	FSR,1	 
;		call	put_decimal16
;		
;		MOVLW	' ' 
;		MOVWF	data0
;		call	puttty
;		MOVLW	$ >> 8	 
;		MOVWF	PCLATH
;		
;		bsf	STATUS,IRP	;irp
;		MOVF	INDF,0	 
;		MOVWF	val3
;		INCF	FSR,1	 
;		MOVF	INDF,0 
;		MOVWF	val2
;		INCF	FSR,1	 
;		MOVF	INDF,0	 
;		MOVWF	val1
;		INCF	FSR,1	 
;		MOVF	INDF,0	 
;		MOVWF	val
;		INCF	FSR,1	 
;		call	put_decimal32
;		
;		MOVLW	' '	 
;		MOVWF	data0
;		call	puttty
;		MOVLW	$ >>8	 
;		MOVWF	PCLATH
;		
;		bsf	STATUS,IRP	;irp
;		MOVF	INDF,0	 
;		MOVWF	val3
;		INCF	FSR,1	 
 ;		MOVF	INDF,0
;		MOVWF	val2
;		INCF	FSR,1	 
 ;		MOVF	INDF,0
;		MOVWF	val1
;		INCF	FSR,1		 
 ;		MOVF	INDF,0	
;		MOVWF	val
;		goto	put_decimal32
 ;


;-----------------------------------------------------------------------------------
;		'.' 区切りで８ビット１０進数値をEEPROMから取得＋表示する
;-----------------------------------------------------------------------------------
put_number0
		MOVLW	'.'	 
		MOVWF	data0
		call	puttty
		MOVLW	$ >> 8
		MOVWF	PCLATH
put_number
		bsf	STATUS,RP1
		bsf	STATUS,RP0
		bcf	EECON1,7	;eepgd
		BSF	EECON1,0 
		bcf	STATUS,RP0
		MOVF	EEDATA,0 
		MOVWF	data0
		INCF	EEADR,1	 
		bcf	STATUS,RP1
		
		MOVF	data0,0
		call	put_decimal
		DECFSZ	common,1 
		GOTO	put_number0
		RETURN


;-----------------------------------------------------------------------------------
;		'.' 区切りで８ビット１０進数値を表示する
;-----------------------------------------------------------------------------------
put_number_fr0
		MOVLW	'.' 
		MOVWF	data0
		call	puttty
		MOVLW	HIGH (put_number_fr0)
		MOVWF	PCLATH
put_number_fr
		MOVF	INDF,0
		INCF	FSR,1
		call	put_decimal
		DECFSZ	common,1 
		GOTO	put_number_fr0
		RETURN


;-----------------------------------------------------------------------------------
;		EEPROMから１６ビット値を取得＋１０進表示する
;-----------------------------------------------------------------------------------
put_number16
		bsf	STATUS,RP1
		bsf	STATUS,RP0
		bcf	EECON1,7	;eepgd
		BSF	EECON1,0 
		bcf	STATUS,RP0
		MOVF	EEDATA,0 
		INCF	EEADR,1	 
		bcf	STATUS,RP1
		MOVWF	val1	 
		
		bsf	STATUS,RP1
		bsf	STATUS,RP0
		bcf	EECON1,7	;eepgd
		BSF	EECON1,0 
		bcf	STATUS,RP0
		MOVF	EEDATA,0		;mov	w,eedata
		INCF	EEADR,1	 
		bcf	STATUS,RP1
		MOVWF	val 
		
		call	put_decimal16
		RETURN

;-----------------------------------------------------------------------------------
;		１６進出力ルーチン
;-----------------------------------------------------------------------------------
put_hexadecimal
		CLRF	PCLATH
		swapf	cd,0
		call	getascii
		MOVWF	data0	 
		MOVLW	HIGH (puttty)
		MOVWF	PCLATH

		call	puttty
	;	mov	pclath,#$>>8
	;
		CLRF	PCLATH
		MOVF	cd,0
		call	getascii
		MOVWF	data0	 
		MOVLW	HIGH (puttty)
		MOVWF	PCLATH

		call	puttty
		MOVLW	HIGH (put_hexadecimal)
		MOVWF	PCLATH
		RETURN

;-----------------------------------------------------------------------------------
;		ＭＡＣアドレスを出力
;-----------------------------------------------------------------------------------
put_mac_address
		MOVLW	mymac
		MOVWF	FSR
		MOVF	INDF,0	 
		MOVWF	cd
		INCF	FSR,1
		call	put_hexadecimal
		
		MOVLW	':'	 
		MOVWF	data0
		call	puttty
		MOVLW	HIGH (put_hexadecimal)
		MOVWF	PCLATH
		
		MOVF	INDF,0	 
		MOVWF	cd
		INCF	FSR,1
		call	put_hexadecimal
		
		MOVLW	':'	 
		MOVWF	data0
		call	puttty
		MOVLW	HIGH (put_hexadecimal)
		MOVWF	PCLATH

		MOVF	INDF,0	 
		MOVWF	cd
		INCF	FSR,1
		call	put_hexadecimal
		
		MOVLW	':'	 
		MOVWF	data0
		call	puttty
		MOVLW	HIGH (put_hexadecimal)
		MOVWF	PCLATH 
		MOVF	INDF,0	 
		MOVWF	cd
		INCF	FSR,1
		call	put_hexadecimal
		
		MOVLW	':' 
		MOVWF	data0
		call	puttty
		MOVLW	HIGH (put_hexadecimal)
		MOVWF	PCLATH

		MOVF	INDF,0 
		MOVWF	cd
		INCF	FSR,1
		call	put_hexadecimal
		
		MOVLW	':' 
		MOVWF	data0
		call	puttty
		MOVLW	HIGH (put_hexadecimal)
		MOVWF	PCLATH

		MOVF	INDF,0	 
		MOVWF	cd
		INCF	FSR,1
		call	put_hexadecimal
		RETURN

;-----------------------------------------------------------------------------------
;		ＩＰアドレスを液晶に出力
;-----------------------------------------------------------------------------------
print_ip
		MOVLW	HIGH (print_dec)
		MOVWF	PCLATH

		MOVLW	this_ip	 
		MOVWF	FSR
		
		MOVF	INDF,0
		INCF	FSR,1
		call	print_dec
		
		MOVLW	'.'
		MOVWF	d4
		call	write_lcd4
		
		MOVF	INDF,0
		INCF	FSR,1
		call	print_dec
		
		MOVLW	'.'
		MOVWF	d4
		call	write_lcd4
		
		MOVF	INDF,0
		INCF	FSR,1
		call	print_dec
		
		MOVLW	'.'
		MOVWF	d4
		call	write_lcd4
		
		MOVF	INDF,0
		INCF	FSR,1
		call	print_dec
		RETURN

;-----------------------------------------------------------------------------------
;		シリアル受信データの送信先を登録
;-----------------------------------------------------------------------------------
		org	1000h

ser_register
		;mov	wk,#SERIAL_PACKET_SIZE-2
		MOVLW	SERIAL_PACKET_SIZE - 2
		MOVWF	wk
		CLRF	wk1	 
		bsf	STATUS,IRP
		MOVLW	on_ether & 0ffh
		MOVWF	FSR
ser_register0
		MOVF	INDF,0	 
		IORWF	wk1,1
		INCF	FSR,1
		DECFSZ	wk,1	 
		GOTO	ser_register0
		bcf	STATUS,IRP

		MOVLW	0 
		SUBWF	wk1,0		; 既に設定済みの場合は何もしないで、
		BTFSS	3,2		;ステータスのみ送信する。
		GOTO	ser_register9
;	送信先を登録
		bsf	STATUS,IRP
		MOVLW	on_ip & 0ffh
		MOVWF	FSR
 		
		MOVF	udp_data1,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	udp_data2,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	udp_data3,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	udp_data4,0 
		MOVWF	INDF
		INCF	FSR,1
		
		MOVF	udp_src_port,0 
		MOVWF	INDF
		INCF	FSR,1
		MOVF	udp_src_port1,0 
		MOVWF	INDF
		INCF	FSR,1

		MOVF	udp_data5,0 
		MOVWF	INDF
		bsf	STATUS,RP0
		MOVF	INDF,0 ; ボーレートを設定
		MOVWF	SPBRG
		bcf	STATUS,RP0
		
		INCF	FSR,1
		MOVF	udp_data6,0 
		MOVWF	INDF
		MOVLW	0
		SUBWF	INDF,0
		BTFSS	3,2
		BSF	INTCON,INTE
		bcf	STATUS,IRP
;
;		ＡＲＰ要求を送信
;
		CLRF	PCLATH				; Important!
		
 		CLRF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1

		MOVLW	PACKET_SIZE + ARP_SIZE
		MOVWF	remote_len
		CLRF	remote_len1

 		call	remote_write
		
		MOVLW	10h		; 宛て先："ff-ff-ff-ff-ff-ff"に送信
		MOVWF	PORTC
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		movlw	0ffh
		call	assert_wr
		
		MOVLW	mymac		; 送信元：自分のＭＡＣアドレスを設定
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes
		
		movlw	COM_PROTO			; 08 Etherframe type
		call	assert_wr
		movlw	ARP_PROTO			; ARP
		call	assert_wr
		
		MOVLW	$ >> 8	
		MOVWF	PCLATH
		call	arp2				; ARP header write
		CLRF	PCLATH				; Important!
		
		clrF	PORTC
		movlw	B'00100010'
		call	assert_wr0
		
		MOVLW	4h
		MOVWF	PORTC
		movlw	PAGE_BEGIN		; transmit page is start page 
		call	assert_wr0
		
		MOVLW	.5
		MOVWF	PORTC
		movlw	.60				; minimum packet = 60
		call	assert_wr0
		
		MOVLW	6
		MOVWF	PORTC
		DB	01,00		;clrw					; adr high
		call	assert_wr0
		call	transmit			; ARP応答を送信する
ser_register9
		MOVLW	HIGH (ser_get_status)
		MOVWF	PCLATH
		goto	ser_get_status

;-----------------------------------------------------------------------------------
;		シリアル受信データの送信先を登録削除
;-----------------------------------------------------------------------------------
ser_unregister
		bcf	RCSTA,4		;cren
		bcf	INTCON,6	;peie				; 使用禁止
		
 		MOVLW	SERIAL_PACKET_SIZE - 2
		MOVWF	wk
		CLRF	wk1		;clr	wk[1]
		bsf	STATUS,IRP
		MOVLW	on_ether & 0ffh
		MOVWF	FSR
ser_unregister0
		clrF	INDF
		INCF	FSR,1
		DECFSZ	wk,1	 
		GOTO	ser_unregister0
		bcf	STATUS,IRP
		
		goto	ser_register9

;
;	DHCPプロトコル処理
;
dhcp
		BSF	STATUS,RP0
		MOVLW	0FFH
		MOVWF	dhcp_done
		BCF	STATUS,RP0

		MOVLW	HIGH (bootp)
		MOVWF	PCLATH

		call	bootp			; DHCPでアドレス取得
		CLRF	PCLATH

		movlw	35h	; 
		call	assert_wr
		movlw	01h
		call	assert_wr
		movlw	1
		call	assert_wr
		
		movlw	3dh	; 
		call	assert_wr
		movlw	07h
		call	assert_wr
		movlw	01h
		call	assert_wr
		MOVLW	mymac
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes			; 自分のＭＡＣ
		
		movlw	0ffh
		call	assert_wr
		
		MOVLW	.64 - .7 - .9 - .1
		MOVWF	gcn1
bootp_30
		CLRF	PCLATH
		DB	01,00		;clrw
		call	assert_wr
		
		MOVLW	HIGH (bootp_30)
		MOVWF	PCLATH
		DECFSZ	gcn1,1		;djnz	gcn1,bootp_30
		GOTO	bootp_30
		MOVLW	HIGH (bootp_tx)
		MOVWF	PCLATH

		call	bootp_tx
		RETURN

;-----------------------------------------------------------------------------------
;	ＡＲＰヘッダの作成
arp1
		CLRF	PCLATH
		
		DB	01,00		;clrw
		call	assert_wr
		movlw	01h			; Ethernetは１固定
		call	assert_wr

		movlw	COM_PROTO
		call	assert_wr
		movlw	IP_PROTO		; IPでよい
		call	assert_wr
		movlw	06h
		call	assert_wr
		movlw	04h
		call	assert_wr
		movlw	00h
		call	assert_wr
		movlw	02h
		call	assert_wr
		movlw	mymac
		movwf	FSR
		movlw	6
		call	transmit_nbytes
		call	transmit_this_ip
		movlw	arp_src_mac
		movwf	FSR
		movlw	.10
		call	transmit_nbytes
		return
arp2	
		clrf	PCLATH
		db	01,00
		call	assert_wr
		movlw	01h
		call	assert_wr
		movlw	COM_PROTO
		call	assert_wr
		movlw	IP_PROTO
		call	assert_wr
		
		movlw	06h			; Ethernetアドレスのバイト数＝６
		call	assert_wr
		movlw	04h			; IPアドレスのバイト数＝４
		call	assert_wr

		movlw	00h
		call	assert_wr
		movlw	01h			; ARP要求(＝１)
		call	assert_wr
		
		MOVLW	mymac
		MOVWF	FSR
		movlw	6
		call	transmit_nbytes		; 自分のＭＡＣを送信
		call	transmit_this_ip	; 自分のＩＰを送信
		
		movlw	00h
		call	assert_wr
		movlw	00h
		call	assert_wr
		movlw	00h
		call	assert_wr
		movlw	00h
		call	assert_wr
		movlw	00h
		call	assert_wr
		movlw	00h
		call	assert_wr
		
		bsf	STATUS,IRP
		MOVLW	on_ip & 0ffh
		MOVWF	FSR
check_netid
		MOVLW	HIGH (check_netid)
		MOVWF	PCLATH
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVLW	.4		; address=16
		MOVWF	EEADR
		bcf	STATUS,RP1
		
		call	getnetmask
		bsf	STATUS,RP0
		MOVF	this_ip,0 
		MOVWF	wk1
		MOVF	wk,0	 	; [1] = this
		ANDWF	wk1,1
		MOVF	INDF,0	 	;on_ip[0]
		ANDWF	wk,1
	; [0] = host
		INCF	FSR,1
		MOVF	wk1,0
		SUBWF	wk,0 
		BTFSS	3,2
		GOTO	gateway

		call	getnetmask
		bsf	STATUS,RP0
		MOVF	this_ip1,0
		MOVWF	wk1
		MOVF	wk,0
		ANDWF	wk1,1
		MOVF	INDF,0	 	;on_ip[0]	
		ANDWF	wk,1

		INCF	FSR,1
		MOVF	wk1,0	 
		SUBWF	wk,0
		BTFSS	3,2
		GOTO	gateway
		call	getnetmask
		bsf	STATUS,RP0
		;mov	wk[1],this_ip[2]
		;and	wk[1],wk[0]		; [1] = this
		;and	wk[0],INDF		;on_ip[0]	; [0] = host
		MOVF	this_ip2,0
		MOVWF	wk1
		MOVF	wk,0
		ANDWF	wk1,1
		MOVF	INDF,0
		ANDWF	wk,1
		INCF	FSR,1
		MOVF	wk1,0	 
		SUBWF	wk,0
		BTFSS	3,2
		GOTO	gateway

		call	getnetmask
		bsf	STATUS,RP0
		;mov	wk[1],this_ip[3]
		;and	wk[1],wk[0]		; [1] = this
		;and	wk[0],INDF		;on_ip[0]	; [0] = host
		MOVF	this_ip3,0
		MOVWF	wk1
		MOVF	wk,0
		ANDWF	wk1,1
		MOVF	INDF,0
		ANDWF	wk,1

		MOVF	wk1,0	 
		SUBWF	wk,0
		BTFSS	3,2
		GOTO	gateway

direct
		bcf	STATUS,RP0
		bcf	STATUS,RP1
		CLRF	PCLATH
		MOVLW	on_ip & 0ffh
		MOVWF	FSR
		movlw	4			; 相手のＩＰを送信
		call	transmit_nbytes
		
		bcf	STATUS,IRP
		MOVLW	$ >> 8
		MOVWF	PCLATH
		RETURN

gateway
		bsf	STATUS,RP1
		bcf	STATUS,RP0
		MOVLW	.8		; address=16
		MOVWF	EEADR
		bsf	STATUS,RP0
		bcf	STATUS,RP1

		MOVLW	$ >> 8
		MOVWF	PCLATH
		call	getnetmask
		CLRF	PCLATH
		MOVF	wk,0
		call	assert_wr

		MOVLW	$ >> 8
		MOVWF	PCLATH
		call	getnetmask
		CLRF	PCLATH
		MOVF	wk,0
		call	assert_wr

		MOVLW	$ >> 8
		MOVWF	PCLATH
		call	getnetmask
		CLRF	PCLATH
		MOVF	wk,0
		call	assert_wr

		MOVLW	$ >> 8
		MOVWF	PCLATH
		call	getnetmask
		CLRF	PCLATH
		MOVF	wk,0
		call	assert_wr
		
		bcf	STATUS,IRP
		MOVLW	$ >> 8
		MOVWF	PCLATH
		RETURN

getnetmask
		bsf	STATUS,RP1
		bsf	STATUS,RP0
		bcf	EECON1,7	;eepgd
		BSF	EECON1,0		;bsf	eecon1,0
		bcf	STATUS,RP0
		MOVF	EEDATA,0		;mov	wk[0],eedata
		MOVWF	wk
		INCF	EEADR,1		;inc	eeadr
		bcf	STATUS,RP1
		RETURN


;-----------------------------------------------------------------------------------
;		２３２Ｃデータをホストに送信
;-----------------------------------------------------------------------------------
serial_tx
		bsf	STATUS,IRP		;irp
		MOVLW	on_ether & 0ffh	 
		MOVWF	FSR
		bsf	STATUS,RP0		;rp0
		MOVF	INDF,0	 
		MOVWF	eth_src
		INCF	FSR,1	 
		MOVF	INDF,0
		MOVWF	eth_src1
		INCF	FSR,1	 
		MOVF	INDF,0
		MOVWF	eth_src2
		;mov	eth_src[2],INDF
		INCF	FSR,1	 
		MOVF	INDF,0
		MOVWF	eth_src3
		INCF	FSR,1		 
		;mov	eth_src[4],INDF
		MOVF	INDF,0
		MOVWF	eth_src4

		INCF	FSR,1	 
	 
		MOVF	INDF,0
		MOVWF	eth_src5

		INCF	FSR,1	 
		bcf	STATUS,RP0		;rp0
		
		;mov	ip_src[0],INDF
		MOVF	INDF,0
		MOVWF	ip_src
		INCF	FSR,1	 
		;mov	ip_src[1],INDF
		MOVF	INDF,0
		MOVWF	ip_src1

		INCF	FSR,1 
		;mov	ip_src[2],INDF
		MOVF	INDF,0
		MOVWF	ip_src2

		INCF	FSR,1 
		MOVF	INDF,0
		MOVWF	ip_src3

		INCF	FSR,1	 
		bcf	STATUS,IRP		;irp
;
;	下準備をする
;
		bsf	STATUS,RP0		;rp0
		MOVF	fifo_cn,0 
		movwf	wk
;skip1
		bcf	STATUS,RP0		;rp0
		
		MOVLW	0	 
		MOVWF	ip_length
		MOVLW	IP_SIZE + UDP_SIZE 
		MOVWF	ip_length1
		MOVF	wk,0	 
		ADDWF	ip_length1,1		; 送信バイトサイズ
		MOVLW	SERIAL_PACKET_SIZE    ; 共通ヘッダサイズ
		ADDWF	ip_length1,1
		CLRF	PCLATH	 
		
		MOVLW	UDP_PROTO	 
		MOVWF	proto			; UDP packet
		call	prepare_ip			; ＩＰパケットまで作成
		
		call	clear_sum			; チェックサムの値をクリア
		
 		MOVLW	PACKET_SIZE+IP_SIZE
		MOVWF	remote_adr
		MOVLW	PAGE_BEGIN
		MOVWF	remote_adr1
		
		;mov	remote_len[0],#UDP_SIZE
		MOVLW	UDP_SIZE
		MOVWF	remote_len

 		MOVLW	SERIAL_PACKET_SIZE
		ADDWF	remote_len,1
		MOVF	wk,0
		ADDWF	remote_len,1
		MOVLW	0	 
		MOVWF	remote_len1
		call	remote_write
		
		
		MOVLW	10H	 
		MOVWF	PORTC
	
		MOVLW	serial_port	 
		MOVWF	FSR
		MOVF	INDF,0	 		; From PORT #(HIGH)
		call	assert_wr
		INCF	FSR,1	 
		MOVF	INDF,0	 			; From PORT #(LOW)
		call	assert_wr
		
		bsf	STATUS,IRP	;irp
		MOVLW	on_port & 0ffh 
		MOVWF	FSR			; To Port#
		MOVF	INDF,0	 
		call	assert_wr
		INCF	FSR,1	 
		MOVF	INDF,0	 
		call	assert_wr
		bcf	STATUS,IRP	;irp
		
		movlw	0
		call	assert_wr
		movlw	UDP_SIZE+SERIAL_PACKET_SIZE
		ADDWF	wk,0 
		call	assert_wr
		
		call	assert_wr2times

		movlw	4
		call	assert_wr
		MOVF	wk,0 
		addlw	SERIAL_PACKET_SIZE
		call	assert_wr			; sum(not fixed)
;
;		ステータス部
		bsf	STATUS,IRP	;irp
		MOVLW	on_ether & 0ffh	 
		MOVWF	FSR
		movlw	SERIAL_PACKET_SIZE - 2
		call	transmit_nbytes
		bcf	STATUS,IRP	;irp
;
;		送信
serial_tx0
		MOVLW	$ >> 8	 
		MOVWF	PCLATH
		bsf	STATUS,RP0		;rp0
		MOVF	fifo_poi,0 
		MOVWF	FSR		;; 受信ポインタ(GET)
		MOVF	INDF,0	 
		MOVWF	data0		; 受信した文字を取得
		
		incF	fifo_poi,1			; 受信バッファをインクリメント
 		MOVLW	fifo_bottom
		SUBWF	fifo_poi,0
		BTFSS	3,0
		GOTO	tx100
		MOVLW	fifo_top 
		MOVWF	fifo_poi
tx100		decF	fifo_cn,1				; 受信バイト数をデクリメント
		bcf	STATUS,RP0		;rp0
		
		clrF	PCLATH
		MOVF	data0,0	 
		call	assert_wr
		
		MOVLW	$ >> 8	 
		MOVWF	PCLATH
 		DECFSZ	wk,1
		GOTO	serial_tx0
		bcf	PORTB,1

;
;	UDPサム計算＋送信
		MOVLW	calc_udp_sum >> 8 
		MOVWF	PCLATH
		call	calc_udp_sum
		
		clrF	PCLATH		;pclc,#4hath
		MOVLW	4		 
		MOVWF	PORTC
		movlw	PAGE_BEGIN 
		call	assert_wr0

		MOVLW	PACKET_SIZE 
		ADDWF	ip_length1,1	; パケットサイズ6+6+2を送信バイト数に加算1
		movlw	1
		btfsc	STATUS,C 
		ADDWF	ip_length,1 
		
		MOVLW	6	 
		MOVWF	PORTC
		MOVF	ip_length,0 	; HIGH
		call	assert_wr0
		
		MOVLW	$ >> 8	 
		MOVWF	PCLATH
		MOVF	ip_length,1 
		btfsc	STATUS,Z 
		goto	serial_tx1
serial_tx2
		clrF	PCLATH	 
		MOVLW	5	 
		MOVWF	PORTC
		MOVF	ip_length1,0 
		call	assert_wr0
		call	transmit			; 送信！！
		
		clrF	PCLATH		;pclath
		goto	main0
serial_tx1
 		MOVLW	.60	
		SUBWF	ip_length1,0
		BTFSC	3,0
		GOTO	serial_tx2

		CLRF	PCLATH	 
		MOVLW	5	 
		MOVWF	PORTC
		movlw	.60				; MINIMUM 60bytes
		call	assert_wr0
		call	transmit
		
		CLRF	PCLATH	 
		goto	main0
udp_lcd9
		clrf	PCLATH
		GOTO	main9
;-------------------------------------------------------------------------------
;　　液晶への文字出力
;-------------------------------------------------------------------------------
udp_lcd
		MOVF	udp_length,0
		movwf	remote_len1
		movf	udp_length1,0
		movwf	remote_len
		movlw	8
		subwf	remote_len,1
		btfss	STATUS,C
		
		decF	remote_len1,1
		MOVLW	get_dgram >> 8
		movwf	PCLATH
		CALL	get_dgram
		MOVLW	$ >> 8
		MOVWF	PCLATH
		BTFSC	STATUS,C
		GOTO	udp_lcd9
		
		MOVLW	1
		SUBWF	data0,0
		BTFSS	3,2
		GOTO	udp_lcd_0
		MOVLW	get_dgram >>8
		MOVWF	PCLATH
		CALL	get_dgram
		MOVLW	$ >> 8
		MOVWF	PCLATH
		BTFSC	STATUS,C
		GOTO	udp_lcd9

		MOVF	PORTB,0
		MOVWF	wk
		BCF	PORTB,2
		MOVF	data0,0
		MOVWF	d4
		
		MOVLW	write_lcd4 >> 8
		MOVWF	PCLATH
		CALL	write_lcd4
		MOVLW	$ >> 8
		MOVWF	PCLATH
		
		MOVF	wk,0
		MOVWF	PORTB
		MOVLW	B'11111100'
		ANDWF	d4,1
		BTFSS	STATUS,Z
		GOTO	udp_lcd_0
		
		MOVLW	2
		MOVWF	wait_cn
		MOVLW	wait_ms >> 8
		MOVWF	PCLATH
		CALL	wait_ms
		MOVLW	$ >> 8
		MOVWF	PCLATH
udp_lcd_0
		MOVLW	get_dgram >> 8
		MOVWF	PCLATH
		CALL	get_dgram
		MOVLW	$ >> 8
		MOVWF	PCLATH
		BTFSC	STATUS,C
		GOTO	udp_lcd91
		MOVF	PORTB,0
		MOVWF	wk
		BSF	PORTB,2
		MOVF	data0,0
		MOVWF	d4
		MOVLW	write_lcd4 >> 8
		MOVWF	PCLATH
		CALL	write_lcd4
		MOVLW	$ >> 8
		MOVWF	PCLATH
		MOVF	wk,0
		MOVWF	PORTB

		GOTO	udp_lcd_0
udp_lcd91
		MOVLW	lcd_port
		MOVWF	wk2
		MOVLW	para_get_status >> 8
		MOVWF	PCLATH
		GOTO	common_get_status


;-----------------------------------------------------------------------------------
;		ブートストラップモード・メッセージ
;-----------------------------------------------------------------------------------
		org	1300h
lcd_mes		DT	"Bootstrap Mode  "
bs_1		DB	06,8A,06,8A		;.13,.10,.13,.10,
		DA	"PIC Network Interface Card - Bootstrap Mode Version $8"
		DB	06,8A		;,.13,.10
		DB	0,0
bs_prompt	DA	"PICNIC>"
bs_config	DA	"***** Configuration ***** "
		DB	06,8A		;,.13,.10
		DA	"MAC Addr.  :$0"
		DB	06,8A		;,.13,.10
		DA	"[I]P Addr. :$1"
		DB	06,8A		;,.13,.10
		DA	"[N]etMask  :$2"
		DB	06,8A		;.13,.10
		DA	"[G]ateWay  :$3"
		DB	06,8A		;,.13,.10
		DA	"[H]ttpPort     #$4"
		DB	06,8A		;,.13,.10
		DA	"[L]CD Port     #$5"
		DB	06,8A		;,.13,.10
		DA	"[P]arallelPort #$6"
		DB	06,8A		;,.13,.10
		DA	"[S]erialPort   #$7"
		DB	06,8A		;,.13,.10
		DB	0,0
bs_err		DA	"Syntax Error"
		DB	17,0D,05,00		;(,and 13),(10,0)
bs_invalid	DA	"Invalid Command."
		DB	06,8A,00,00		;,.13,.10,0,0
bs_help
		DA	"***** Bootstrap Mode Help ***** "
		DB	06,8A		;,.13,.10
		DA	"config         - Print Board Configuration and Status."
		DB	06,8A		;,.13,.10
		DA	"{str}={value}  - Update System Configuration. "
		DB	06,8A		;,.13,.10
		DA	"initialize     - All registers set Initial Values."
		DB	06,8A		;,.13,.10
		DB	0,0

;----------------------------------------------------------------------
;		Webブラウザ用メッセージ
;		値埋め込みのDA化版 [ver0.4a]
;----------------------------------------------------------------------

;======================================================================
;		バンク＃１
;======================================================================

		ORG	1400h
;
;++++++++++++++ HTTPレスポンス＋HTMLヘッダ ++++++++++++++++++
;
		DA 	"HTTP/1.0 200 OK\r\nConnection: close\r\nContent-type: text/html\r\n\r\n"

		DA	"<HTML><HEAD><TITLE>PIC Network Interface Card</TITLE>"
		DA	"</HEAD><BODY>"

		DA	"<H1>Welcome to My PICNIC version"
		DA	"$8</H1><HR>"
;
;++++++++++++++ I/O Ports セクション ++++++++++++++++++
;
		DA	"<H3>I/O Ports</H3>"
		DA	"<DL><DD><FORM ACTION=\"modify.cgi\" METHOD=\"GET\">\n"
		DA	"<TABLE BORDER>"
		DA	"<TR><TD>Port</TD><TD>Value</TD></TR>"
;
;++++++++++++++ アナログ入力 RA0,RA1（Exp-CN4:pin6,7） ++++++++++++++++++
;
		DA	"<TR><TD>AD#1(RA0) "
		DA	"%\x00"		;"%",0000_0000b,（入力方向）
		DA	" </TD>"
		DA	"<TD ALIGN=\"right\">"
		DA	"@\x00"		;'@",00000000b,（値表示）
		DA	"</TD></TR>"
		
		DA	"<TR><TD>AD#2(RA1) "
		DA	"%\x01"		;"%",0000_0001b,（入力方向）
		DA	" </TD>"
		DA	"<TD ALIGN=\"right\">"
		DA	"@\x01"		;@",00000001b,（値表示）
		DA	"</TD></TR>"
;
;++++++++++++++ 室温センサ入力 RA5（℃換算） ++++++++++++++++++
;
		DA	"<TR><TD>Temp(RA5) "
		DA	"%\x04"		;%",0000_0100b,（入力方向）
		DA	" </TD>"
		DA	"<TD ALIGN=\"right\">"
		DA	"@\x04"		;@",00000100b,（℃換算値表示）
		DA	" Celsius</TD></TR>"

		DB	0,0		;バンク終端

;======================================================================
;		バンク＃２
;======================================================================

		ORG	1700h
;
;++++++++++++++ ディジタル入力RB0,RB1（Exp-CN4:pin1-2,3-4）++++++++++++++++++
;
		DA	"<TR><TD>Switch#1(RB0) "
		DA	"%\x10"		;%",0001_0000b,（入力方向）
		DA	" </TD>"

		DA	"<TD>"
		DA	"@\x10"		;'@',0001_0000b,（値表示）
		DA	"</TD></TR>"

		DA	"<TR><TD>Switch#2(RB1) "
		DA	"%\x11"		;%",0001_0001b,（入力方向）
		DA	" </TD>"

		DA	"<TD>"
		DA	"@\x11"		;'@',0001_0001b,（値表示）
		DA	"</TD></TR>"
;
;++++++++++++++ ディジタル出力RB4,RB5（LED4, LED5）++++++++++++++++++
;
		DA	"<TR><TD>Mode#1(LED4) "
		DA	"%\x14"		;%",0001_0110b,（出力方向）
		DA	" </TD>"

		DA	"<TD><INPUT TYPE=\"submit\" NAME=\"RB4\" VALUE=\"H\">"
		DA	"@\x14"		;'@',0001_0110b,
		DA	"<INPUT TYPE=\"submit\" NAME=\"RB4\" VALUE=\"L\"></TD></TR>"

		DA	"<TR><TD>Mode#2(LED5) "
		DA	"%\x15"		;%",0001_0111b,（出力方向）
		DA	" </TD>"

		DA	"<TD><INPUT TYPE=\"submit\" NAME=\"RB5\" VALUE=\"H\">"
		DA	"@\x15"		;'@',0001_0111b,
		DA	"<INPUT TYPE=\"submit\" NAME=\"RB5\" VALUE=\"L\"></TD></TR>"
;
;++++++++++++++ ディジタル出力RB6,RB7（Exp-CN3:pin5-6-7,2-3-4）++++++++++++++++++
;
		DA	"<TR><TD>Relay#1(LED6) "
		DA	"%\x16"		;%",0001_0110b,（出力方向）
		DA	" </TD>"

		DA	"<TD><INPUT TYPE=\"submit\" NAME=\"RB6\" VALUE=\"H\">"
		DA	"@\x16"		;'@',0001_0110b,
		DA	"<INPUT TYPE=\"submit\" NAME=\"RB6\" VALUE=\"L\"></TD></TR>"

		DA	"<TR><TD>Relay#2(LED7) "
		DA	"%\x17"		;%",0001_0111b,（出力方向）
		DA	" </TD>"

		DA	"<TD><INPUT TYPE=\"submit\" NAME=\"RB7\" VALUE=\"H\">"
		DA	"@\x17"		;'@',0001_0111b,
		DA	"<INPUT TYPE=\"submit\" NAME=\"RB7\" VALUE=\"L\"></TD></TR>"

		DA	"<TR><TD> </TD>"
		DA	"<TD><INPUT TYPE=\"submit\" VALUE=\"Reload\"></TD></TR>"

		DA	"</TABLE>"
		DA	"</FORM></DL>"

		DB	0,0		;バンク終端
		
;======================================================================
;		バンク＃３
;======================================================================

		ORG	1A00h

;;;;		DB	0,0	;←バンク＃３メッセージ非表示はこれを有効

;
;++++++++++++++ 各種設定値の表示＆設定 $8, $0--$4 ++++++++++++++++++
;

		DA	"<FORM METHOD=\"GET\" ACTION=\"submit.cgi\">\n"
		DA	"<H3>Configuration</H3>"

		DA	"<DL><DD><TABLE BORDER>"
		
		DA	"<TR><TD>Firm Version</TD><TD>"
		DA	"$8</TD></TR>"			; バージョン番号($8)

		DA	"<TR><TD>MAC Address</TD><TD>"
		DA	"$0</TD></TR>"			; MACアドレス($0)
		
		DA	"<TR><TD>IP Address</TD><TD>"
		DA	"<INPUT TYPE=\"text\" NAME=\"00b\"  VALUE=\""
		DA	"$1\"></TD></TR>"		; IPアドレス($1)
		
		DA	"<TR><TD>NetMask</TD><TD>"
		DA	"<INPUT TYPE=\"text\" NAME=\"04b\"  VALUE=\""
		DA	"$2\"></TD></TR>"		; ネットマスク($2)
		
		DA	"<TR><TD>GateWay</TD><TD>"
		DA	"<INPUT TYPE=\"text\" NAME=\"08b\"  VALUE=\""
		DA	"$3\"></TD></TR>"		; defaultゲートウェイ($3)
		
		DA	"<TR><TD>http Port#</TD><TD>"
		DA	"<INPUT TYPE=\"text\" NAME=\"10w\"  VALUE=\""
		DA	"$4\"></TD></TR>"		; httpポート番号($4)
		
		DA	"<TR><TD> </TD>"
		DA	"<TD><INPUT TYPE=\"submit\" VALUE=\"Apply\">"
		DA	"</TD></TR>"

		DA	"</TABLE>"
		DA	"</FORM></DL>"

		DB	0,0		;バンク終端
		
;======================================================================
;		バンク＃４
;======================================================================
		
		ORG	1D00h
		
;;;;		DB	0,0	;←バンク＃４メッセージ非表示はこれを有効

;
;++++++++++++++ 送信パケット数、自IPアドレス値の表示 ++++++++++++++++++
;
		DA	"<H3>Status</H3>"
		DA	"<DL><DD><TABLE BORDER>"
		DA	"<TR><TD>Sent Packets </TD>"
		DA	"<TD>$9</TD></TR>"
		DA	"<TR><TD>IP address:Port#</TD>"
		DA	"<TD>"
		DA	"$\x3A"		; '$'+0x3a(":") put_this_ip
		DA	": "
		DA	"$4"
		DA	"</TD></TR>"
		DA	"</TABLE></DL> "
;
;++++++++++++++ フッタ表示 ++++++++++++++++++
;
		DA	"<P><HR>Copyright (c) 2000-2001 by <A HREF=\"http://www.tristate.ne.jp\">TriState Co.,Ltd.</A> "
		DA	"<BR>Firmware Modified by <A HREF=\"http://sugsi.jp/\">Nagano TARO (02TA699X)</A>\n" ; [ver0.1]
		DA	"</BODY></HTML>"

		DB	0,0		;バンク終端

;----------------------------------------------------------------------
;		Ｗｅｂブラウザ用・メッセージここまで	[ver0.4]
;----------------------------------------------------------------------

;-----------------------------------------------------------------------------------
;		EEPROMデータ初期値
;-----------------------------------------------------------------------------------
		org	1F00h
default_values_begin
		DT	.192,.168,1,.200	; [ver0.2]
		DT	.255,.255,.255,0
		DT	0,0,0,0
		DT	1,2,0,4		; Farmware Version x,x,x,x [ver0.4]
		
		DT	HTTP_PORT / .256,HTTP_PORT & .255				; HTTPポート番号
		DT	LCD_PORT / .256,LCD_PORT & .255				; LCDポート番号
		DT	PARALLEL_PORT / .256,PARALLEL_PORT & .255			; PARALLELポート番号
		DT	SERIAL_PORT / .256,SERIAL_PORT & .255			; SERIALポート番号
default_values_end

getadtable
		bsf	STATUS,RP0		;rp0
		MOVF	ADCON1,0		;adcon1,0
		bcf	STATUS,RP0
		andlw	0fh
		ADDWF	2,1		;jmp	pc+w
		retLw	B'11111111'
		retLw	B'11111111'
		retLw	B'00011111'
		retLw	B'00011111'
		retLw	B'00001011'
		retLw	B'00000011'
		retLw	B'00000000'
		retLw	B'00000000'
		retLw	B'11110011'
		retLw	B'00111111'
		retLw	B'00110111'
		retLw	B'00110011'
		retLw	B'00010011'
		retLw	B'00000011'
		retLw	B'00000001'
		retLw	B'00000001'

mes_low		DT	" Low  ",0
mes_high	DT	" High ",0
mes_in		DT	"In ",0
mes_out		DT	"Out",0

;-----------------------------------------------------------------------------------
;		ブートストラップモードのコマンドパース用
;-----------------------------------------------------------------------------------
get_bs_job
		ADDWF	2,1		;jmp	pc+w
		DT	str_init & 0ffh,	bsj_init & 0ffh
		DT	str_init2 & 0ffh,	bsj_init & 0ffh
		
		DT	str_config & 0ffh,	bsj_config & 0ffh
		DT	str_config2 & 0ffh,	bsj_config & 0ffh
		
		DT	str_help & 0ffh,	bsj_help & 0ffh
		DT	str_help2 & 0ffh,	bsj_help & 0ffh
		
		DT	str_ip & 0ffh,		bsj_ip & 0ffh
		DT	str_ip2 & 0ffh,		bsj_ip & 0ffh
		
		DT	str_net & 0ffh,		bsj_net & 0ffh
		DT	str_net2 & 0ffh,	bsj_net & 0ffh
		
		DT	str_gate & 0ffh,	bsj_gate & 0ffh
		DT	str_gate2 & 0ffh,	bsj_gate & 0ffh
		
		DT	str_http & 0ffh,	bsj_http & 0ffh
		DT	str_http2 & 0ffh,	bsj_http & 0ffh

		DT	str_lcd & 0ffh,		bsj_lcd & 0ffh
		DT	str_lcd2 & 0ffh,	bsj_lcd & 0ffh

		DT	str_para & 0ffh,	bsj_para & 0ffh
		DT	str_para2 & 0ffh,	bsj_para & 0ffh

		DT	str_serial & 0ffh,	bsj_serial & 0ffh
		DT	str_serial2 & 0ffh,	bsj_serial & 0ffh

		DT	0,0		; Terminator


str_config	DT	"config",0
str_config2	DT	"ls",0

str_init	DT	"initialize",0
str_init2	DT	"init",0

str_help	DT	"help",0
str_help2	DT	'?',0

str_ip		DT	"ip",0
str_ip2		DT	'i',0

str_net		DT	"net",0
str_net2	DT	"n",0

str_gate	DT	"gate",0
str_gate2	DT	'g',0

str_http	DT	"http",0
str_http2	DT	'h',0

str_lcd		DT	"lcd",0
str_lcd2	DT	'l',0

str_para	DT	"parallel",0
str_para2	DT	'p',0

str_serial	DT	"serial",0
str_serial2	DT	's',0



		end

